feat: added module functionality

README.md

@@ -1,2 +1,82 @@
 # terraform-aws-vpc-endpoint-service
 Terraform module which creates a vpc endpoint service
+
+<!-- BEGINNING OF PRE-COMMIT-TERRAFORM DOCS HOOK -->
+## Requirements
+
+| Name | Version |
+|------|---------|
+| <a name="requirement_terraform"></a> [terraform](#requirement\_terraform) | >= 1.3.0 |
+| <a name="requirement_aws"></a> [aws](#requirement\_aws) | >= 4.67 |
+
+## Providers
+
+| Name | Version |
+|------|---------|
+| <a name="provider_aws"></a> [aws](#provider\_aws) | >= 4.67 |
+
+## Modules
+
+| Name | Source | Version |
+|------|--------|---------|
+| <a name="module_this"></a> [this](#module\_this) | justtrackio/label/null | 0.26.0 |
+
+## Resources
+
+| Name | Type |
+|------|------|
+| [aws_lb.lb](https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/lb) | resource |
+| [aws_lb_listener.listener](https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/lb_listener) | resource |
+| [aws_lb_target_group.target_group](https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/lb_target_group) | resource |
+| [aws_vpc_endpoint_service.service](https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/vpc_endpoint_service) | resource |
+| [aws_subnets.subnets](https://registry.terraform.io/providers/hashicorp/aws/latest/docs/data-sources/subnets) | data source |
+
+## Inputs
+
+| Name | Description | Type | Default | Required |
+|------|-------------|------|---------|:--------:|
+| <a name="input_additional_tag_map"></a> [additional\_tag\_map](#input\_additional\_tag\_map) | Additional key-value pairs to add to each map in `tags_as_list_of_maps`. Not added to `tags` or `id`.<br>This is for some rare cases where resources want additional configuration of tags<br>and therefore take a list of maps with tag key, value, and additional configuration. | `map(string)` | `{}` | no |
+| <a name="input_attributes"></a> [attributes](#input\_attributes) | ID element. Additional attributes (e.g. `workers` or `cluster`) to add to `id`,<br>in the order they appear in the list. New attributes are appended to the<br>end of the list. The elements of the list are joined by the `delimiter`<br>and treated as a single ID element. | `list(string)` | `[]` | no |
+| <a name="input_aws_account_id"></a> [aws\_account\_id](#input\_aws\_account\_id) | AWS account id | `string` | `null` | no |
+| <a name="input_aws_region"></a> [aws\_region](#input\_aws\_region) | AWS region | `string` | `null` | no |
+| <a name="input_context"></a> [context](#input\_context) | Single object for setting entire context at once.<br>See description of individual variables for details.<br>Leave string and numeric variables as `null` to use default value.<br>Individual variable settings (non-null) override settings in context object,<br>except for attributes, tags, and additional\_tag\_map, which are merged. | `any` | <pre>{<br>  "additional_tag_map": {},<br>  "attributes": [],<br>  "delimiter": null,<br>  "descriptor_formats": {},<br>  "enabled": true,<br>  "environment": null,<br>  "id_length_limit": null,<br>  "label_key_case": null,<br>  "label_order": [],<br>  "label_value_case": null,<br>  "labels_as_tags": [<br>    "unset"<br>  ],<br>  "name": null,<br>  "namespace": null,<br>  "regex_replace_chars": null,<br>  "stage": null,<br>  "tags": {},<br>  "tenant": null<br>}</pre> | no |
+| <a name="input_delimiter"></a> [delimiter](#input\_delimiter) | Delimiter to be used between ID elements.<br>Defaults to `-` (hyphen). Set to `""` to use no delimiter at all. | `string` | `null` | no |
+| <a name="input_descriptor_formats"></a> [descriptor\_formats](#input\_descriptor\_formats) | Describe additional descriptors to be output in the `descriptors` output map.<br>Map of maps. Keys are names of descriptors. Values are maps of the form<br>`{<br>   format = string<br>   labels = list(string)<br>}`<br>(Type is `any` so the map values can later be enhanced to provide additional options.)<br>`format` is a Terraform format string to be passed to the `format()` function.<br>`labels` is a list of labels, in order, to pass to `format()` function.<br>Label values will be normalized before being passed to `format()` so they will be<br>identical to how they appear in `id`.<br>Default is `{}` (`descriptors` output will be empty). | `any` | `{}` | no |
+| <a name="input_enabled"></a> [enabled](#input\_enabled) | Set to false to prevent the module from creating any resources | `bool` | `null` | no |
+| <a name="input_endpoint_service_acceptance_required"></a> [endpoint\_service\_acceptance\_required](#input\_endpoint\_service\_acceptance\_required) | Whether or not a consumer of this service needs to be accepted | `bool` | `false` | no |
+| <a name="input_endpoint_service_allowed_principals"></a> [endpoint\_service\_allowed\_principals](#input\_endpoint\_service\_allowed\_principals) | Principals allowed to access this VPC endpoint service | `set(string)` | `[]` | no |
+| <a name="input_environment"></a> [environment](#input\_environment) | ID element. Usually used for region e.g. 'uw2', 'us-west-2', OR role 'prod', 'staging', 'dev', 'UAT' | `string` | `null` | no |
+| <a name="input_id_length_limit"></a> [id\_length\_limit](#input\_id\_length\_limit) | Limit `id` to this many characters (minimum 6).<br>Set to `0` for unlimited length.<br>Set to `null` for keep the existing setting, which defaults to `0`.<br>Does not affect `id_full`. | `number` | `null` | no |
+| <a name="input_label_key_case"></a> [label\_key\_case](#input\_label\_key\_case) | Controls the letter case of the `tags` keys (label names) for tags generated by this module.<br>Does not affect keys of tags passed in via the `tags` input.<br>Possible values: `lower`, `title`, `upper`.<br>Default value: `title`. | `string` | `null` | no |
+| <a name="input_label_order"></a> [label\_order](#input\_label\_order) | The order in which the labels (ID elements) appear in the `id`.<br>Defaults to ["namespace", "environment", "stage", "name", "attributes"].<br>You can omit any of the 6 labels ("tenant" is the 6th), but at least one must be present. | `list(string)` | `null` | no |
+| <a name="input_label_value_case"></a> [label\_value\_case](#input\_label\_value\_case) | Controls the letter case of ID elements (labels) as included in `id`,<br>set as tag values, and output by this module individually.<br>Does not affect values of tags passed in via the `tags` input.<br>Possible values: `lower`, `title`, `upper` and `none` (no transformation).<br>Set this to `title` and set `delimiter` to `""` to yield Pascal Case IDs.<br>Default value: `lower`. | `string` | `null` | no |
+| <a name="input_labels_as_tags"></a> [labels\_as\_tags](#input\_labels\_as\_tags) | Set of labels (ID elements) to include as tags in the `tags` output.<br>Default is to include all labels.<br>Tags with empty values will not be included in the `tags` output.<br>Set to `[]` to suppress all generated tags.<br>**Notes:**<br>  The value of the `name` tag, if included, will be the `id`, not the `name`.<br>  Unlike other `null-label` inputs, the initial setting of `labels_as_tags` cannot be<br>  changed in later chained modules. Attempts to change it will be silently ignored. | `set(string)` | <pre>[<br>  "default"<br>]</pre> | no |
+| <a name="input_lb_enable_cross_zone_load_balancing"></a> [lb\_enable\_cross\_zone\_load\_balancing](#input\_lb\_enable\_cross\_zone\_load\_balancing) | Whether or not to enable cross zone load balancing for the load balancer | `bool` | `true` | no |
+| <a name="input_lb_enable_deletion_protection"></a> [lb\_enable\_deletion\_protection](#input\_lb\_enable\_deletion\_protection) | Whether or not to enable deletion protection for the load balancer | `bool` | `false` | no |
+| <a name="input_lb_subnet_ids"></a> [lb\_subnet\_ids](#input\_lb\_subnet\_ids) | Set of subnet ids to use for the load balancer | `list(string)` | `[]` | no |
+| <a name="input_lb_subnets_tags"></a> [lb\_subnets\_tags](#input\_lb\_subnets\_tags) | Map with tags to filter for subnets that the load balancer should be available in (when lb\_subnet\_ids is not set) | `map(string)` | <pre>{<br>  "Type": "private"<br>}</pre> | no |
+| <a name="input_lb_target_group_port"></a> [lb\_target\_group\_port](#input\_lb\_target\_group\_port) | Port to listen on | `number` | `8088` | no |
+| <a name="input_name"></a> [name](#input\_name) | ID element. Usually the component or solution name, e.g. 'app' or 'jenkins'.<br>This is the only ID element not also included as a `tag`.<br>The "name" tag is set to the full `id` string. There is no tag with the value of the `name` input. | `string` | `null` | no |
+| <a name="input_namespace"></a> [namespace](#input\_namespace) | ID element. Usually an abbreviation of your organization name, e.g. 'eg' or 'cp', to help ensure generated IDs are globally unique | `string` | `null` | no |
+| <a name="input_organizational_unit"></a> [organizational\_unit](#input\_organizational\_unit) | Usually used to indicate the AWS organizational unit, e.g. 'prod', 'sdlc' | `string` | `null` | no |
+| <a name="input_regex_replace_chars"></a> [regex\_replace\_chars](#input\_regex\_replace\_chars) | Terraform regular expression (regex) string.<br>Characters matching the regex will be removed from the ID elements.<br>If not set, `"/[^a-zA-Z0-9-]/"` is used to remove all characters other than hyphens, letters and digits. | `string` | `null` | no |
+| <a name="input_stage"></a> [stage](#input\_stage) | ID element. Usually used to indicate role, e.g. 'prod', 'staging', 'source', 'build', 'test', 'deploy', 'release' | `string` | `null` | no |
+| <a name="input_tags"></a> [tags](#input\_tags) | Additional tags (e.g. `{'BusinessUnit': 'XYZ'}`).<br>Neither the tag keys nor the tag values will be modified by this module. | `map(string)` | `{}` | no |
+| <a name="input_tenant"></a> [tenant](#input\_tenant) | ID element \_(Rarely used, not included by default)\_. A customer identifier, indicating who this instance of a resource is for | `string` | `null` | no |
+| <a name="input_vpc_id"></a> [vpc\_id](#input\_vpc\_id) | VPC id to filter for discovering private subnets | `string` | n/a | yes |
+
+## Outputs
+
+| Name | Description |
+|------|-------------|
+| <a name="output_lb_arn"></a> [lb\_arn](#output\_lb\_arn) | ARN of the LB |
+| <a name="output_lb_dns_name"></a> [lb\_dns\_name](#output\_lb\_dns\_name) | DNS name of the LB |
+| <a name="output_lb_name"></a> [lb\_name](#output\_lb\_name) | Name of the LB |
+| <a name="output_lb_private_ips"></a> [lb\_private\_ips](#output\_lb\_private\_ips) | Private IPs of the LB |
+| <a name="output_lb_target_group_arn"></a> [lb\_target\_group\_arn](#output\_lb\_target\_group\_arn) | ARN of the LBs target group |
+| <a name="output_vpc_endpoint_service_arn"></a> [vpc\_endpoint\_service\_arn](#output\_vpc\_endpoint\_service\_arn) | ARN of the VPC endpoint service |
+| <a name="output_vpc_endpoint_service_availability_zones"></a> [vpc\_endpoint\_service\_availability\_zones](#output\_vpc\_endpoint\_service\_availability\_zones) | AZs of the VPC endpoint service |
+| <a name="output_vpc_endpoint_service_id"></a> [vpc\_endpoint\_service\_id](#output\_vpc\_endpoint\_service\_id) | ID of the VPC endpoint service |
+| <a name="output_vpc_endpoint_service_service_name"></a> [vpc\_endpoint\_service\_service\_name](#output\_vpc\_endpoint\_service\_service\_name) | Name of the VPC endpoint service |
+| <a name="output_vpc_endpoint_service_service_type"></a> [vpc\_endpoint\_service\_service\_type](#output\_vpc\_endpoint\_service\_service\_type) | Type of the VPC endpoint service |
+<!-- END OF PRE-COMMIT-TERRAFORM DOCS HOOK -->

data.tf

@@ -0,0 +1,10 @@
+data "aws_subnets" "subnets" {
+  count = length(var.lb_subnet_ids) == 0 ? 1 : 0
+
+  filter {
+    name   = "vpc-id"
+    values = [var.vpc_id]
+  }
+
+  tags = var.lb_subnets_tags
+}

main.tf

@@ -0,0 +1,44 @@
+locals {
+  data_subnets = try(data.aws_subnets.subnets[0].ids, [])
+  subnet_ids   = coalescelist(tolist(local.data_subnets), var.lb_subnet_ids)
+}
+
+resource "aws_lb" "lb" {
+  name                             = "${module.this.id}-vpces"
+  internal                         = true
+  load_balancer_type               = "network"
+  subnets                          = local.subnet_ids
+  enable_deletion_protection       = var.lb_enable_deletion_protection
+  enable_cross_zone_load_balancing = var.lb_enable_cross_zone_load_balancing
+
+  tags = module.this.tags
+}
+
+resource "aws_lb_target_group" "target_group" {
+  name     = "${module.this.environment}-${module.this.stage}-${module.this.name}"
+  port     = var.lb_target_group_port
+  protocol = "TCP"
+  vpc_id   = var.vpc_id
+
+  tags = module.this.tags
+}
+
+resource "aws_lb_listener" "listener" {
+  load_balancer_arn = aws_lb.lb.arn
+  port              = 80
+  protocol          = "TCP"
+  default_action {
+    type             = "forward"
+    target_group_arn = aws_lb_target_group.target_group.arn
+  }
+
+  tags = module.this.tags
+}
+
+resource "aws_vpc_endpoint_service" "service" {
+  acceptance_required        = var.endpoint_service_acceptance_required
+  network_load_balancer_arns = [aws_lb.lb.arn]
+  allowed_principals         = var.endpoint_service_allowed_principals
+
+  tags = module.this.tags
+}

outputs.tf

@@ -0,0 +1,49 @@
+output "lb_arn" {
+  description = "ARN of the LB"
+  value       = aws_lb.lb.arn
+}
+
+output "lb_name" {
+  description = "Name of the LB"
+  value       = aws_lb.lb.name
+}
+
+output "lb_dns_name" {
+  description = "DNS name of the LB"
+  value       = aws_lb.lb.dns_name
+}
+
+output "lb_private_ips" {
+  description = "Private IPs of the LB"
+  value       = [for mapping in aws_lb.lb.subnet_mapping : mapping.private_ipv4_address]
+}
+
+output "lb_target_group_arn" {
+  description = "ARN of the LBs target group"
+  value       = aws_lb_target_group.target_group.arn
+}
+
+output "vpc_endpoint_service_arn" {
+  description = "ARN of the VPC endpoint service"
+  value       = aws_vpc_endpoint_service.service.arn
+}
+
+output "vpc_endpoint_service_id" {
+  description = "ID of the VPC endpoint service"
+  value       = aws_vpc_endpoint_service.service.id
+}
+
+output "vpc_endpoint_service_service_name" {
+  description = "Name of the VPC endpoint service"
+  value       = aws_vpc_endpoint_service.service.service_name
+}
+
+output "vpc_endpoint_service_service_type" {
+  description = "Type of the VPC endpoint service"
+  value       = aws_vpc_endpoint_service.service.service_type
+}
+
+output "vpc_endpoint_service_availability_zones" {
+  description = "AZs of the VPC endpoint service"
+  value       = aws_vpc_endpoint_service.service.availability_zones
+}

variables.tf

@@ -0,0 +1,48 @@
+variable "endpoint_service_acceptance_required" {
+  type        = bool
+  description = "Whether or not a consumer of this service needs to be accepted"
+  default     = false
+}
+
+variable "endpoint_service_allowed_principals" {
+  type        = set(string)
+  description = "Principals allowed to access this VPC endpoint service"
+  default     = []
+}
+
+variable "lb_enable_cross_zone_load_balancing" {
+  type        = bool
+  description = "Whether or not to enable cross zone load balancing for the load balancer"
+  default     = true
+}
+
+variable "lb_enable_deletion_protection" {
+  type        = bool
+  description = "Whether or not to enable deletion protection for the load balancer"
+  default     = false
+}
+
+variable "lb_target_group_port" {
+  type        = number
+  description = "Port to listen on"
+  default     = 8088
+}
+
+variable "lb_subnets_tags" {
+  type        = map(string)
+  description = "Map with tags to filter for subnets that the load balancer should be available in (when lb_subnet_ids is not set)"
+  default = {
+    Type = "private"
+  }
+}
+
+variable "lb_subnet_ids" {
+  type        = list(string)
+  description = "Set of subnet ids to use for the load balancer"
+  default     = []
+}
+
+variable "vpc_id" {
+  type        = string
+  description = "VPC id to filter for discovering private subnets"
+}

versions.tf

@@ -0,0 +1,9 @@
+terraform {
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+      version = ">= 4.67"
+    }
+  }
+  required_version = ">= 1.3.0"
+}