Add :file-handers and :resource-handlers options

src/duct/router/reitit.clj

@@ -47,11 +47,27 @@
     (-> (update :coercion (comp var-get requiring-resolve coercion-engines))
         (update :middleware #(into coercion-middleware %)))))
 
+(defn- path-map->options [path-map]
+  (for [[path opts] (sort-by key path-map)]
+    (assoc opts :path path)))
+
+(defn- create-handlers
+  [{:keys [default-handler file-handlers resource-handlers]}]
+  (concat
+   (when file-handlers
+     (->> (path-map->options file-handlers)
+          (map ring/create-file-handler)))
+   (when resource-handlers
+     (->> (path-map->options resource-handlers)
+          (map ring/create-resource-handler)))
+   (when default-handler
+     (list (ring/create-default-handler default-handler)))))
+
 (defmethod ig/init-key :duct.router/reitit [_ options]
   (let [opts   (-> options
                    (update-data convert-coercion)
                    (update-data convert-muuntaja))
         router (ring/router (:routes opts) opts)]
-    (if-some [handler (:default-handler opts)]
-      (ring/ring-handler router (ring/create-default-handler handler) opts)
+    (if-some [handlers (seq (create-handlers opts))]
+      (ring/ring-handler router (apply ring/routes handlers) opts)
       (ring/ring-handler router opts))))

test/duct/router/files/bar.txt

@@ -0,0 +1 @@
+bar

test/duct/router/files/foo.txt

@@ -0,0 +1 @@
+foo

test/duct/router/reitit_test.clj

@@ -1,5 +1,6 @@
 (ns duct.router.reitit-test
   (:require [clojure.test :refer [deftest is]]
+            [clojure.java.io :as io]
             [integrant.core :as ig]
             [duct.router.reitit :as reitit]))
 
@@ -63,3 +64,37 @@
            (router {:request-method :post, :uri "/"})))
     (is (= {:status 406, :body "406"}
            (router {:request-method :post, :uri "/406"})))))
+
+(deftest file-handler-test
+  (let [handler (constantly {:status 200, :body "Hello World"})
+        config
+        {:duct.router/reitit
+         {:routes {"/" {:get {:handler handler}}}
+          :file-handlers {"/" {:root "test/duct/router/files"}}}}
+        router (:duct.router/reitit (ig/init config))]
+    (is (= {:status 200, :body "Hello World"}
+           (router {:request-method :get, :uri "/"})))
+    (is (= {:status 200, :body (io/file "test/duct/router/files/foo.txt")}
+           (-> (router {:request-method :get, :uri "/foo.txt"})
+               (dissoc :headers))))
+    (is (= {:status 200, :body (io/file "test/duct/router/files/bar.txt")}
+           (-> (router {:request-method :get, :uri "/bar.txt"})
+               (dissoc :headers))))))
+
+(deftest resource-handler-test
+  (let [handler (constantly {:status 200, :body "Hello World"})
+        config
+        {:duct.router/reitit
+         {:routes {"/" {:get {:handler handler}}}
+          :resource-handlers {"/" {:root "duct/router/files"}}}}
+        router (:duct.router/reitit (ig/init config))]
+    (is (= {:status 200, :body "Hello World"}
+           (router {:request-method :get, :uri "/"})))
+    (is (= {:status 200, :body "foo\n"}
+           (-> (router {:request-method :get, :uri "/foo.txt"})
+               (dissoc :headers)
+               (update :body slurp))))
+    (is (= {:status 200, :body "bar\n"}
+           (-> (router {:request-method :get, :uri "/bar.txt"})
+               (dissoc :headers)
+               (update :body slurp))))))