build.gradle

plugins {
    id 'java'
    id 'maven-publish'
    id 'signing'
}

group 'fr.ztn.java'
version '1.0.0'

sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

dependencies {
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.3.2'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.3.2'
}

test {
    useJUnitPlatform()

    testLogging {
        events "passed", "failed"
    }
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allJava
    classifier = 'sources'
}

task javadocJar(type: Jar) {
    from javadoc
    classifier = 'javadoc'
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifactId = 'csharpflavour'
            from components.java
            artifact sourcesJar
            artifact javadocJar
            pom {
                name = 'A flavour of C# in java'
                description = 'This library defines some classes that help me converting/rewriting some C# projects to java'
                url = 'https://github.com/zetoken/csharp-flavour'
                licenses {
                    license {
                        name = 'MIT'
                        url = 'https://github.com/zetoken/csharp-flavour/blob/master/LICENSE'
                    }
                }
                developers {
                    developer {
                        id = 'ztn'
                        name = 'ZeToken'
                        email = 'zetoken@gmail.com'
                    }
                }
                scm {
                    connection = 'scm:git:https://github.com/zetoken/csharp-flavour.git'
                    developerConnection = 'scm:git:https://github.com/zetoken/csharp-flavour.git'
                    url = 'https://github.com/zetoken/'
                }
            }
        }
    }
    repositories {
        maven {
            credentials {
                username findProperty('ossrhUsername')
                password findProperty('ossrhPassword')
            }
            // def releasesRepoUrl = "$buildDir/repos/releases"
            // def snapshotsRepoUrl = "$buildDir/repos/snapshots"
            def releasesRepoUrl = 'https://oss.sonatype.org/service/local/staging/deploy/maven2/'
            def snapshotsRepoUrl = 'https://oss.sonatype.org/content/repositories/snapshots'
            url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
        }
    }
}

signing {
    sign publishing.publications.mavenJava
}

javadoc {
    if (JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}