#912 - Quadratic map of a zonotope

docs/src/lib/sets/Zonotope.md

@@ -18,6 +18,7 @@ split(::AbstractZonotope, ::Int)
 split(::AbstractZonotope, ::AbstractVector{Int}, ::AbstractVector{Int})
 remove_zero_generators(::Zonotope)
 linear_map!(::Zonotope, ::AbstractMatrix, ::Zonotope)
+quadratic_map(Q::Vector{MT}, Z::Zonotope{N}) where {N, MT<:AbstractMatrix{N}}
 ```
 
 Inherited from [`LazySet`](@ref):

src/Sets/Zonotope.jl

@@ -427,3 +427,65 @@ function linear_map!(Zout::Zonotope, M::AbstractMatrix, Z::Zonotope)
     mul!(Zout.generators, M, Z.generators)
     return Zout
 end
+
+"""
+    quadratic_map(Q::Vector{MT}, Z::Zonotope{N}) where {N, MT<:AbstractMatrix{N}}
+
+Return the overapproximation of the quadratic map of the given zonotope.
+
+### Input
+
+- `Z` -- zonotope
+- `Q` -- array of square matrices
+
+### Output
+
+The overapproximation of the quadratic map of the given zonotope.
+
+### Notes
+
+Mathematically, a quadratic map of a zonotope is defined as:
+
+```math
+Z_Q = \\right\\{ \\lambda | \\lambda_i = x^T Q\\^{(i)} x, x \\in Z \\left\\}
+```
+such that each coordinate ``i`` of the resulting zonotope is influenzed by ``Q\\^{(i)}``
+
+### Algorithm
+
+This function implements [Lemma 1, 1].
+
+[1] *Matthias Althoff and Bruce H. Krogh. 2012. Avoiding geometric intersection
+operations in reachability analysis of hybrid systems. In Proceedings of the
+15th ACM international conference on Hybrid Systems: Computation and Control
+(HSCC ’12). Association for Computing Machinery, New York, NY, USA, 45–54.*
+"""
+function quadratic_map(Q::Vector{MT}, Z::Zonotope{N}) where {N, MT<:AbstractMatrix{N}}
+    @assert length(Q) == dim(Z) "the number of matrices needs to match the dimension of the zonotope"
+    G = genmat(Z)
+    c = center(Z)
+    n, p = size(G)
+    h = Matrix{N}(undef, n, binomial(p+2, 2)-1)
+    d = Vector{N}(undef, n)
+    g(x) = view(G, :, x)
+    cᵀ = c'
+    for (i, Qᵢ) in enumerate(Q)
+        cᵀQᵢ = cᵀ * Qᵢ
+        Qᵢc = Qᵢ * c
+        aux = zero(N)
+        for j=1:p
+            aux += g(j)' * Qᵢ * g(j)
+            h[i, j] = cᵀQᵢ * g(j) + g(j)' * Qᵢc
+            h[i, p+j] = 0.5 * g(j)' * Qᵢ * g(j)
+        end
+        d[i] = cᵀQᵢ * c + 0.5 * aux
+        l = 0
+        for j=1:p-1
+            for k=j+1:p
+                l += 1
+                h[i, 2p+l] = g(j)' * Qᵢ * g(k) + g(k)' * Qᵢ * g(j)
+            end
+        end
+    end
+    return Zonotope(d, h)
+end