Merge #2786

2786: Better concatenation for pkg-config values, better use of GNUInstallDirs variables r=RAOF a=OPNA2608 Similar situation as canonical/wlcs#258, canonical/wlcs#260: - CMake code assumes `CMAKE_INSTALL_<dir>` are relative to `CMAKE_INSTALL_PREFIX` when they may be absolute and completely outside of the `PREFIX`, blindly concatenating these two causes broken pkg-config files in such situations - `CMAKE_INSTALL_FULL_<dir>` should only be used in pkg-config files when the dir is not relative to the `${prefix}` so overriding the pkg-config variables has the intended effect - In various places, suitable GNUInstallDirs variables for specifying header & data file locations are ignored - As a minor point `FULL` & non-`FULL` variables are used inconsistently in `install` commands I've - fixed these concatenations in CMake & pkg-config files according to [jtojnar/cmake-snips#concatenating-paths-when-building-pkg-config-files](https://github.com/jtojnar/cmake-snips/tree/a9d72829ab0cb42e541c9975e698d6b8282610ed#concatenating-paths-when-building-pkg-config-files) - added more usage of `CMAKE_INSTALL_INCLUDEDIR` (defaults to `include`) & `CMAKE_INSTALL_DATADIR` (`share`) and - replaced some `FULL` variables with non-`FULL` variants where the effect should be the same, for consistency I've cherry-picked these commits onto 2.11.0 and checked the pkg-config files with relative & absolute install paths, resulting files looked okay to me. I've also tried building egmde against it and it builds & launches, where previously it would fail to find Mir's headers if `CMAKE_INSTALL_INCLUDEDIR` was an absolute path. Co-authored-by: OPNA2608 <[email protected]>
canonical · Jan 20, 2023 · 7606aa9 · 7606aa9
2 parents 6240112 + 74d5941
commit 7606aa9
Show file tree

Hide file tree

Showing 29 changed files with 92 additions and 55 deletions.
diff --git a/CMakeLists.txt b/CMakeLists.txt
@@ -322,6 +322,10 @@ endif()
 
 set(MIR_TRACEPOINT_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR}/mir/tools)
 
+mir_make_pkgconfig_variable(PKGCONFIG_LIBDIR "${CMAKE_INSTALL_LIBDIR}")
+mir_make_pkgconfig_variable(PKGCONFIG_INCLUDEDIR "${CMAKE_INSTALL_INCLUDEDIR}")
+include(JoinPaths)
+
 set(MIR_GENERATED_INCLUDE_DIRECTORIES)
 add_subdirectory(src/)
 include_directories(${MIR_GENERATED_INCLUDE_DIRECTORIES})

diff --git a/cmake/JoinPaths.cmake b/cmake/JoinPaths.cmake
@@ -0,0 +1,23 @@
+# This module provides function for joining paths
+# known from most languages
+#
+# SPDX-License-Identifier: (MIT OR CC0-1.0)
+# Copyright 2020 Jan Tojnar
+# https://github.com/jtojnar/cmake-snips
+#
+# Modelled after Python’s os.path.join
+# https://docs.python.org/3.7/library/os.path.html#os.path.join
+# Windows not supported
+function(join_paths joined_path first_path_segment)
+    set(temp_path "${first_path_segment}")
+    foreach(current_segment IN LISTS ARGN)
+        if(NOT ("${current_segment}" STREQUAL ""))
+            if(IS_ABSOLUTE "${current_segment}")
+                set(temp_path "${current_segment}")
+            else()
+                set(temp_path "${temp_path}/${current_segment}")
+            endif()
+        endif()
+    endforeach()
+    set(${joined_path} "${temp_path}" PARENT_SCOPE)
+endfunction()
diff --git a/cmake/MirCommon.cmake b/cmake/MirCommon.cmake
@@ -329,3 +329,14 @@ function (mir_generate_protocol_wrapper TARGET_NAME NAME_PREFIX PROTOCOL_FILE)
   )
   target_sources("${TARGET_NAME}" PRIVATE "${OUTPUT_PATH_HEADER}" "${OUTPUT_PATH_SRC}")
 endfunction()
+
+function (mir_make_pkgconfig_variable PKGCONFIG_VARIABLE INPUT_PATH)
+  get_filename_component(INPUT_ABSOLUTE "${INPUT_PATH}" ABSOLUTE BASE_DIR "${CMAKE_INSTALL_PREFIX}")
+  file(RELATIVE_PATH INPUT_RELATIVE "${CMAKE_INSTALL_PREFIX}" "${INPUT_ABSOLUTE}")
+  string(FIND "${INPUT_RELATIVE}" ".." INPUT_EXITS_PREFIX)
+  if ("${INPUT_EXITS_PREFIX}" EQUAL "-1" )
+    set ("${PKGCONFIG_VARIABLE}" "\${prefix}/${INPUT_RELATIVE}" PARENT_SCOPE)
+  else()
+    set ("${PKGCONFIG_VARIABLE}" "${INPUT_PATH}" PARENT_SCOPE)
+  endif()
+endfunction()
diff --git a/examples/miral-shell/CMakeLists.txt b/examples/miral-shell/CMakeLists.txt
@@ -6,15 +6,15 @@ add_custom_target(miral-app ALL
 )
 
 install(PROGRAMS ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/miral-app
-    DESTINATION ${CMAKE_INSTALL_PREFIX}/bin
+    DESTINATION ${CMAKE_INSTALL_BINDIR}
 )
 
 add_custom_target(miral-terminal ALL
     cp ${CMAKE_CURRENT_SOURCE_DIR}/miral-terminal.sh ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/miral-terminal
 )
 
 install(PROGRAMS ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/miral-terminal
-    DESTINATION ${CMAKE_INSTALL_PREFIX}/bin
+    DESTINATION ${CMAKE_INSTALL_BINDIR}
 )
 
 mir_add_wrapped_executable(miral-shell

diff --git a/examples/miral-shell/desktop/CMakeLists.txt b/examples/miral-shell/desktop/CMakeLists.txt
@@ -4,21 +4,21 @@ configure_file(miral-shell.desktop.in ${CMAKE_CURRENT_BINARY_DIR}/miral-shell.de
 configure_file(mir-shell.desktop.in ${CMAKE_CURRENT_BINARY_DIR}/mir-shell.desktop @ONLY)
 
 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/miral-shell.desktop
-    DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications
+    DESTINATION ${CMAKE_INSTALL_DATADIR}/applications
 )
 
 add_custom_target(mir-shell ALL
     cp ${CMAKE_CURRENT_SOURCE_DIR}/mir-shell.sh ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/mir-shell
 )
 
 install(PROGRAMS ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/mir-shell
-    DESTINATION ${CMAKE_INSTALL_PREFIX}/bin
+    DESTINATION ${CMAKE_INSTALL_BINDIR}
 )
 
 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/mir-shell.desktop
-    DESTINATION ${CMAKE_INSTALL_PREFIX}/share/wayland-sessions
+    DESTINATION ${CMAKE_INSTALL_DATADIR}/wayland-sessions
 )
 
 install(FILES ${ICON_NAME}.svg
-    DESTINATION ${CMAKE_INSTALL_PREFIX}/share/icons/hicolor/scalable/apps
+    DESTINATION ${CMAKE_INSTALL_DATADIR}/icons/hicolor/scalable/apps
 )
diff --git a/src/common/CMakeLists.txt b/src/common/CMakeLists.txt
@@ -96,11 +96,11 @@ install(TARGETS mircommon LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 
 install(
   DIRECTORY ${CMAKE_SOURCE_DIR}/include/common/mir
-  DESTINATION "include/mircommon"
+  DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/mircommon"
 )
 
 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/mircommon.pc.in
     ${CMAKE_CURRENT_BINARY_DIR}/mircommon.pc
     @ONLY
 )
-install(FILES       ${CMAKE_CURRENT_BINARY_DIR}/mircommon.pc    DESTINATION "${CMAKE_INSTALL_FULL_LIBDIR}/pkgconfig")
+install(FILES       ${CMAKE_CURRENT_BINARY_DIR}/mircommon.pc    DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
diff --git a/src/common/mircommon.pc.in b/src/common/mircommon.pc.in
@@ -1,6 +1,6 @@
 prefix=@CMAKE_INSTALL_PREFIX@
-libdir=${prefix}/@CMAKE_INSTALL_LIBDIR@
-includedir=${prefix}/@CMAKE_INSTALL_INCLUDEDIR@/mircommon
+libdir=@PKGCONFIG_LIBDIR@
+includedir=@PKGCONFIG_INCLUDEDIR@/mircommon
 
 Name: mircommon
 Description: Mir server library

diff --git a/src/common/report/lttng/CMakeLists.txt b/src/common/report/lttng/CMakeLists.txt
@@ -1,4 +1,5 @@
-add_compile_definitions(MIR_TRACEPOINT_LIB_INSTALL_PATH="${CMAKE_INSTALL_PREFIX}/${MIR_TRACEPOINT_LIB_INSTALL_DIR}")
+join_paths(MIR_TRACEPOINT_LIB_INSTALL_PATH "${CMAKE_INSTALL_PREFIX}" "${MIR_TRACEPOINT_LIB_INSTALL_DIR}")
+add_compile_definitions(MIR_TRACEPOINT_LIB_INSTALL_PATH="${MIR_TRACEPOINT_LIB_INSTALL_PATH}")
 
 add_library(mirsharedlttng OBJECT
 

diff --git a/src/cookie/CMakeLists.txt b/src/cookie/CMakeLists.txt
@@ -42,7 +42,7 @@ install(
 
 install(
   DIRECTORY ${CMAKE_SOURCE_DIR}/include/cookie/mir
-  DESTINATION "include/mircookie"
+  DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/mircookie"
 )
 
 install(

diff --git a/src/cookie/mircookie.pc.in b/src/cookie/mircookie.pc.in
@@ -1,6 +1,6 @@
 prefix=@CMAKE_INSTALL_PREFIX@
-libdir=${prefix}/@CMAKE_INSTALL_LIBDIR@
-includedir=${prefix}/@CMAKE_INSTALL_INCLUDEDIR@/mircookie
+libdir=@PKGCONFIG_LIBDIR@
+includedir=@PKGCONFIG_INCLUDEDIR@/mircookie
 
 Name: mircookie
 Description: Mir client library

diff --git a/src/core/CMakeLists.txt b/src/core/CMakeLists.txt
@@ -58,7 +58,7 @@ install(TARGETS mircore LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 
 install(
     DIRECTORY ${CMAKE_SOURCE_DIR}/include/core/mir ${CMAKE_SOURCE_DIR}/include/core/mir_toolkit
-    DESTINATION "include/mircore"
+    DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/mircore"
 )
 
 install(

diff --git a/src/core/mircore.pc.in b/src/core/mircore.pc.in
@@ -1,6 +1,6 @@
 prefix=@CMAKE_INSTALL_PREFIX@
-libdir=${prefix}/@CMAKE_INSTALL_LIBDIR@
-includedir=${prefix}/@CMAKE_INSTALL_INCLUDEDIR@/mircore
+libdir=@PKGCONFIG_LIBDIR@
+includedir=@PKGCONFIG_INCLUDEDIR@/mircore
 
 Name: mircore
 Description: Mir core library

diff --git a/src/miral/CMakeLists.txt b/src/miral/CMakeLists.txt
@@ -158,6 +158,6 @@ if(TARGET doc)
             DEPENDS doc)
 endif()
 
-install(TARGETS     miral                           LIBRARY DESTINATION "${CMAKE_INSTALL_FULL_LIBDIR}")
-install(DIRECTORY   ${CMAKE_SOURCE_DIR}/include/miral       DESTINATION "${CMAKE_INSTALL_PREFIX}/include")
-install(FILES       ${CMAKE_CURRENT_BINARY_DIR}/miral.pc    DESTINATION "${CMAKE_INSTALL_FULL_LIBDIR}/pkgconfig")
+install(TARGETS     miral                           LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}")
+install(DIRECTORY   ${CMAKE_SOURCE_DIR}/include/miral       DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}")
+install(FILES       ${CMAKE_CURRENT_BINARY_DIR}/miral.pc    DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
diff --git a/src/miral/miral.pc.in b/src/miral/miral.pc.in
@@ -1,6 +1,6 @@
 prefix=@CMAKE_INSTALL_PREFIX@
-libdir=${prefix}/@CMAKE_INSTALL_LIBDIR@
-includedir=${prefix}/@CMAKE_INSTALL_INCLUDEDIR@/miral
+libdir=@PKGCONFIG_LIBDIR@
+includedir=@PKGCONFIG_INCLUDEDIR@/miral
 
 Name: miral
 Description: Mir Abstraction Layer library

diff --git a/src/miroil/CMakeLists.txt b/src/miroil/CMakeLists.txt
@@ -89,6 +89,6 @@ if(TARGET doc)
             DEPENDS doc)
 endif()
 
-install(TARGETS     miroil                           LIBRARY DESTINATION "${CMAKE_INSTALL_FULL_LIBDIR}")
-install(DIRECTORY   ${CMAKE_SOURCE_DIR}/include/miroil       DESTINATION "${CMAKE_INSTALL_PREFIX}/include")
-install(FILES       ${CMAKE_CURRENT_BINARY_DIR}/miroil.pc    DESTINATION "${CMAKE_INSTALL_FULL_LIBDIR}/pkgconfig")
+install(TARGETS     miroil                           LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}")
+install(DIRECTORY   ${CMAKE_SOURCE_DIR}/include/miroil       DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}")
+install(FILES       ${CMAKE_CURRENT_BINARY_DIR}/miroil.pc    DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
diff --git a/src/miroil/miroil.pc.in b/src/miroil/miroil.pc.in
@@ -1,6 +1,6 @@
 prefix=@CMAKE_INSTALL_PREFIX@
-libdir=${prefix}/@CMAKE_INSTALL_LIBDIR@
-includedir=${prefix}/@CMAKE_INSTALL_INCLUDEDIR@/miroil
+libdir=@PKGCONFIG_LIBDIR@
+includedir=@PKGCONFIG_INCLUDEDIR@/miroil
 
 Name: miral
 Description: Mir "OIL" (lomiri support) library

diff --git a/src/platform/mirplatform.pc.in b/src/platform/mirplatform.pc.in
@@ -1,6 +1,6 @@
 prefix=@CMAKE_INSTALL_PREFIX@
-libdir=${prefix}/@CMAKE_INSTALL_LIBDIR@
-includedir=${prefix}/@CMAKE_INSTALL_INCLUDEDIR@
+libdir=@PKGCONFIG_LIBDIR@
+includedir=@PKGCONFIG_INCLUDEDIR@
 
 Name: mirplatform
 Description: Mir platform library

diff --git a/src/platforms/CMakeLists.txt b/src/platforms/CMakeLists.txt
@@ -21,7 +21,7 @@ set(MIR_INPUT_PLATFORM_VERSION_SCRIPT
 set(MIR_INPUT_PLATFORM_VERSION_SCRIPT ${MIR_INPUT_PLATFORM_VERSION_SCRIPT} PARENT_SCOPE)
 
 set(MIR_SERVER_PLATFORM_PATH
-  ${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR}/mir/server-platform
+  ${CMAKE_INSTALL_FULL_LIBDIR}/mir/server-platform
 )
 set(MIR_SERVER_PLATFORM_PATH
   ${MIR_SERVER_PLATFORM_PATH}

diff --git a/src/renderer/CMakeLists.txt b/src/renderer/CMakeLists.txt
@@ -1,6 +1,6 @@
 install(
   DIRECTORY ${CMAKE_SOURCE_DIR}/include/renderer/mir
-  DESTINATION "include/mirrenderer"
+  DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/mirrenderer"
 )
 
 configure_file(

diff --git a/src/renderer/mirrenderer.pc.in b/src/renderer/mirrenderer.pc.in
@@ -1,5 +1,5 @@
 prefix=@CMAKE_INSTALL_PREFIX@
-includedir=${prefix}/@CMAKE_INSTALL_INCLUDEDIR@
+includedir=@PKGCONFIG_INCLUDEDIR@
 
 Name: mirrenderer
 Description: Mir renderer

diff --git a/src/renderers/gl/CMakeLists.txt b/src/renderers/gl/CMakeLists.txt
@@ -6,7 +6,7 @@ configure_file(
 
 install(
   DIRECTORY ${CMAKE_SOURCE_DIR}/include/renderers/gl/mir
-  DESTINATION "include/mirrenderer"
+  DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/mirrenderer"
 )
 
 install(

diff --git a/src/renderers/gl/mir-renderer-gl-dev.pc.in b/src/renderers/gl/mir-renderer-gl-dev.pc.in
@@ -1,5 +1,5 @@
 prefix=@CMAKE_INSTALL_PREFIX@
-includedir=${prefix}/@CMAKE_INSTALL_INCLUDEDIR@/mirrenderer
+includedir=@PKGCONFIG_INCLUDEDIR@/mirrenderer
 
 Name: mir-renderer-gl-dev
 Description: Mir GL renderer development files

diff --git a/src/server/CMakeLists.txt b/src/server/CMakeLists.txt
@@ -164,10 +164,10 @@ install(TARGETS mirserver
   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 )
 install(DIRECTORY
-  ${CMAKE_SOURCE_DIR}/include/platform/mir DESTINATION "include/mirplatform"
+  ${CMAKE_SOURCE_DIR}/include/platform/mir DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/mirplatform"
 )
 install(DIRECTORY
-  ${CMAKE_SOURCE_DIR}/include/server/mir DESTINATION "include/mirserver"
+  ${CMAKE_SOURCE_DIR}/include/server/mir DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/mirserver"
 )
 
 set(MIRSERVER_ABI 58) # Be sure to increment MIR_VERSION_MINOR at the same time

diff --git a/src/server/mirserver.pc.in b/src/server/mirserver.pc.in
@@ -1,6 +1,6 @@
 prefix=@CMAKE_INSTALL_PREFIX@
-libdir=${prefix}/@CMAKE_INSTALL_LIBDIR@
-includedir=${prefix}/@CMAKE_INSTALL_INCLUDEDIR@/mirserver
+libdir=@PKGCONFIG_LIBDIR@
+includedir=@PKGCONFIG_INCLUDEDIR@/mirserver
 
 Name: mirserver
 Description: Mir server library

diff --git a/src/wayland/CMakeLists.txt b/src/wayland/CMakeLists.txt
@@ -62,7 +62,7 @@ configure_file(
     @ONLY
 )
 
-install(TARGETS     mirwayland                           LIBRARY DESTINATION "${CMAKE_INSTALL_FULL_LIBDIR}")
-install(FILES       ${CMAKE_CURRENT_BINARY_DIR}/mirwayland.pc    DESTINATION "${CMAKE_INSTALL_FULL_LIBDIR}/pkgconfig")
-install(DIRECTORY   ${CMAKE_SOURCE_DIR}/include/wayland/mir      DESTINATION "include/mirwayland")
+install(TARGETS     mirwayland                           LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}")
+install(FILES       ${CMAKE_CURRENT_BINARY_DIR}/mirwayland.pc    DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
+install(DIRECTORY   ${CMAKE_SOURCE_DIR}/include/wayland/mir      DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/mirwayland")
 
diff --git a/src/wayland/mirwayland.pc.in b/src/wayland/mirwayland.pc.in
@@ -1,6 +1,6 @@
 prefix=@CMAKE_INSTALL_PREFIX@
-libdir=${prefix}/@CMAKE_INSTALL_LIBDIR@
-includedir=${prefix}/@CMAKE_INSTALL_INCLUDEDIR@/mirwayland
+libdir=@PKGCONFIG_LIBDIR@
+includedir=@PKGCONFIG_INCLUDEDIR@/mirwayland
 
 Name: mirwayland
 Description: Mir Wayland library

diff --git a/tests/CMakeLists.txt b/tests/CMakeLists.txt
@@ -204,25 +204,23 @@ PRIVATE
   ${CMAKE_THREAD_LIBS_INIT} # Link in pthread.
 )
 
-set(PREFIX "${CMAKE_INSTALL_PREFIX}")
-set(LIBDIR "${CMAKE_INSTALL_FULL_LIBDIR}")
-set(INCLUDEDIR "${CMAKE_INSTALL_PREFIX}/include/mirtest")
 configure_file(
   ${CMAKE_CURRENT_SOURCE_DIR}/mirtest.pc.in
   ${CMAKE_CURRENT_BINARY_DIR}/mirtest.pc
+  @ONLY
 )
 
 install(TARGETS mir-test-assist
   ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 )
 install(DIRECTORY ${CMAKE_SOURCE_DIR}/include/test/mir
-  DESTINATION "include/mirtest"
+  DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/mirtest"
 )
 install(DIRECTORY ${CMAKE_SOURCE_DIR}/include/test/mir_test_framework
-  DESTINATION "include/mirtest"
+  DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/mirtest"
 )
 install(DIRECTORY ${CMAKE_SOURCE_DIR}/include/test/miral
-  DESTINATION "include/mirtest"
+  DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/mirtest"
 )
 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/mirtest.pc
   DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig

diff --git a/tests/mirtest.pc.in b/tests/mirtest.pc.in
@@ -1,10 +1,10 @@
-prefix=@PREFIX@
-libdir=@LIBDIR@
-includedir=@INCLUDEDIR@
+prefix=@CMAKE_INSTALL_PREFIX@
+libdir=@PKGCONFIG_LIBDIR@
+includedir=@PKGCONFIG_INCLUDEDIR@/mirtest
 
 Name: mirtest
 Description: Mir test assist library
 Version: @MIR_VERSION@
 Requires: miral mirserver mirplatform mircommon mir-renderer-gl-dev
-Libs: -L@LIBDIR@ -lmir-test-assist -ldl -lboost_filesystem -lboost_system
-Cflags: -I@INCLUDEDIR@
+Libs: -L${libdir} -lmir-test-assist -ldl -lboost_filesystem -lboost_system
+Cflags: -I${includedir}
diff --git a/tests/performance-tests/CMakeLists.txt b/tests/performance-tests/CMakeLists.txt
@@ -15,7 +15,7 @@ add_custom_target(mir-smoke-test-runner ALL
 )
 
 install(PROGRAMS ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/mir-smoke-test-runner
-    DESTINATION ${CMAKE_INSTALL_PREFIX}/bin
+    DESTINATION ${CMAKE_INSTALL_BINDIR}
 )
 
 find_program(XVFB_RUN_EXECUTABLE xvfb-run)