Document checkpoint simulator, with java/groovy/kotlin examples

[wetted]

closes #115

[wetted]

@timyates I also thought trying something like the following, but it's apparently not exactly what you meant.

@MicronautTest
class CheckpointSimulatorTest extends Specification {

    void 'emulate checkpoint'() {
        given:
        EmbeddedServer server = ApplicationContext.run(EmbeddedServer.class, ['spec.name': 'CheckpointSimulatorTest'], Environment.TEST)
        CheckpointSimulator checkpointSimulator = server.getApplicationContext().getBean(CheckpointSimulator) // <1>
        TestResource testResource = server.getApplicationContext().getBean(TestResource)

        expect:
        testResource
        testResource.running

        when:
        checkpointSimulator.runBeforeCheckpoint() // <2>
        then:
        !testResource.running

        when:
        checkpointSimulator.runAfterRestore() // <3>
        then:
        testResource.running
    }

    @Singleton
    @Requires(property = "spec.name", value = "CheckpointSimulatorTest")
    static class TestResource implements OrderedResource {
        boolean running = true
        @Override
        void beforeCheckpoint(Context<? extends Resource> context) throws Exception {
            running = false
        }
        @Override
        void afterRestore(Context<? extends Resource> context) throws Exception {
            running = true
        }
    }
}

[timyates]

Hi @wetted 👋

I meant something like this to show people how to implement their own Resource handlers for their own custom beans

import io.micronaut.context.BeanContext
import io.micronaut.context.annotation.Property
import io.micronaut.context.annotation.Requires
import io.micronaut.crac.test.CheckpointSimulator
import io.micronaut.test.extensions.spock.annotation.MicronautTest
import jakarta.inject.Inject
import jakarta.inject.Singleton
import org.crac.Context
import org.crac.Resource
import spock.lang.Specification

@MicronautTest
@Property(name = "spec.name", value = SPEC_NAME)
class OrderedResourceCheckpointSimulatorTest extends Specification {

    public static final String SPEC_NAME = "OrderedResourceCheckpointSimulatorTest"

    @Inject
    BeanContext ctx

    void "test custom OrderedResource implementation using the CheckpointSimulator"() {
        given:
        def myBean = ctx.getBean(ResourceBean)
        def checkpointSimulator = ctx.getBean(CheckpointSimulator)

        expect:
        myBean.running

        when:
        checkpointSimulator.runBeforeCheckpoint()

        then:
        !myBean.running

        when:
        checkpointSimulator.runAfterRestore()

        then:
        myBean.running
    }

    /**
     * A bean to demonstrate how to write and test custom OrderedResource implementations.
     * Here it is doing nothing for sake of the example, but in reality it would have a socket or something that needs to be closed.
     */
    @Singleton
    @Requires(property = "spec.name", value = SPEC_NAME)
    static class ResourceBean {

        private boolean running = true

        boolean isRunning() {
            return running
        }

        void stop() {
            this.running = false
        }

        void start() {
            this.running = true
        }
    }

    /**
     * An OrderedResource which will stop the {@link ResourceBean} before a checkpoint and start it again after a restore.
     */
    @Singleton
    @Requires(property = "spec.name", value = SPEC_NAME)
    static class ResourceBeanResource implements OrderedResource {

        private final ResourceBean resourceBean

        ResourceBeanResource(ResourceBean resourceBean) {
            this.resourceBean = resourceBean
        }

        @Override
        void beforeCheckpoint(Context<? extends Resource> context) throws Exception {
            resourceBean.stop()
        }

        @Override
        void afterRestore(Context<? extends Resource> context) throws Exception {
            resourceBean.start()
        }
    }
}

[timyates]

The docs had static in the bean and resource definition, so I moved them from being inner classes so we could get rid of it

[sonarcloud]

Kudos, SonarCloud Quality Gate passed!   

0 Bugs
0 Vulnerabilities
0 Security Hotspots
0 Code Smells

No Coverage information
0.0% Duplication