Automatic version bumping

app/build.gradle

@@ -1,5 +1,5 @@
 apply plugin: 'com.android.application'
-
+apply plugin: 'org.ajoberstar.grgit'
 android {
     compileSdkVersion 32
 
@@ -60,3 +60,78 @@ dependencies {
     androidTestImplementation 'androidx.test.ext:junit:1.1.3'
     androidTestImplementation 'androidx.test.espresso:espresso-core:3.4.0'
 }
+
+
+
+task releaseClean {
+    doLast {
+        if (!grgit.repository.jgit.status().call().clean) {
+            throw new GradleException('Git status is not clean')
+        }
+    }
+}
+
+// Task parameters:
+//    version -> if available will specify new versionName directly and ignores the `type` parameter.
+//    type[major|minor|patch] -> will specify how the version bumping occurs.
+task releasePrepare(dependsOn: releaseClean) {
+    doLast {
+        def versionCode = android.defaultConfig.versionCode
+        def versionName = android.defaultConfig.versionName
+
+        if (versionName.indexOf("-") > -1) {
+            versionName = versionName.split("-")[0]
+        }
+
+        // Set new version name from input parameters.
+        def newVersionName
+        if (project.properties.containsKey("version")){
+            newVersionName = project.properties["version"]
+        }else {
+            def (major, minor, patch) = versionName.tokenize('.')
+            switch (type) {
+                case "major":
+                    major = major.toInteger() + 1
+                    minor = 0
+                    patch = 0
+                    break
+                case "minor":
+                    minor = minor.toInteger() + 1
+                    break
+                case "patch":
+                    patch = patch.toInteger() + 1
+                    break
+            }
+            newVersionName = "$major.$minor.$patch"
+        }
+
+        def newVersionCode = versionCode + 1
+        println "Bumping versionName from $versionName to $newVersionName"
+        println "Bumping versionCode from $versionCode to $newVersionCode"
+
+        // Prepare the release commit with the specific tag.
+        String buildText = buildFile.getText()
+        buildText = buildText.replaceFirst(/versionName(\s+.*)/, "versionName '$newVersionName'")
+        buildText = buildText.replaceFirst(/versionCode(\s+.*)/, "versionCode $newVersionCode")
+        buildFile.setText(buildText) //replace the build file's text
+        grgit.add(patterns: ['app/build.gradle'])
+        grgit.commit(message: "[gradle-release-task] prepare release vitabu-$newVersionName")
+        grgit.tag.add {
+            name = newVersionName
+            message = "Release of $newVersionName"
+        }
+
+        // Prepare for next development iteration.
+        buildText = buildFile.getText()
+        buildText = buildText.replaceFirst(/versionName(\s+.*)/, "versionName '$newVersionName-SNAPSHOT'")
+        buildFile.setText(buildText) //replace the build file's text
+        grgit.add(patterns: ['app/build.gradle'])
+        grgit.commit(message: "[gradle-release-task] prepare for next development iteration")
+    }
+}
+
+task performRelease(dependsOn: releaseClean) {
+    doLast {
+        grgit.push()
+    }
+}

build.gradle

@@ -7,7 +7,7 @@ buildscript {
     }
     dependencies {
         classpath 'com.android.tools.build:gradle:7.1.2'
-
+        classpath 'org.ajoberstar:gradle-git:+'
         // NOTE: Do not place your application dependencies here; they belong
         // in the individual module build.gradle files
     }
@@ -26,3 +26,4 @@ allprojects {
 task clean(type: Delete) {
     delete rootProject.buildDir
 }
+