feat(accrued-interests): add interests library

src/interfaces/IIrm.sol

@@ -4,5 +4,5 @@ pragma solidity >=0.5.0;
 import {Market} from "./IBlue.sol";
 
 interface IIrm {
-    function borrowRate(Market memory market) external returns (uint256);
+    function borrowRate(Market calldata market) external view returns (uint256);
 }

src/libraries/BlueLib.sol

@@ -0,0 +1,52 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.0;
+
+import {Id, Market, IBlue} from "../interfaces/IBlue.sol";
+import {IIrm} from "../interfaces/IIrm.sol";
+
+import {MarketLib} from "./MarketLib.sol";
+import {BlueStorageLib} from "./BlueStorageLib.sol";
+import {FixedPointMathLib} from "./FixedPointMathLib.sol";
+
+library BlueLib {
+    using MarketLib for Market;
+    using FixedPointMathLib for uint256;
+
+    function accruedInterests(IBlue blue, Market memory market)
+        internal
+        view
+        returns (uint256 totalSupply, uint256 totalBorrow, uint256 totalSupplyShares)
+    {
+        Id id = market.id();
+
+        bytes32[] memory slots = new bytes32[](5);
+        slots[0] = BlueStorageLib.totalSupply(id);
+        slots[1] = BlueStorageLib.totalBorrow(id);
+        slots[2] = BlueStorageLib.totalSupplyShares(id);
+        slots[3] = BlueStorageLib.fee(id);
+        slots[4] = BlueStorageLib.lastUpdate(id);
+
+        bytes32[] memory values = blue.extsload(slots);
+        totalSupply = uint256(values[0]);
+        totalBorrow = uint256(values[1]);
+        totalSupplyShares = uint256(values[2]);
+        uint256 fee = uint256(values[3]);
+        uint256 lastUpdate = uint256(values[4]);
+
+        if (totalBorrow != 0) {
+            uint256 borrowRate = IIrm(market.irm).borrowRate(market);
+            uint256 interests = totalBorrow.wMulDown(borrowRate * (block.timestamp - lastUpdate));
+
+            totalBorrow += interests;
+            totalSupply += interests;
+
+            if (fee != 0) {
+                uint256 feeAmount = interests.wMulDown(fee);
+                // The fee amount is subtracted from the total supply in this calculation to compensate for the fact that total supply is already updated.
+                uint256 feeShares = feeAmount.mulDivDown(totalSupplyShares, totalSupply - feeAmount);
+
+                totalSupplyShares += feeShares;
+            }
+        }
+    }
+}

src/libraries/BlueStorageLib.sol

@@ -0,0 +1,77 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.0;
+
+import {Id} from "./MarketLib.sol";
+
+library BlueStorageLib {
+    uint256 internal constant OWNER_SLOT = 0;
+    uint256 internal constant FEE_RECIPIENT_SLOT = 1;
+    uint256 internal constant SUPPLY_SHARES_SLOT = 2;
+    uint256 internal constant BORROW_SHARES_SLOT = 3;
+    uint256 internal constant COLLATERAL_SLOT = 4;
+    uint256 internal constant TOTAL_SUPPLY_SLOT = 5;
+    uint256 internal constant TOTAL_SUPPLY_SHARES_SLOT = 6;
+    uint256 internal constant TOTAL_BORROW_SLOT = 7;
+    uint256 internal constant TOTAL_BORROW_SHARES_SLOT = 8;
+    uint256 internal constant LAST_UPDATE_SLOT = 9;
+    uint256 internal constant FEE_SLOT = 10;
+    uint256 internal constant IS_IRM_ENABLED_SLOT = 11;
+    uint256 internal constant IS_LLTV_ENABLED_SLOT = 12;
+    uint256 internal constant IS_AUTHORIZED_SLOT = 13;
+
+    function owner() internal pure returns (bytes32) {
+        return bytes32(OWNER_SLOT);
+    }
+
+    function feeRecipient() internal pure returns (bytes32) {
+        return bytes32(FEE_RECIPIENT_SLOT);
+    }
+
+    function supplyShares(Id id, address user) internal pure returns (bytes32) {
+        return keccak256(abi.encode(user, keccak256(abi.encode(id, SUPPLY_SHARES_SLOT))));
+    }
+
+    function borrowShares(Id id, address user) internal pure returns (bytes32) {
+        return keccak256(abi.encode(user, keccak256(abi.encode(id, BORROW_SHARES_SLOT))));
+    }
+
+    function collateral(Id id, address user) internal pure returns (bytes32) {
+        return keccak256(abi.encode(user, keccak256(abi.encode(id, COLLATERAL_SLOT))));
+    }
+
+    function totalSupply(Id id) internal pure returns (bytes32) {
+        return keccak256(abi.encode(id, TOTAL_SUPPLY_SLOT));
+    }
+
+    function totalSupplyShares(Id id) internal pure returns (bytes32) {
+        return keccak256(abi.encode(id, TOTAL_SUPPLY_SHARES_SLOT));
+    }
+
+    function totalBorrow(Id id) internal pure returns (bytes32) {
+        return keccak256(abi.encode(id, TOTAL_BORROW_SLOT));
+    }
+
+    function totalBorrowShares(Id id) internal pure returns (bytes32) {
+        return keccak256(abi.encode(id, TOTAL_BORROW_SHARES_SLOT));
+    }
+
+    function lastUpdate(Id id) internal pure returns (bytes32) {
+        return keccak256(abi.encode(id, LAST_UPDATE_SLOT));
+    }
+
+    function fee(Id id) internal pure returns (bytes32) {
+        return keccak256(abi.encode(id, FEE_SLOT));
+    }
+
+    function isIrmEnabled(address irm) internal pure returns (bytes32) {
+        return keccak256(abi.encode(irm, IS_IRM_ENABLED_SLOT));
+    }
+
+    function isLltvEnabled(uint256 lltv) internal pure returns (bytes32) {
+        return keccak256(abi.encode(lltv, IS_LLTV_ENABLED_SLOT));
+    }
+
+    function isApproved(address delegator, address manager) internal pure returns (bytes32) {
+        return keccak256(abi.encode(manager, keccak256(abi.encode(delegator, IS_AUTHORIZED_SLOT))));
+    }
+}