Internal Tool: ale#util#MapMatches

[w0rp]

ALE has had ale#util#GetMatches for internal use a while, and has also only supported versions of NeoVim that have lambdas for a while. I realised that we can add another function ale#util#MapMatches for making it even easier to write some helper functions, which will accept a function for mapping matches to loclist items.

Take my recent systemd-analyze linter as an example:

function! ale_linters#systemd#systemd_analyze#Handle(buffer, lines) abort
    let l:re = '\v(.+):([0-9]+): (.+)'
    let l:output = []

    for l:match in ale#util#GetMatches(a:lines, l:re)
        call add(l:output, {
        \   'lnum': str2nr(l:match[2]),
        \   'col': 1,
        \   'type': 'W',
        \   'text': l:match[3],
        \})
    endfor

    return l:output
endfunction

call ale#linter#Define('systemd', {
\   'name': 'systemd_analyze',
\   'aliases': ['systemd-analyze'],
\   'executable': 'systemd-analyze',
\   'command': 'SYSTEMD_LOG_COLOR=0 %e --user verify %s',
\   'callback': 'ale_linters#systemd#systemd_analyze#Handle',
\   'output_stream': 'both',
\   'lint_file': 1,
\})

With the new function, it can be shortened down to the following:

call ale#linter#Define('systemd', {
\   'name': 'systemd_analyze',
\   'aliases': ['systemd-analyze'],
\   'executable': 'systemd-analyze',
\   'command': 'SYSTEMD_LOG_COLOR=0 %e --user verify %s',
\   'callback': {buffer, lines -> ale#util#MapMatches(
\       lines, 
\       '\v(.+):([0-9]+): (.+)', 
\       {match -> {
\           'lnum': str2nr(match[2]),
\           'col': 1,
\           'type': 'W',
\           'text': match[3],
\       }}
\   )},
\   'output_stream': 'both',
\   'lint_file': 1,
\})