Add Solidity-friendly account structure as public input for the account inclusion proof

Makefile

@@ -9,6 +9,7 @@ submit_account:
 gen_contract_abi:
 	forge build --root contract/
 	cp contract/out/MinaBridge.sol/MinaBridge.json core/abi/MinaBridge.json
+	cp contract/out/MinaAccountValidation.sol/MinaAccountValidation.json core/abi/MinaAccountValidation.json
 
 deploy_contract: gen_contract_abi
 	@cargo run --manifest-path contract_deployer/Cargo.toml --release

contract/src/MinaAccountValidation.sol

@@ -0,0 +1,135 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.12;
+
+import "aligned_layer/contracts/src/core/AlignedLayerServiceManager.sol";
+
+error AccountIsNotVerified();
+
+contract MinaAccountValidation {
+    /// @notice Reference to the AlignedLayerServiceManager contract.
+    AlignedLayerServiceManager aligned;
+
+    constructor(address _alignedServiceAddr) {
+        aligned = AlignedLayerServiceManager(_alignedServiceAddr);
+    }
+
+    function validateAccount(
+        bytes32 proofCommitment,
+        bytes32 provingSystemAuxDataCommitment,
+        bytes20 proofGeneratorAddr,
+        bytes32 batchMerkleRoot,
+        bytes memory merkleProof,
+        uint256 verificationDataBatchIndex,
+        bytes calldata pubInput
+    ) external view returns (Account memory) {
+        bytes calldata encodedAccount = pubInput[32 + 8:];
+
+        bytes32 pubInputCommitment = keccak256(pubInput);
+
+        bool isAccountVerified = aligned.verifyBatchInclusion(
+            proofCommitment,
+            pubInputCommitment,
+            provingSystemAuxDataCommitment,
+            proofGeneratorAddr,
+            batchMerkleRoot,
+            merkleProof,
+            verificationDataBatchIndex
+        );
+
+        if (isAccountVerified) {
+            return abi.decode(encodedAccount, (Account));
+        } else {
+            revert AccountIsNotVerified();
+        }
+    }
+
+    struct Account {
+        CompressedECPoint publicKey;
+        bytes32 tokenIdKeyHash;
+        string tokenSymbol;
+        uint64 balance;
+        uint32 nonce;
+        bytes32 receiptChainHash;
+        CompressedECPoint delegate;
+        bytes32 votingFor;
+        Timing timing;
+        Permissions permissions;
+        ZkappAccount zkapp;
+    }
+
+    struct CompressedECPoint {
+        bytes32 x;
+        bool isOdd;
+    }
+
+    struct Timing {
+        uint64 initialMinimumBalance;
+        uint32 cliffTime;
+        uint64 cliffAmount;
+        uint32 vestingPeriod;
+        uint64 vestingIncrement;
+    }
+
+    enum AuthRequired {
+        None,
+        Either,
+        Proof,
+        Signature,
+        Impossible
+    }
+
+    struct Permissions {
+        AuthRequired editState;
+        AuthRequired access;
+        AuthRequired send;
+        AuthRequired rreceive;
+        AuthRequired setDelegate;
+        AuthRequired setPermissions;
+        AuthRequired setVerificationKeyAuth;
+        uint32 setVerificationKeyUint;
+        AuthRequired setZkappUri;
+        AuthRequired editActionState;
+        AuthRequired setTokenSymbol;
+        AuthRequired incrementNonce;
+        AuthRequired setVotingFor;
+        AuthRequired setTiming;
+    }
+
+    struct ZkappAccount {
+        bytes32[8] appState;
+        VerificationKey verificationKey;
+        uint32 zkappVersion;
+        bytes32[5] actionState;
+        uint32 lastActionSlot;
+        bool provedState;
+        bytes zkappUri;
+    }
+
+    struct VerificationKey {
+        ProofsVerified maxProofsVerified;
+        ProofsVerified actualWrapDomainSize;
+        WrapIndex wrapIndex;
+    }
+
+    enum ProofsVerified {
+        N0,
+        N1,
+        N2
+    }
+
+    struct WrapIndex {
+        Commitment[7] sigmaComm;
+        Commitment[15] coefficientsComm;
+        Commitment genericComm;
+        Commitment psmComm;
+        Commitment completeAddComm;
+        Commitment mulComm;
+        Commitment emulComm;
+        Commitment endomulScalarComm;
+    }
+
+    struct Commitment {
+        bytes32 x;
+        bytes32 y;
+    }
+}

contract/src/MinaBridge.sol

@@ -2,7 +2,6 @@
 pragma solidity ^0.8.12;
 
 import "aligned_layer/contracts/src/core/AlignedLayerServiceManager.sol";
-import "./Account.sol";
 
 error NewStateIsNotValid();
 error TipStateIsWrong(bytes32 pubInputTipStateHash, bytes32 tipStatehash);
@@ -127,36 +126,4 @@ contract MinaBridge {
             revert NewStateIsNotValid();
         }
     }
-
-    function isAccountVerified(
-        bytes32 proofCommitment,
-        bytes32 provingSystemAuxDataCommitment,
-        bytes20 proofGeneratorAddr,
-        bytes32 batchMerkleRoot,
-        bytes memory merkleProof,
-        uint256 verificationDataBatchIndex,
-        bytes memory pubInput
-    ) external view returns (bool) {
-        bytes32 ledgerHash;
-        bytes32 accountHash;
-        bytes32 accountIdHash;
-        assembly {
-            ledgerHash := mload(add(pubInput, 0x20))
-            accountHash := mload(add(pubInput, 0x40))
-            accountIdHash := mload(add(pubInput, 0x60))
-        }
-
-        bytes32 pubInputCommitment = keccak256(pubInput);
-
-        return
-            aligned.verifyBatchInclusion(
-                proofCommitment,
-                pubInputCommitment,
-                provingSystemAuxDataCommitment,
-                proofGeneratorAddr,
-                batchMerkleRoot,
-                merkleProof,
-                verificationDataBatchIndex
-            );
-    }
 }