cmake: Build bitcoin-qt executable

CMakeLists.txt

@@ -218,7 +218,7 @@ add_threads_if_needed()
 include(AddBoostIfNeeded)
 add_boost_if_needed()
 
-if(BUILD_DAEMON OR BUILD_CLI OR BUILD_TESTS OR BUILD_BENCH)
+if(BUILD_DAEMON OR WITH_GUI OR BUILD_CLI OR BUILD_TESTS OR BUILD_BENCH)
   find_package(Libevent 2.1.8 MODULE REQUIRED)
 endif()
 
@@ -296,6 +296,8 @@ else()
   unset(c_flags_debug_overridden)
 endif()
 
+include(cmake/optional_qt.cmake)
+
 include(cmake/optional.cmake)
 
 # Don't allow extended (non-ASCII) symbols in identifiers. This is easier for code review.
@@ -409,6 +411,7 @@ message("Configure summary")
 message("=================")
 message("Executables:")
 message("  bitcoind ............................ ${BUILD_DAEMON}")
+message("  bitcoin-qt (GUI) .................... ${WITH_GUI}")
 message("  bitcoin-cli ......................... ${BUILD_CLI}")
 message("  bitcoin-tx .......................... ${BUILD_TX}")
 message("  bitcoin-util ........................ ${BUILD_UTIL}")

cmake/optional_qt.cmake

@@ -0,0 +1,50 @@
+# Copyright (c) 2023-present The Bitcoin Core developers
+# Distributed under the MIT software license, see the accompanying
+# file COPYING or https://opensource.org/license/mit/.
+
+set(WITH_GUI "AUTO" CACHE STRING "Build GUI ([AUTO], Qt5, OFF)")
+set(with_gui_values AUTO Qt5 OFF)
+if(NOT WITH_GUI IN_LIST with_gui_values)
+  message(FATAL_ERROR "WITH_GUI value is \"${WITH_GUI}\", but must be one of \"AUTO\", \"Qt5\" or \"OFF\".")
+endif()
+
+if(WITH_GUI)
+  set(QT_NO_CREATE_VERSIONLESS_FUNCTIONS ON)
+  set(QT_NO_CREATE_VERSIONLESS_TARGETS ON)
+
+  set(qt5_brew_prefix)
+  if(CMAKE_HOST_APPLE)
+    find_program(HOMEBREW_EXECUTABLE brew)
+    if(HOMEBREW_EXECUTABLE)
+      execute_process(
+        COMMAND ${HOMEBREW_EXECUTABLE} --prefix qt@5
+        OUTPUT_VARIABLE qt5_brew_prefix
+        ERROR_QUIET
+        OUTPUT_STRIP_TRAILING_WHITESPACE
+      )
+    endif()
+  endif()
+
+  if(WITH_GUI STREQUAL "AUTO")
+    # The PATH_SUFFIXES option is required on OpenBSD systems.
+    find_package(QT NAMES Qt5
+      COMPONENTS Core
+      HINTS ${qt5_brew_prefix}
+      PATH_SUFFIXES Qt5
+    )
+    if(QT_FOUND)
+      set(WITH_GUI Qt${QT_VERSION_MAJOR})
+      if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
+        enable_language(OBJCXX)
+        set(CMAKE_OBJCXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO}")
+        set(CMAKE_OBJCXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
+        set(CMAKE_OBJCXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG}")
+        set(CMAKE_OBJCXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL}")
+      endif()
+    else()
+      message(WARNING "Qt not found, disabling.\n"
+                      "To skip this warning check, use \"-DWITH_GUI=OFF\".\n")
+      set(WITH_GUI OFF)
+    endif()
+  endif()
+endif()

depends/packages/qt.mk

@@ -263,13 +263,14 @@ define $(package)_build_cmds
   $(MAKE)
 endef
 
+# TODO: Investigate whether specific targets can be used here to minimize the amount of files/components installed.
 define $(package)_stage_cmds
-  $(MAKE) -C qtbase/src INSTALL_ROOT=$($(package)_staging_dir) $(addsuffix -install_subtargets,$(addprefix sub-,$($(package)_qt_libs))) && \
-  $(MAKE) -C qttools/src/linguist INSTALL_ROOT=$($(package)_staging_dir) $(addsuffix -install_subtargets,$(addprefix sub-,$($(package)_linguist_tools))) && \
+  $(MAKE) -C qtbase INSTALL_ROOT=$($(package)_staging_dir) install && \
+  $(MAKE) -C qttools INSTALL_ROOT=$($(package)_staging_dir) install && \
   $(MAKE) -C qttranslations INSTALL_ROOT=$($(package)_staging_dir) install_subtargets
 endef
 
 define $(package)_postprocess_cmds
-  rm -rf native/mkspecs/ native/lib/ lib/cmake/ && \
-  rm -f lib/lib*.la lib/*.prl plugins/*/*.prl
+  rm -rf doc/ native/lib/ && \
+  rm -f lib/lib*.la
 endef

src/CMakeLists.txt

@@ -320,6 +320,11 @@ if(BUILD_UTIL)
 endif()
 
 
+if(WITH_GUI)
+  add_subdirectory(qt)
+endif()
+
+
 add_subdirectory(test/util)
 if(BUILD_BENCH)
   add_subdirectory(bench)

src/qt/CMakeLists.txt

@@ -0,0 +1,207 @@
+# Copyright (c) 2023-present The Bitcoin Core developers
+# Distributed under the MIT software license, see the accompanying
+# file COPYING or https://opensource.org/license/mit/.
+
+function(import_plugins target)
+  if(QT_IS_STATIC)
+    set(plugins Qt5::QMinimalIntegrationPlugin)
+    if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
+      list(APPEND plugins Qt5::QXcbIntegrationPlugin)
+    elseif(WIN32)
+      list(APPEND plugins Qt5::QWindowsIntegrationPlugin Qt5::QWindowsVistaStylePlugin)
+    elseif(APPLE)
+      list(APPEND plugins Qt5::QCocoaIntegrationPlugin Qt5::QMacStylePlugin)
+    endif()
+    qt5_import_plugins(${target}
+        INCLUDE ${plugins}
+        EXCLUDE_BY_TYPE imageformats iconengines
+    )
+  endif()
+endfunction()
+
+# See:
+#  - https://cmake.org/cmake/help/latest/manual/cmake-qt.7.html
+#  - https://doc.qt.io/qt-5/cmake-manual.html
+
+set(CMAKE_AUTOMOC ON)
+set(CMAKE_AUTORCC ON)
+set(CMAKE_AUTOUIC ON)
+set(CMAKE_AUTOUIC_SEARCH_PATHS forms)
+
+set(qt_minimum_required_version 5.11.3)
+
+set(qt_components Core Gui Widgets Network LinguistTools)
+
+if(CMAKE_CROSSCOMPILING)
+  # The find_package(Qt ...) function internally uses find_library()
+  # calls for all dependencies to ensure their availability.
+  # In turn, the find_library() inspects the well-known locations
+  # on the file system; therefore, it must be able to find
+  # platform-specific system libraries, for example:
+  # /usr/x86_64-w64-mingw32/lib/libm.a or /usr/arm-linux-gnueabihf/lib/libm.a.
+  set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY BOTH)
+endif()
+
+find_package(Qt5 ${qt_minimum_required_version} REQUIRED
+  COMPONENTS ${qt_components}
+  HINTS ${qt5_brew_prefix}
+  PATH_SUFFIXES Qt5 # Required on OpenBSD systems.
+)
+unset(qt_components)
+message(STATUS "Found Qt: ${Qt5_DIR} (found suitable version \"${Qt5_VERSION}\", minimum required is \"${qt_minimum_required_version}\")")
+unset(qt_minimum_required_version)
+
+include(CMakePushCheckState)
+cmake_push_check_state(RESET)
+set(CMAKE_REQUIRED_LIBRARIES Qt5::Core)
+include(CheckCXXSourceCompiles)
+check_cxx_source_compiles("
+  #include <QtGlobal>
+
+  #if !defined(QT_STATIC)
+  #error Qt is not static
+  #endif
+  int main() {}
+  " QT_IS_STATIC
+)
+cmake_pop_check_state()
+
+# TODO: The file(GLOB ...) command should be replaced with an explicit
+# file list. Such a change must be synced with the corresponding change
+# to https://github.com/bitcoin-core/bitcoin-maintainer-tools/blob/main/update-translations.py
+file(GLOB ts_files RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} locale/*.ts)
+set_source_files_properties(${ts_files} PROPERTIES OUTPUT_LOCATION ${CMAKE_CURRENT_BINARY_DIR}/locale)
+qt5_add_translation(qm_files ${ts_files})
+
+configure_file(bitcoin_locale.qrc bitcoin_locale.qrc COPYONLY)
+
+add_library(bitcoinqt STATIC EXCLUDE_FROM_ALL
+  bantablemodel.cpp
+  bitcoin.cpp
+  bitcoinaddressvalidator.cpp
+  bitcoinamountfield.cpp
+  bitcoingui.cpp
+  bitcoinunits.cpp
+  clientmodel.cpp
+  csvmodelwriter.cpp
+  guiutil.cpp
+  initexecutor.cpp
+  intro.cpp
+  modaloverlay.cpp
+  networkstyle.cpp
+  notificator.cpp
+  optionsdialog.cpp
+  optionsmodel.cpp
+  peertablemodel.cpp
+  peertablesortproxy.cpp
+  platformstyle.cpp
+  qvalidatedlineedit.cpp
+  qvaluecombobox.cpp
+  rpcconsole.cpp
+  splashscreen.cpp
+  trafficgraphwidget.cpp
+  utilitydialog.cpp
+  $<$<PLATFORM_ID:Windows>:winshutdownmonitor.cpp>
+  $<$<PLATFORM_ID:Darwin>:macdockiconhandler.mm>
+  $<$<PLATFORM_ID:Darwin>:macnotificationhandler.mm>
+  $<$<PLATFORM_ID:Darwin>:macos_appnap.mm>
+  bitcoin.qrc
+  ${CMAKE_CURRENT_BINARY_DIR}/bitcoin_locale.qrc
+)
+target_compile_definitions(bitcoinqt
+  PUBLIC
+    QT_NO_KEYWORDS
+    QT_USE_QSTRINGBUILDER
+)
+target_include_directories(bitcoinqt
+  PUBLIC
+    $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/src>
+)
+set_property(SOURCE macnotificationhandler.mm
+  # Ignore warnings "'NSUserNotificationCenter' is deprecated: first deprecated in macOS 11.0".
+  APPEND PROPERTY COMPILE_OPTIONS -Wno-deprecated-declarations
+)
+target_link_libraries(bitcoinqt
+  PUBLIC
+    Qt5::Widgets
+  PRIVATE
+    core_interface
+    bitcoin_cli
+    leveldb
+    Boost::headers
+    $<TARGET_NAME_IF_EXISTS:NATPMP::NATPMP>
+    $<TARGET_NAME_IF_EXISTS:MiniUPnPc::MiniUPnPc>
+    $<$<PLATFORM_ID:Darwin>:-framework\ AppKit>
+    $<$<CXX_COMPILER_ID:MSVC>:shlwapi>
+)
+
+if(ENABLE_WALLET)
+  target_sources(bitcoinqt
+    PRIVATE
+      addressbookpage.cpp
+      addresstablemodel.cpp
+      askpassphrasedialog.cpp
+      coincontroldialog.cpp
+      coincontroltreewidget.cpp
+      createwalletdialog.cpp
+      editaddressdialog.cpp
+      openuridialog.cpp
+      overviewpage.cpp
+      paymentserver.cpp
+      psbtoperationsdialog.cpp
+      qrimagewidget.cpp
+      receivecoinsdialog.cpp
+      receiverequestdialog.cpp
+      recentrequeststablemodel.cpp
+      sendcoinsdialog.cpp
+      sendcoinsentry.cpp
+      signverifymessagedialog.cpp
+      transactiondesc.cpp
+      transactiondescdialog.cpp
+      transactionfilterproxy.cpp
+      transactionoverviewwidget.cpp
+      transactionrecord.cpp
+      transactiontablemodel.cpp
+      transactionview.cpp
+      walletcontroller.cpp
+      walletframe.cpp
+      walletmodel.cpp
+      walletmodeltransaction.cpp
+      walletview.cpp
+  )
+  target_link_libraries(bitcoinqt
+    PRIVATE
+      bitcoin_wallet
+      Qt5::Network
+  )
+endif()
+
+if(QT_IS_STATIC)
+  # We want to define static plugins to link ourselves, thus preventing
+  # automatic linking against a "sane" set of default static plugins.
+  qt5_import_plugins(bitcoinqt
+      EXCLUDE_BY_TYPE bearer iconengines imageformats platforms styles
+  )
+endif()
+
+add_executable(bitcoin-qt
+  main.cpp
+  ../init/bitcoin-qt.cpp
+)
+
+target_link_libraries(bitcoin-qt
+  core_interface
+  bitcoinqt
+  bitcoin_node
+)
+
+import_plugins(bitcoin-qt)
+
+if(WIN32)
+  set_target_properties(bitcoin-qt PROPERTIES WIN32_EXECUTABLE TRUE)
+endif()
+
+install(TARGETS bitcoin-qt
+  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+  COMPONENT GUI
+)