Cannot register CLICK events on items inside an item dragged with Gestouch

[PippoFlash]

Hi,
I have a Sprite who can successfully been panned around.
There are children of this sprite which are registered to listen to CLICK events.
Those events do not get fires. If I activate the TAP event in gestouch, target.target registers the container sprite, not the InteractivObjects inside the sprite.
Tried all possible permutations. Any suggestion?
thanks
BTW Gestouch rocks.

[fljot]

Gestouch doesn't stop any events propagation. Everything works just fine.

package {

import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.events.TouchEvent;

import org.gestouch.core.Gestouch;
import org.gestouch.events.GestureEvent;
import org.gestouch.extensions.native.NativeDisplayListAdapter;
import org.gestouch.extensions.native.NativeTouchHitTester;
import org.gestouch.gestures.PanGesture;
import org.gestouch.input.NativeInputAdapter;

public class Main extends Sprite {

    public function Main() {

        Gestouch.inputAdapter = new NativeInputAdapter(stage);
        Gestouch.addDisplayListAdapter(DisplayObject, new NativeDisplayListAdapter());
        Gestouch.addTouchHitTester(new NativeTouchHitTester(stage));

        var pannable:Sprite = new Sprite();
        addChild(pannable);

        var pan:PanGesture = new PanGesture(pannable);
        pan.addEventListener(GestureEvent.GESTURE_BEGAN, onPan);
        pan.addEventListener(GestureEvent.GESTURE_CHANGED, onPan);

        var child:Sprite = new Sprite();
        child.graphics.beginFill(0xCCCCCC);
        child.graphics.drawCircle(0, 0, 100);
        child.graphics.endFill();
        child.addEventListener(MouseEvent.CLICK, onChildTouch);
        child.addEventListener(TouchEvent.TOUCH_BEGIN, onChildTouch);
        child.addEventListener(TouchEvent.TOUCH_END, onChildTouch);
        pannable.addChild(child)
    }

    private function onPan(event:GestureEvent):void
    {
        trace("gesture recognized", event);
    }

    private function onChildTouch(event:Event):void
    {
        trace("child interactive event", event);
    }
}
}

[PippoFlash]

Weird since it doesn't work to me. I had to implement event tunneling, probably because I use a personal events framework quite complex, it gets in the way somehow. Thank you for your answer.