Add InputMethod View

.github/workflows/main.yml

@@ -15,7 +15,7 @@ jobs:
     - name: Install Dependencies
       run: |
         apt update
-        apt install -y meson libgranite-dev libswitchboard-2.0-dev libxml2-dev libgnomekbd-dev libxklavier-dev valac
+        apt install -y meson libgranite-dev libswitchboard-2.0-dev libxml2-dev libgnomekbd-dev libibus-1.0-dev libxklavier-dev valac
     - name: Build
       env:
         DESTDIR: out

README.md

@@ -11,6 +11,7 @@ You'll need the following dependencies:
 * libgnomekbd-dev
 * libgranite-dev
 * libgtk-3-dev
+* libibus-1.0-dev
 * libxklavier-dev
 * libxml2-dev
 * meson

po/POTFILES

@@ -1,5 +1,12 @@
 src/Plug.vala
+src/InputMethod/AddEnginesList.vala
+src/InputMethod/Utils.vala
 src/Dialogs/ConflictDialog.vala
+src/Dialogs/InstallEngineDialog.vala
+src/Dialogs/ProgressDialog.vala
+src/InputMethod/Installer/aptd-client.vala
+src/InputMethod/Installer/InstallList.vala
+src/InputMethod/Installer/UbuntuInstaller.vala
 src/Layout/AdvancedSettingsGrid.vala
 src/Layout/AdvancedSettingsPanel.vala
 src/Layout/Handler.vala
@@ -11,8 +18,12 @@ src/Shortcuts/Settings.vala
 src/Shortcuts/Shortcut.vala
 src/Views/AbstractPage.vala
 src/Views/Behavior.vala
+src/Views/InputMethod.vala
 src/Views/Layout.vala
 src/Views/Shortcuts.vala
+src/Widgets/InputMethod/AddEnginesPopover.vala
+src/Widgets/InputMethod/EnginesRow.vala
+src/Widgets/InputMethod/LanguagesRow.vala
 src/Widgets/Layout/AddLayoutPopover.vala
 src/Widgets/Layout/Display.vala
 src/Widgets/Shortcuts/CustomTree.vala

src/Dialogs/InstallEngineDialog.vala

@@ -0,0 +1,140 @@
+/*
+* Copyright 2019-2020 elementary, Inc. (https://elementary.io)
+*
+* This program is free software: you can redistribute it and/or modify
+* it under the terms of the GNU General Public License as published by
+* the Free Software Foundation, either version 3 of the License, or
+* (at your option) any later version.
+*
+* This program is distributed in the hope that it will be useful,
+* but WITHOUT ANY WARRANTY; without even the implied warranty of
+* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+* GNU General Public License for more details.
+*
+* You should have received a copy of the GNU General Public License
+* along with this program.  If not, see <https://www.gnu.org/licenses/>.
+*/
+
+public class Pantheon.Keyboard.InputMethodPage.InstallEngineDialog : Granite.MessageDialog {
+    private InstallList? engines_filter;
+
+    public InstallEngineDialog (Gtk.Window parent) {
+        Object (
+            primary_text: _("Choose an engine to install"),
+            secondary_text: _("Select an engine from the list to install and use."),
+            image_icon: new ThemedIcon ("extension"),
+            transient_for: parent,
+            buttons: Gtk.ButtonsType.CANCEL
+        );
+    }
+
+    construct {
+        var languages_list = new Gtk.ListBox () {
+            activate_on_single_click = true,
+            expand = true,
+            selection_mode = Gtk.SelectionMode.NONE
+        };
+
+        foreach (var language in InstallList.get_all ()) {
+            var lang = new LanguagesRow (language);
+            languages_list.add (lang);
+        }
+
+        var back_button = new Gtk.Button.with_label (_("Languages")) {
+            halign = Gtk.Align.START,
+            margin = 6
+        };
+        back_button.get_style_context ().add_class (Granite.STYLE_CLASS_BACK_BUTTON);
+
+        var language_title = new Gtk.Label ("");
+
+        var language_header = new Gtk.Box (Gtk.Orientation.HORIZONTAL, 6);
+        language_header.pack_start (back_button);
+        language_header.set_center_widget (language_title);
+
+        var listbox = new Gtk.ListBox () {
+            expand = true
+        };
+        listbox.set_filter_func (filter_function);
+        listbox.set_sort_func (sort_function);
+
+        foreach (var language in InstallList.get_all ()) {
+            foreach (var engine in language.get_components ()) {
+                listbox.add (new EnginesRow (engine));
+            }
+        }
+
+        var scrolled = new Gtk.ScrolledWindow (null, null);
+        scrolled.add (listbox);
+
+        var engine_list_grid = new Gtk.Grid () {
+            orientation = Gtk.Orientation.VERTICAL
+        };
+        engine_list_grid.get_style_context ().add_class (Gtk.STYLE_CLASS_VIEW);
+        engine_list_grid.add (language_header);
+        engine_list_grid.add (new Gtk.Separator (Gtk.Orientation.HORIZONTAL));
+        engine_list_grid.add (scrolled);
+
+        var stack = new Gtk.Stack () {
+            height_request = 200,
+            width_request = 300,
+            transition_type = Gtk.StackTransitionType.SLIDE_LEFT_RIGHT
+        };
+        stack.add (languages_list);
+        stack.add (engine_list_grid);
+
+        var frame = new Gtk.Frame (null);
+        frame.add (stack);
+
+        custom_bin.add (frame);
+        custom_bin.show_all ();
+
+        var install_button = add_button (_("Install"), Gtk.ResponseType.OK);
+        install_button.sensitive = false;
+        install_button.get_style_context ().add_class (Gtk.STYLE_CLASS_SUGGESTED_ACTION);
+
+        languages_list.row_activated.connect ((row) => {
+            stack.visible_child = engine_list_grid;
+            language_title.label = ((LanguagesRow) row).language.get_name ();
+            engines_filter = ((LanguagesRow) row).language;
+            listbox.invalidate_filter ();
+            var adjustment = scrolled.get_vadjustment ();
+            adjustment.set_value (adjustment.lower);
+        });
+
+        back_button.clicked.connect (() => {
+            stack.visible_child = languages_list;
+            install_button.sensitive = false;
+        });
+
+        listbox.selected_rows_changed.connect (() => {
+            foreach (var engines_row in listbox.get_children ()) {
+                ((EnginesRow) engines_row).selected = false;
+            }
+
+            ((EnginesRow) listbox.get_selected_row ()).selected = true;
+            install_button.sensitive = true;
+        });
+
+        response.connect ((response_id) => {
+            if (response_id == Gtk.ResponseType.OK) {
+                string engine_to_install = ((EnginesRow) listbox.get_selected_row ()).engine_name;
+                UbuntuInstaller.get_default ().install (engine_to_install);
+            }
+        });
+    }
+
+    [CCode (instance_pos = -1)]
+    private bool filter_function (Gtk.ListBoxRow row) {
+        if (InstallList.get_language_from_engine_name (((EnginesRow) row).engine_name) == engines_filter) {
+            return true;
+        }
+
+        return false;
+    }
+
+    [CCode (instance_pos = -1)]
+    private int sort_function (Gtk.ListBoxRow row1, Gtk.ListBoxRow row2) {
+        return ((EnginesRow) row1).engine_name.collate (((EnginesRow) row1).engine_name);
+    }
+}

src/Dialogs/ProgressDialog.vala

@@ -0,0 +1,82 @@
+/*
+* Copyright 2011-2020 elementary, Inc. (https://elementary.io)
+*
+* This program is free software: you can redistribute it
+* and/or modify it under the terms of the GNU Lesser General Public License as
+* published by the Free Software Foundation, either version 3 of the
+* License, or (at your option) any later version.
+*
+* This program is distributed in the hope that it will be
+* useful, but WITHOUT ANY WARRANTY; without even the implied warranty of
+* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
+* Public License for more details.
+*
+* You should have received a copy of the GNU General Public License along
+* with this program. If not, see http://www.gnu.org/licenses/.
+*/
+
+public class Pantheon.Keyboard.InputMethodPage.ProgressDialog : Gtk.Dialog {
+    public int progress {
+        set {
+            if (value >= 100) {
+                destroy ();
+            }
+
+            progress_bar.fraction = value / 100.0;
+        }
+    }
+
+    private Gtk.ProgressBar progress_bar;
+
+    construct {
+        var image = new Gtk.Image.from_icon_name ("preferences-desktop-locale", Gtk.IconSize.DIALOG) {
+            valign = Gtk.Align.START
+        };
+
+        var primary_label = new Gtk.Label (null) {
+            max_width_chars = 50,
+            wrap = true,
+            xalign = 0
+        };
+        primary_label.get_style_context ().add_class (Granite.STYLE_CLASS_PRIMARY_LABEL);
+
+        unowned UbuntuInstaller installer = UbuntuInstaller.get_default ();
+        switch (installer.transaction_mode) {
+            case UbuntuInstaller.TransactionMode.INSTALL:
+                primary_label.label = _("Installing %s").printf (installer.engine_to_address);
+                break;
+            case UbuntuInstaller.TransactionMode.REMOVE:
+                primary_label.label = _("Removing %s").printf (installer.engine_to_address);
+                break;
+        }
+
+        progress_bar = new Gtk.ProgressBar () {
+            hexpand = true,
+            valign = Gtk.Align.START,
+            width_request = 300
+        };
+
+        var cancel_button = (Gtk.Button) add_button (_("Cancel"), 0);
+
+        installer.bind_property ("install-cancellable", cancel_button, "sensitive");
+
+        var grid = new Gtk.Grid () {
+            column_spacing = 12,
+            margin = 6,
+            row_spacing = 6
+        };
+        grid.attach (image, 0, 0, 1, 2);
+        grid.attach (primary_label, 1, 0);
+        grid.attach (progress_bar, 1, 1);
+        grid.show_all ();
+
+        border_width = 6;
+        deletable = false;
+        get_content_area ().add (grid);
+
+        cancel_button.clicked.connect (() => {
+            installer.cancel_install ();
+            destroy ();
+        });
+    }
+}

src/InputMethod/AddEnginesList.vala

@@ -0,0 +1,38 @@
+/*
+* 2019-2020 elementary, Inc. (https://elementary.io)
+*
+* This program is free software: you can redistribute it and/or modify
+* it under the terms of the GNU General Public License as published by
+* the Free Software Foundation, either version 3 of the License, or
+* (at your option) any later version.
+*
+* This program is distributed in the hope that it will be useful,
+* but WITHOUT ANY WARRANTY; without even the implied warranty of
+* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+* GNU General Public License for more details.
+*
+* You should have received a copy of the GNU General Public License
+* along with this program.  If not, see <https://www.gnu.org/licenses/>.
+*/
+
+public class Pantheon.Keyboard.InputMethodPage.AddEnginesList : Object {
+    /*
+     * Stores strings used to add/remove engines in the code and won't be shown in the UI.
+     * It consists from "<Engine name>",
+     * e.g. "mozc-jp" or "libpinyin"
+     */
+    public string engine_id { get; private set; }
+
+    /*
+     * Stores strings used to show in the UI.
+     * It consists from "<Language name> - <Engine name>",
+     * e.g. "Japanese - Mozc" or "Chinese - Intelligent Pinyin"
+     */
+    public string engine_full_name { get; private set; }
+
+    public AddEnginesList (IBus.EngineDesc engine) {
+        engine_id = engine.name;
+        engine_full_name = "%s - %s".printf (IBus.get_language_name (engine.language),
+                                            Utils.gettext_engine_longname (engine));
+    }
+}

src/InputMethod/Installer/InstallList.vala

@@ -0,0 +1,73 @@
+/*
+* 2019-2020 elementary, Inc. (https://elementary.io)
+*
+* This program is free software: you can redistribute it and/or modify
+* it under the terms of the GNU General Public License as published by
+* the Free Software Foundation, either version 3 of the License, or
+* (at your option) any later version.
+*
+* This program is distributed in the hope that it will be useful,
+* but WITHOUT ANY WARRANTY; without even the implied warranty of
+* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+* GNU General Public License for more details.
+*
+* You should have received a copy of the GNU General Public License
+* along with this program.  If not, see <https://www.gnu.org/licenses/>.
+*/
+
+public enum Pantheon.Keyboard.InputMethodPage.InstallList {
+    JA,
+    KO,
+    ZH;
+
+    public string get_name () {
+        switch (this) {
+            case JA:
+                return _("Japanese");
+            case KO:
+                return _("Korean");
+            case ZH:
+                return _("Chinese");
+            default:
+                assert_not_reached ();
+        }
+    }
+
+    public string[] get_components () {
+        switch (this) {
+            case JA:
+                return { "ibus-anthy", "ibus-mozc", "ibus-skk" };
+            case KO:
+                return { "ibus-hangul" };
+            case ZH:
+                return { "ibus-cangjie", "ibus-chewing", "ibus-pinyin" };
+            default:
+                assert_not_reached ();
+        }
+    }
+
+    public static InstallList get_language_from_engine_name (string engine_name) {
+        switch (engine_name) {
+            case "ibus-anthy":
+                return JA;
+            case "ibus-mozc":
+                return JA;
+            case "ibus-skk":
+                return JA;
+            case "ibus-hangul":
+                return KO;
+            case "ibus-cangjie":
+                return ZH;
+            case "ibus-chewing":
+                return ZH;
+            case "ibus-pinyin":
+                return ZH;
+            default:
+                assert_not_reached ();
+        }
+    }
+
+    public static InstallList[] get_all () {
+        return { JA, KO, ZH };
+    }
+}