Fixes BLEScanResults to be used by reference

[SuGlider]

Description of Change

A BLEScanResults object is returned from BLEScan methods, causing issues because its same copy is released more than one time, causing HEAP corruption.

To fix it BLEScanResults should be used as a contained class, by reference and not copy.
This is the same done with BLEScan*, for instance.

Tests scenarios

Tested with ESP32 using this sketch that causes the issue, before the change is done (previous version):

#include <BLEDevice.h>
#include <BLEUtils.h>
#include <BLEScan.h>
#include <BLEAdvertisedDevice.h>

int scanTime = 5; //In seconds
BLEScan* pBLEScan;

void setup() {
  Serial.begin(115200);
  Serial.println("Scanning...");

  BLEDevice::init("");
  pBLEScan = BLEDevice::getScan(); //create new scan
  pBLEScan->setActiveScan(true); //active scan uses more power, but get results faster
  pBLEScan->setInterval(100);
  pBLEScan->setWindow(99);  // less or equal setInterval value
}

void myBLEScanFunction() {
  BLEScanResults foundDevices = pBLEScan->start(scanTime, false);
  Serial.print("Devices found: ");
  Serial.println(foundDevices.getCount());
  Serial.println("Scan done!");
  pBLEScan->clearResults();   // delete results fromBLEScan buffer to release memory
}

void loop() {
 myBLEScanFunction(); // crashes when returning from the function with corrupted HEAP
 delay(2000);
}

After the fix, it shall use a BLEScanResults * as reference, instead of the copy of the object as before.

void myBLEScanFunction() {
  BLEScanResults *foundDevices = pBLEScan->start(scanTime, false);
  Serial.print("Devices found: ");
  Serial.println(foundDevices->getCount());
  Serial.println("Scan done!");
  pBLEScan->clearResults();   // delete results fromBLEScan buffer to release memory
}

Related links

Fix #8751

[SuGlider]

@P-R-O-C-H-Y - This change shuold be added to the migration guide.

[lucasssvaz]

LGTM