Add check 'python-include-tests'

overlays/python-include-tests.nix

@@ -0,0 +1,28 @@
+{ builtAttrs
+, packageSet
+, namePositions
+}@attrs:
+
+final: prev:
+let
+  inherit (prev) lib;
+  inherit (import ../lib { inherit lib; }) checkBuildPythonPackageFor;
+
+  checkDerivation = drvArgs: drv:
+    lib.singleton {
+      name = "python-include-tests";
+      cond = let
+        hasCheckPhase = drvArgs ? checkPhase;
+        hasDoCheckFalse = (drvArgs ? doCheck) && (drvArgs.doCheck == false);
+        hasPytestCheckHook = drvArgs ? checkInputs && lib.any (n: n.name == "pytest-check-hook") drvArgs.checkInputs;
+        hasPythonImportsCheck = drvArgs ? pythonImportsCheck;
+
+        hasActiveCheckPhase = (hasCheckPhase || hasPytestCheckHook) && (! hasDoCheckFalse);
+      in
+        ! (hasActiveCheckPhase || hasPythonImportsCheck);
+      msg = ''
+        Add a checkPhase for tests, or at least pythonImportsCheck.
+      '';
+    };
+  in
+checkBuildPythonPackageFor checkDerivation attrs final prev

run-tests.py

@@ -143,6 +143,19 @@ def __iter__(self):
             ]
         )
 
+        yield make_test_rule(
+            'python-include-tests',
+            [
+                'no-tests-no-import-checks',
+                'tests-disabled-no-import-checks',
+            ],
+            [
+                'pytest-check-hook',
+                'explicit-check-phase',
+                'has-imports-check'
+            ]
+        )
+
         yield make_test_rule(
             'unnecessary-parallel-building',
             [

tests/default.nix

@@ -12,6 +12,7 @@
   patch-phase = pkgs.callPackage ./patch-phase { };
   python-explicit-check-phase = pkgs.python3.pkgs.callPackage ./python-explicit-check-phase { };
   python-imports-check-typo = pkgs.python3.pkgs.callPackage ./python-imports-check-typo { };
+  python-include-tests = pkgs.python3.pkgs.callPackage ./python-include-tests { };
   unclear-gpl = pkgs.callPackage ./unclear-gpl { };
   unnecessary-parallel-building = pkgs.callPackage ./unnecessary-parallel-building { };
 }

tests/python-include-tests/default.nix

@@ -0,0 +1,13 @@
+{ callPackage
+}:
+
+{
+  # positive cases
+  no-tests-no-import-checks = callPackage ./no-tests-no-import-checks.nix { };
+  tests-disabled-no-import-checks = callPackage ./tests-disabled-no-import-checks.nix { };
+
+  # negative cases
+  pytest-check-hook = callPackage ./pytest-check-hook.nix { };
+  explicit-check-phase = callPackage ./explicit-check-phase.nix { };
+  has-imports-check = callPackage ./has-imports-check.nix { };
+}

tests/python-include-tests/explicit-check-phase.nix

@@ -0,0 +1,10 @@
+{ buildPythonPackage
+}:
+
+buildPythonPackage {
+  pname = "package";
+
+  src = ../fixtures/make;
+
+  checkPhase = "";
+}

tests/python-include-tests/has-imports-check.nix

@@ -0,0 +1,10 @@
+{ buildPythonPackage
+}:
+
+buildPythonPackage {
+  pname = "package";
+
+  src = ../fixtures/make;
+
+  pythonImportsCheck = [];
+}

tests/python-include-tests/no-tests-no-import-checks.nix

@@ -0,0 +1,8 @@
+{ buildPythonPackage
+}:
+
+buildPythonPackage {
+  pname = "package";
+
+  src = ../fixtures/make;
+}

tests/python-include-tests/pytest-check-hook.nix

@@ -0,0 +1,11 @@
+{ buildPythonPackage
+, pytestCheckHook
+}:
+
+buildPythonPackage {
+  pname = "package";
+
+  src = ../fixtures/make;
+
+  checkInputs = [ pytestCheckHook ];
+}

tests/python-include-tests/tests-disabled-no-import-checks.nix

@@ -0,0 +1,12 @@
+{ buildPythonPackage
+, pytestCheckHook
+}:
+
+buildPythonPackage {
+  pname = "package";
+
+  src = ../fixtures/make;
+
+  checkInputs = [ pytestCheckHook ];
+  doCheck = false;
+}