Черновик библиотеки autumn-cli и ее использование

autumn-properties.json

@@ -0,0 +1,23 @@
+{
+    "cli": {
+        "ИмяПриложения": "ovm",
+        "ПолноеИмяПриложения": "OneScript Version Manager v%{cli.ВерсияПриложения}",
+        "ВерсияПриложения": "1.0.0-RC17"
+    },
+    "logos": {
+        "logger": {
+            "oscript.app.ovm": {
+                "level": "info",
+                "appenders": [
+                    "logos"
+                ]
+            }
+        },
+        "appender": {
+            "logos": {
+                "type": "ЛогосАппендер",
+                "level": "info"
+            }
+        }
+    }
+}

packagedef

@@ -4,6 +4,8 @@
 	.АдресАвтора("[email protected]")
 	.Описание("OneScript Version Manager")
 	.ВерсияСреды("1.0.20")
+	.ЗависитОт("autumn", "2.3.0")
+	.ЗависитОт("autumn-logos", "1.0.0")
 	.ЗависитОт("json")
 	.ЗависитОт("1commands", "1.3.2")
 	.ЗависитОт("fluent", "0.3.1")

src/cmd/ovm.os

@@ -1,81 +1,10 @@
-#Использовать cli
-#Использовать tempfiles
+#Использовать autumn
+#Использовать autumn-logos
 
 #Использовать "."
 #Использовать "../core"
 
-///////////////////////////////////////////////////////////////////////////////
-
-// Обработчик выполнения команды
-//
-// Параметры:
-//   КомандаПриложения - КомандаПриложения - Выполняемая команда
-//
-Процедура ВыполнитьКоманду(Знач КомандаПриложения) Экспорт
-
-	КомандаПриложения.ВывестиСправку();
-
-КонецПроцедуры
-
-Процедура ВыполнитьПриложение()
-
-	КонсольноеПриложение = Новый КонсольноеПриложение(
-		ПараметрыПриложения.ИмяПриложения(),
-		"OneScript Version Manager v" + ПараметрыПриложения.Версия()
-	);
-
-	КонсольноеПриложение.Версия("v version", ПараметрыПриложения.Версия());
-
-	КонсольноеПриложение.ДобавитьКоманду(
-		"install i",
-		"Установить OneScript указанных версий",
-		Новый КомандаInstall()
-	);
-	КонсольноеПриложение.ДобавитьКоманду(
-		"use u", 
-		"Использовать OneScript указанной версии",
-		Новый КомандаUse()
-	);
-	КонсольноеПриложение.ДобавитьКоманду(
-		"uninstall delete d", 
-		"Удалить OneScript указанных версий",
-		Новый КомандаUninstall()
-	);
-	КонсольноеПриложение.ДобавитьКоманду(
-		"list ls", 
-		"Вывести список установленных и/или доступных версий OneScript",
-		Новый КомандаList()
-	);
-	КонсольноеПриложение.ДобавитьКоманду(
-		"run r", 
-		"Запустить исполняемый файл в окружении указанной версии OneScript",
-		Новый КомандаRun()
-	);
-	КонсольноеПриложение.ДобавитьКоманду(
-		"which w", 
-		"Вывести путь к установленной версии OneScript",
-		Новый КомандаWhich()
-	);
-	КонсольноеПриложение.ДобавитьКоманду(
-		"config", 
-		"Настройки ovm. Прокси, сервера и т.п.",
-		Новый КомандаConfig()
-	);
-
-	КонсольноеПриложение.УстановитьОсновноеДействие(ЭтотОбъект);
-	КонсольноеПриложение.Запустить(АргументыКоманднойСтроки);
-
-КонецПроцедуры
-
-Лог = ПараметрыOVM.ПолучитьЛог();
-КодСостояния = 0;
-Попытка
-	ВыполнитьПриложение();
-Исключение
-	Лог.Ошибка(ОписаниеОшибки());
-	КодСостояния = 1;
-КонецПопытки;
-
-ВременныеФайлы.Удалить();
-
-ЗавершитьРаботу(КодСостояния);
+Поделка = Новый Поделка();
+Поделка
+	.ПросканироватьКаталог(ТекущийСценарий().Каталог)
+	.ЗапуститьПриложение();

src/cmd/Классы/АннотацияКомандаПриложения.os

@@ -0,0 +1,5 @@
+&Аннотация("КомандаПриложения")
+&Прозвище("КомандаПриложения")
+&Желудь
+Процедура ПриСозданииОбъекта(Имя, Описание = "")
+КонецПроцедуры

src/cmd/Классы/АннотацияЛогOVM.os

@@ -0,0 +1,4 @@
+&Аннотация("ЛогOVM")
+&Лог("oscript.app.ovm")
+Процедура ПриСозданииОбъекта()
+КонецПроцедуры

src/cmd/Классы/ДубCli.os

@@ -0,0 +1,51 @@
+#Использовать autumn
+#Использовать cli
+
+&Завязь
+Функция КонсольноеПриложение(
+	&Пластилин(Значение = "КомандаПриложения", Тип = "ТаблицаЗначений") КомандыПриложения,
+	&Пластилин КомандаПриложенияПоУмолчанию,
+	&Деталька(Значение = "cli.ИмяПриложения") ИмяПриложения,
+	&Деталька(Значение = "cli.ПолноеИмяПриложения") ПолноеИмяПриложения,
+	&Деталька(Значение = "cli.ВерсияПриложения") ВерсияПриложения
+) Экспорт
+
+	// TODO: Перенести в ядро ОСени.
+	ПолноеИмяПриложения = СтрЗаменить(ПолноеИмяПриложения, "%{cli.ВерсияПриложения}", ВерсияПриложения);
+
+	КонсольноеПриложение = Новый КонсольноеПриложение(
+		ИмяПриложения,
+		ПолноеИмяПриложения
+	);
+
+	КонсольноеПриложение.Версия("v version", ВерсияПриложения);
+
+	Для Каждого ДанныеЖелудя Из КомандыПриложения Цикл
+
+		КомандаПриложения = ДанныеЖелудя.Желудь;
+		ОпределениеЖелудя = ДанныеЖелудя.ОпределениеЖелудя;
+
+		Конструктор = ОпределениеЖелудя.Завязь().ДанныеМетода();
+
+		Аннотация = РаботаСАннотациями.НайтиАннотацию(Конструктор.Аннотации, "КомандаПриложения");
+		Если Аннотация = Неопределено Тогда
+			ВызватьИсключение "Не найдена аннотация КомандаПриложения у желудя " + ДанныеЖелудя.Имя;
+		КонецЕсли;
+
+		КонсольноеПриложение.ДобавитьКоманду(
+			РаботаСАннотациями.ПолучитьЗначениеПараметраАннотации(Аннотация, "Имя"), 
+			РаботаСАннотациями.ПолучитьЗначениеПараметраАннотации(Аннотация, "Описание", ""),
+			КомандаПриложения
+		);
+
+	КонецЦикла;
+
+	КонсольноеПриложение.УстановитьОсновноеДействие(КомандаПриложенияПоУмолчанию);
+
+	Возврат КонсольноеПриложение;
+
+КонецФункции
+
+&Дуб
+Процедура ПриСозданииОбъекта()
+КонецПроцедуры

src/cmd/Классы/КомандаConfig.os

@@ -29,4 +29,11 @@
 	Хранилище.Установить(Имя, Значение);
 	Хранилище.Записать();
 
+КонецПроцедуры
+
+&КомандаПриложения(
+	Имя = "config",
+	Описание = "Настройки ovm. Прокси, сервера и т.п."
+)
+Процедура ПриСозданииОбъекта()
 КонецПроцедуры

src/cmd/Классы/КомандаInstall.os

@@ -1,5 +1,6 @@
 #Использовать "../../core"
 
+&ЛогOVM
 Перем Лог;
 
 // Заполняет описание команды для библиотеки cli
@@ -69,4 +70,9 @@
 
 КонецПроцедуры
 
-Лог = ПараметрыOVM.ПолучитьЛог();
+&КомандаПриложения(
+	Имя = "install i",
+	Описание = "Установить OneScript указанных версий"
+)
+Процедура ПриСозданииОбъекта()
+КонецПроцедуры

src/cmd/Классы/КомандаList.os

@@ -1,5 +1,6 @@
 #Использовать "../../core"
 
+&ЛогOVM
 Перем Лог;
 
 // Заполняет описание команды для библиотеки cli
@@ -124,4 +125,9 @@
 
 КонецПроцедуры
 
-Лог = ПараметрыOVM.ПолучитьЛог();
+&КомандаПриложения(
+	Имя = "list ls",
+	Описание = "Вывести список установленных и/или доступных версий OneScript"
+)
+Процедура ПриСозданииОбъекта()
+КонецПроцедуры

src/cmd/Классы/КомандаRun.os

@@ -64,5 +64,12 @@
 
 КонецПроцедуры
 
+&КомандаПриложения(
+	Имя = "run r",
+	Описание = "Запустить исполняемый файл в окружении указанной версии OneScript"
+)
+Процедура ПриСозданииОбъекта()
+КонецПроцедуры
+
 СистемнаяИнформация = Новый СистемнаяИнформация;
 ЭтоWindows = Найти(ВРег(СистемнаяИнформация.ВерсияОС), "WINDOWS") > 0;

src/cmd/Классы/КомандаUninstall.os

@@ -1,3 +1,4 @@
+&ЛогOVM
 Перем Лог;
 
 // Заполняет описание команды для библиотеки cli
@@ -57,4 +58,9 @@
 
 КонецПроцедуры
 
-Лог = ПараметрыOVM.ПолучитьЛог();
+&КомандаПриложения(
+	Имя = "uninstall delete d",
+	Описание = "Удалить OneScript указанных версий"
+)
+Процедура ПриСозданииОбъекта()
+КонецПроцедуры

src/cmd/Классы/КомандаUse.os

@@ -36,3 +36,10 @@
 	АктиваторOneScript.ИспользоватьВерсиюOneScript(ИспользуемаяВерсия, ВыполнятьУстановкуПриНеобходимости);
 
 КонецПроцедуры
+
+&КомандаПриложения(
+	Имя = "use u",
+	Описание = "Использовать OneScript указанной версии"
+)
+Процедура ПриСозданииОбъекта()
+КонецПроцедуры

src/cmd/Классы/КомандаWhich.os

@@ -1,5 +1,6 @@
 #Использовать "../../core"
 
+&ЛогOVM
 Перем Лог;
 
 // Заполняет описание команды для библиотеки cli
@@ -35,4 +36,9 @@
 
 КонецПроцедуры
 
-Лог = ПараметрыOVM.ПолучитьЛог();
+&КомандаПриложения(
+	Имя = "which w",
+	Описание = "Вывести путь к установленной версии OneScript"
+)
+Процедура ПриСозданииОбъекта()
+КонецПроцедуры

src/cmd/Классы/КомандаПоУмолчанию.os

@@ -0,0 +1,19 @@
+// Обработчик выполнения команды
+//
+// Параметры:
+//   КомандаПриложения - КомандаПриложения - Выполняемая команда
+//
+Процедура ВыполнитьКоманду(Знач КомандаПриложения) Экспорт
+
+	КомандаПриложения.ВывестиСправку();
+
+КонецПроцедуры
+
+&КомандаПриложения(
+	Имя = "help h",
+	Описание = "Вывести справку по командам"
+)
+&Прозвище("КомандаПриложенияПоУмолчанию")
+Процедура ПриСозданииОбъекта()
+
+КонецПроцедуры

src/cmd/Классы/РогаткаCli.os

@@ -0,0 +1,30 @@
+// TODO: отдельная рогатка ovm по управлчению временными файлами? Перехватчик "ПриЗавершенииПриложения" в ОСени?
+#Использовать tempfiles
+
+&Пластилин
+Перем КонсольноеПриложение;
+
+&Лог("oscript.lib.autumn-cli")
+Перем Лог;
+
+Процедура ПриЗапускеПриложения() Экспорт
+
+	Лог = ПараметрыOVM.ПолучитьЛог();
+	КодСостояния = 0;
+	Попытка
+		КонсольноеПриложение.Запустить(АргументыКоманднойСтроки);
+	Исключение
+		Лог.Ошибка(ОписаниеОшибки());
+
+		ВременныеФайлы.Удалить(); // todo: перехватчик "ПриЗавершенииПриложения" в ОСени?
+
+		КодСостояния = 1; // todo: возврат кода состояния рогатки как ExitCodeGenerator?
+	КонецПопытки;
+
+	ЗавершитьРаботу(КодСостояния); // todo: прям не хорошо
+
+КонецПроцедуры
+
+&Рогатка(ЗапускатьВФоне = Ложь)
+Процедура ПриСозданииОбъекта()
+КонецПроцедуры