Add capability to run tests with Kubernetes Jobs

[stefanprodan]

This PR adds testing capabilities to Timoni. Module authors can add Kubernetes Jobs templates that get applied after all other resources. After the app workloads are applied and become ready, Timoni will apply the Kubernetes Jobs and wait for the created pods to run to completion. On upgrades, Timoni will delete the previous test pods and will recreate the Jobs for the current module values and version. Test runs are idempotent, if the values or the module version doesn't change, Timoni will not create new test pods, tests are run only when a drift is detected in desired state vs cluster state.

Example

Define a Job that performs a connectivity test:

#TestJob: batchv1.#Job & {
	_config:    #Config
	apiVersion: "batch/v1"
	kind:       "Job"
	metadata: name:        "\(_config.metadata.name)-test"
	metadata: namespace:   _config.metadata.namespace
	metadata: labels:      _config.metadata.labels
	metadata: annotations: timoniv1.action.force
	spec: batchv1.#JobSpec & {
		template: corev1.#PodTemplateSpec & {
			metadata: labels: _config.metadata.labels
			let _checksum = uuid.SHA1(uuid.ns.DNS, yaml.Marshal(_config))
			metadata: annotations: "timoni.sh/checksum": "\(_checksum)"
			spec: {
				containers: [{
					name:            "curl"
					image:           _config.test.image.reference
					imagePullPolicy: _config.imagePullPolicy
					command: [
						"curl",
						"-v",
						"-m",
						"5",
						"\(_config.metadata.name):\(_config.service.port)",
					]
				}]
				restartPolicy: "Never"
			}
		}
		backoffLimit: 1
	}
}

Allow end-users to enable the tests:

// timoni.cue

apply: app: [ for obj in instance.objects {obj}]

// Conditionally run tests after an install or upgrade.
if instance.config.test.enabled {
	apply: test: [ for obj in instance.tests {obj}]
}