Installing neovim 0.10 in NixOS 24.05 with home-manager

[gmile]

Hi! I'm having a hard time specifying neovim 0.10. I building my own flake, and using NixOS 24.05 and home-manager 24.05. In my flake, I am able to specify unstable nixpkgs as an input. However, I am having a hard time understand how to correctly pass information from the flake.nix down to the home-manager module and finally to nixvim to use the neovim package from unstable.

Here's the contents of my flake.nix and home.nix files:

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.05";
    nixpkgs-unstable.url = "github:nixos/nixpkgs/nixpkgs-unstable";

    nixvim.url = "github:nix-community/nixvim?rev=b64ee08d6b08b36b33fd1644b374ec2a5fd1a193";
    nixvim.inputs.nixpkgs.follows = "nixpkgs-unstable";

    home-manager.url = "github:nix-community/home-manager/release-24.05";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = inputs@{ self, nixpkgs, nixvim, home-manager, ... }: {
    nixosConfigurations = {
      my-lenovo-pc = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";

        modules = [
          ./my-vms/my-lenovo-pc/configuration.nix
          home-manager.nixosModules.home-manager
          {
            home-manager.useGlobalPkgs = true; 
            home-manager.useUserPackages = true;
            home-manager.sharedModules = [
              nixvim.homeManagerModules.nixvim
            ];
            home-manager.users.eugene = import ./home.nix; # how do I make nixpkgs-unstable available inside home.nix?
          }
        ];
      };
    };
  };
}

{ config, pkgs, ... }: {
  home.stateVersion = "24.05";

  programs.nixvim = {
    package = # what do I put here ???
    enable = true;
    enableMan = true;
    defaultEditor = true;
  };
}

[MattSturgeon]

You can use home-manager.extraSpecialArgs to pass in additional module args. In this case, your flake inputs.

e.g.

  home-manager.useGlobalPkgs = true; 
  home-manager.useUserPackages = true;
+ home-manager.extraSpecialArgs = {inherit inputs;};
  home-manager.sharedModules = [
    nixvim.homeManagerModules.nixvim
  ];
  home-manager.users.eugene = import ./home.nix;

- { config, pkgs, ... }: {
+ { inputs, config, pkgs, ... }: {
   home.stateVersion = "24.05";

   programs.nixvim = {
-    package = # what do I put here ???
+    package = inputs.nixpkgs-unstable.legacyPackages.${pkgs.system}.neovim;
     enable = true;
     enableMan = true;
     defaultEditor = true;
   };
 }

You can make that more readable by doing something like this:

{ inputs, config, pkgs, ... }:
let
  pkgs-unstable = inputs.nixpkgs-unstable.legacyPackages.${pkgs.system};
in
{
  home.stateVersion = "24.05";

  programs.nixvim = {
    package = pkgs-unnstable.neovim;
    enable = true;
    enableMan = true;
    defaultEditor = true;
  };
}

Or you could pass pkgs-unstable as a module arg, instead of just inputs:

- my-lenovo-pc = nixpkgs.lib.nixosSystem {
+ my-lenovo-pc = nixpkgs.lib.nixosSystem rec {
    system = "x86_64-linux";

    modules = [
      ./my-vms/my-lenovo-pc/configuration.nix
      home-manager.nixosModules.home-manager
      {
        home-manager.useGlobalPkgs = true; 
        home-manager.useUserPackages = true;
+       home-manager.extraSpecialArgs = {
+         pkgs-unstable = inputs.nixpkgs-unstable.legacyPackages.${system};
+       };
        home-manager.sharedModules = [
          nixvim.homeManagerModules.nixvim
        ];
        home-manager.users.eugene = import ./home.nix; # how do I make nixpkgs-unstable available inside home.nix?
      }
    ];
  };

[gmile]

@MattSturgeon thank you! That did indeed helped, I got past the flake evaluation phase, and entered the build neovim-0.10 phase. Now, and I suspect it's a totally different issue - the build for neovim 0.10 is failing.

Would asking how to get past the build issue be out of scope of nixvim? If so, could direct me towards where to ask about the build issue? 🙏 I'm happy to report it to whoever might know more about this.

Build log failure, just in case.

sudo nixos-rebuild switch --flake /home/eugene/my-first-flake#my-lenovo-pc
[sudo] password for eugene:
warning: Git tree '/home/eugene/my-first-flake' is dirty
building the system configuration...
warning: Git tree '/home/eugene/my-first-flake' is dirty
error: builder for '/nix/store/k0mvgilrhy5bqwvmmgic9vi5gs28qcvq-neovim-0.10.0.drv' failed with exit code 1;
       last 9 log lines:
       > structuredAttrs is enabled
       > Running phase: patchPhase
       > Running phase: updateAutotoolsGnuConfigScriptsPhase
       > Running phase: configurePhase
       > no configure script, doing nothing
       > Running phase: buildPhase
       > substituteStream() in derivation neovim-0.10.0: WARNING: '--replace' is deprecated, use --replace-{fail,warn,quiet}. (file '/nix/store/wv8sifkxz08klx563vsyqfm000gsk34i-neovim-0.10.0/share/applications/nvim.desktop')
       > /nix/store/g85xmbanh5h6rwx5jd4jriai36hgk6ja-make-shell-wrapper-hook/nix-support/setup-hook: line 116: /nix/store/blnk22c24riga9qzlxy0aiffgmp532lv-neovim-0.10.0/bin/nvim-python3: Permission denied
       > /nix/store/g85xmbanh5h6rwx5jd4jriai36hgk6ja-make-shell-wrapper-hook/nix-support/setup-hook: line 131: pop_var_context: head of shell_variables not a function context
       For full logs, run 'nix log /nix/store/k0mvgilrhy5bqwvmmgic9vi5gs28qcvq-neovim-0.10.0.drv'.
error: 1 dependencies of derivation '/nix/store/prr6r714df21g9l0zzz81k0j8fslz8il-home-manager-path.drv' failed to build
error: 1 dependencies of derivation '/nix/store/n73ywr1j3xzlagw96vvajjwgmsbvkpzi-man-paths.drv' failed to build
error: 1 dependencies of derivation '/nix/store/zxayxn4d2mxps5q86r23z8wvyhqfl5b2-neovim-0.10.0-fish-completions.drv' failed to build
error: 1 dependencies of derivation '/nix/store/iwh2j54vpmr6whj1354nlgv6s0c8gcrn-home-manager-generation.drv' failed to build
error: 1 dependencies of derivation '/nix/store/xffvm1a3fpsfss3c7n39gn71bml1sxyk-user-environment.drv' failed to build
error: 1 dependencies of derivation '/nix/store/bldhzvx7j3gbzrxdfwgi0h9y471j4h93-etc.drv' failed to build
error: 1 dependencies of derivation '/nix/store/q1967cbdndahszkarh8clk2p4q48kbs6-nixos-system-lenovo-24.05.20240626.89c4987.drv' failed to build

[MattSturgeon]

I suspect this is caused by the 24.05 nixvim branch being designed for the neovim version available in nixos-24.05, though I haven't looked too closely.

You might find nixvim's "standalone build" interesting, as you could build a standalone nixvim config (using any nixvim branch) and then add the resulting package to your home.packages without needing nixvim's home-manager module.

This makes it easier to mix/match nixpkgs channels, since it is an independent build with its own pkgs.

[gmile]

@MattSturgeon thanks! I am afraid I'm too early in my nix journey to be able to understand how to use neovim 0.10 from a standalone build of nixvim in my nixos / home-manager configuration...

Reading the link you've provided as well as "Standalone Usage" didn't get me too far. If I understood correctly, I would have to split my custom nixvim configuration, based off neovim 0.10 into a separate flake, then use it as an input in my main flake?

[MattSturgeon]

You can use a separate flake, or you can just build it separately within a single flake. That's what I do in my config.

I have the flake output packages.<system>.nvim, (my nixvim config), which I then use in my home-manager configs.

I access the flake itself by passing self in as an extra special arg (here and here).

Mine probably isn't the best example because a) it's somewhat complicated by various abstractions and flake-parts modules and b) I use the same nixpkgs channel for my home/system configs as my nixvim config.

There's plenty of other example configs listed here, some of which may do something similar.