openobserve: 0.11.0 -> 0.14.0, move to pkgs/by-name (NixOS#372209)

bhipple · Jan 8, 2025 · 8959d73 · 8959d73
2 parents 75e6ca3 + 627b3b3
commit 8959d73
Show file tree

Hide file tree

Showing 5 changed files with 114 additions and 9,774 deletions.
diff --git a/...ers/monitoring/openobserve/build.rs.patch → pkgs/by-name/op/openobserve/build.rs.patch b/...ers/monitoring/openobserve/build.rs.patch → pkgs/by-name/op/openobserve/build.rs.patch
diff --git a/pkgs/by-name/op/openobserve/package.nix b/pkgs/by-name/op/openobserve/package.nix
@@ -0,0 +1,114 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  protobuf,
+  bzip2,
+  oniguruma,
+  sqlite,
+  xz,
+  zlib,
+  zstd,
+  buildNpmPackage,
+  gitUpdater,
+}:
+
+let
+  version = "0.14.0";
+  src = fetchFromGitHub {
+    owner = "openobserve";
+    repo = "openobserve";
+    tag = "v${version}";
+    hash = "sha256-rTp+DkADqYkJg1zJog1yURE082V5kCqgid/oUd81SN8=";
+  };
+  web = buildNpmPackage {
+    inherit src version;
+    pname = "openobserve-ui";
+
+    sourceRoot = "${src.name}/web";
+
+    npmDepsHash = "sha256-awfQR1wZBX3ggmD0uJE9Fur4voPydeygrviRijKnBTE=";
+
+    preBuild = ''
+      # Patch vite config to not open the browser to visualize plugin composition
+      substituteInPlace vite.config.ts \
+        --replace "open: true" "open: false";
+    '';
+
+    env = {
+      NODE_OPTIONS = "--max-old-space-size=8192";
+      # cypress tries to download binaries otherwise
+      CYPRESS_INSTALL_BINARY = 0;
+    };
+
+    installPhase = ''
+      runHook preInstall
+      mkdir -p $out/share
+      mv dist $out/share/openobserve-ui
+      runHook postInstall
+    '';
+  };
+in
+rustPlatform.buildRustPackage {
+  pname = "openobserve";
+  inherit version src;
+
+  patches = [
+    # prevent using git to determine version info during build time
+    ./build.rs.patch
+  ];
+
+  preBuild = ''
+    cp -r ${web}/share/openobserve-ui web/dist
+  '';
+
+  useFetchCargoVendor = true;
+  cargoHash = "sha256-FWMUPghx9CxuzP7jFZYSIwZsylApWzQsfx8DuwS4GTo=";
+
+  nativeBuildInputs = [
+    pkg-config
+    protobuf
+  ];
+
+  buildInputs = [
+    bzip2
+    oniguruma
+    sqlite
+    xz
+    zlib
+    zstd
+  ];
+
+  env = {
+    RUSTONIG_SYSTEM_LIBONIG = true;
+    ZSTD_SYS_USE_PKG_CONFIG = true;
+
+    RUSTC_BOOTSTRAP = 1; # uses experimental features
+
+    # the patched build.rs file sets these variables
+    GIT_VERSION = src.tag;
+    GIT_COMMIT_HASH = "builtByNix";
+    GIT_BUILD_DATE = "1970-01-01T00:00:00Z";
+  };
+
+  # requires network access or filesystem mutations
+  checkFlags = [
+    "--skip=handler::http::router::tests::test_get_proxy_routes"
+    "--skip=tests::e2e_test"
+  ];
+
+  passthru.updateScript = gitUpdater {
+    rev-prefix = "v";
+    ignoredVersions = "rc";
+  };
+
+  meta = {
+    description = "Cloud-native observability platform built specifically for logs, metrics, traces, analytics & realtime user-monitoring";
+    homepage = "https://github.com/openobserve/openobserve";
+    changelog = "https://github.com/openobserve/openobserve/releases/tag/v${version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ happysalada ];
+    mainProgram = "openobserve";
+  };
+}