Implement Iterator.from_json and #to_json

spec/std/json/serialization_spec.cr

@@ -67,6 +67,22 @@ describe "JSON serialization" do
       Deque(String).from_json(%(["a", "b"])).should eq(Deque.new(["a", "b"]))
     end
 
+    it "does Iterator(String)#from_json" do
+      assert_iterates_iterator ["a", "b"], Iterator(String).from_json(%(["a", "b"]))
+    end
+
+    it "raises an error Iterator(String)#from_json with invalid types" do
+      expect_raises(JSON::ParseException) do
+        Iterator(String).from_json(%([1, 2])).to_a
+      end
+    end
+
+    it "raises an error Iterator(String)#from_json with invalid JSON" do
+      expect_raises(JSON::ParseException) do
+        Iterator(String).from_json(%(["a")).to_a
+      end
+    end
+
     it "does Hash(String, String)#from_json" do
       Hash(String, String).from_json(%({"foo": "x", "bar": "y"})).should eq({"foo" => "x", "bar" => "y"})
     end
@@ -523,6 +539,10 @@ describe "JSON serialization" do
       Set(Int32).new([1, 1, 2]).to_json.should eq("[1,2]")
     end
 
+    it "does for Iterator" do
+      (1..3).each.to_json.should eq("[1,2,3]")
+    end
+
     it "does for Hash" do
       {"foo" => 1, "bar" => 2}.to_json.should eq(%({"foo":1,"bar":2}))
     end

src/json/from_json.cr

@@ -65,6 +65,57 @@ def Deque.from_json(string_or_io) : Nil
   end
 end
 
+module Iterator(T)
+  # Reads the content of a JSON array into an iterator in a lazy way.
+  # With this method it should be possible to process a huge JSON array, without
+  # the requirement that the whole array fits into memory.
+  #
+  # The following example produces a huge file, uses a lot of CPU but should not require much memory.
+  #
+  # ```
+  # File.open("/tmp/test.json", "w+") do |f|
+  #   (0..1_000_000_000).each.to_json(f)
+  # end
+  #
+  # File.open("/tmp/test.json", "r") do |f|
+  #   p Iterator(Int32).from_json(f).skip(1_000_000_000).to_a
+  # end
+  # ```
+  #
+  # WARNING: The `string_or_io` can't be used by anything else until the iterator is fully consumed.
+  def self.from_json(string_or_io)
+    Iterator(T).new(JSON::PullParser.new(string_or_io))
+  end
+
+  # Creates a new iterator which iterates over a JSON array. See also `Iterator#from_json`.
+  #
+  # WARNING: The `JSON::PullParser` can't be used by anything else until the iterator is fully consumed.
+  def self.new(pull : JSON::PullParser)
+    FromJson(T).new(pull)
+  end
+
+  private class FromJson(T)
+    include Iterator(T)
+
+    def initialize(@pull : JSON::PullParser)
+      @pull.read_begin_array
+      @end = false
+    end
+
+    def next
+      if @end
+        stop
+      elsif @pull.kind.end_array?
+        @pull.read_next
+        @end = true
+        stop
+      else
+        T.new(@pull)
+      end
+    end
+  end
+end
+
 def Nil.new(pull : JSON::PullParser)
   pull.read_null
 end

src/json/to_json.cr

@@ -114,6 +114,16 @@ struct Set
   end
 end
 
+module Iterator(T)
+  # Converts the content of an iterator into a JSON array in lazy way.
+  # See `Iterator#from_json` for an example.
+  def to_json(json : JSON::Builder)
+    json.array do
+      each &.to_json(json)
+    end
+  end
+end
+
 class Hash
   # Serializes this Hash into JSON.
   #

src/yaml/to_yaml.cr

@@ -39,6 +39,18 @@ class Array
   end
 end
 
+module Iterator(T)
+  # Converts the content of an iterator to YAML.
+  # The convertion is done in a lazy way.
+  # In contrast to `Iterator#to_json` this operation requires memory for the
+  # for the complete YAML document
+  def to_yaml(yaml : YAML::Nodes::Builder)
+    yaml.sequence(reference: self) do
+      each &.to_yaml(yaml)
+    end
+  end
+end
+
 struct Tuple
   def to_yaml(yaml : YAML::Nodes::Builder) : Nil
     yaml.sequence do