Addition of Multi-Agent PDDL to ANTLR v4

pddl/Pddl.g4 → pddl/SingleAgentPDDL.g4

@@ -10,7 +10,7 @@
 // $antlr-format alignTrailingComments true, columnLimit 150, minEmptyLines 1, maxEmptyLinesToKeep 1, reflowComments false, useTab false
 // $antlr-format allowShortRulesOnASingleLine false, allowShortBlocksOnASingleLine true, alignSemicolons hanging, alignColons hanging
 
-grammar Pddl;
+grammar SingleAgentPDDL;
 
 /************* Start of grammar *******************/
 pddlDoc

pddl/multi-agent-examples/blocksworld/domain.pddl

@@ -0,0 +1,82 @@
+(define (domain blocks)
+	(:requirements :typing :multi-agent :unfactored-privacy)
+(:types
+	agent block - object
+)
+(:predicates
+	(on ?x - block ?y - block)
+	(ontable ?x - block)
+	(clear ?x - block)
+
+	(:private ?agent - agent
+		(holding ?agent - agent ?x - block)
+		(handempty ?agent - agent)
+	)
+)
+
+(:action pick-up
+	:agent ?a - agent
+	:parameters (?x - block)
+	:precondition (and
+		(clear ?x)
+		(ontable ?x)
+		(handempty ?a)
+	)
+	:effect (and
+		(not (ontable ?x))
+		(not (clear ?x))
+		(not (handempty ?a))
+		(holding ?a ?x)
+	)
+)
+
+
+(:action put-down
+	:agent ?a - agent
+	:parameters (?x - block)
+	:precondition 
+		(holding ?a ?x)
+	:effect (and
+		(not (holding ?a ?x))
+		(clear ?x)
+		(handempty ?a)
+		(ontable ?x)
+	)
+)
+
+
+(:action stack
+	:agent ?a - agent
+	:parameters (?x - block ?y - block)
+	:precondition (and
+		(holding ?a ?x)
+		(clear ?y)
+	)
+	:effect (and
+		(not (holding ?a ?x))
+		(not (clear ?y))
+		(clear ?x)
+		(handempty ?a)
+		(on ?x ?y)
+	)
+)
+
+
+(:action unstack
+	:agent ?a - agent
+	:parameters (?x - block ?y - block)
+	:precondition (and
+		(on ?x ?y)
+		(clear ?x)
+		(handempty ?a)
+	)
+	:effect (and
+		(holding ?a ?x)
+		(clear ?y)
+		(not (clear ?x))
+		(not (handempty ?a))
+		(not (on ?x ?y))
+	)
+)
+
+)

pddl/multi-agent-examples/blocksworld/probBLOCKS-16-1.pddl

@@ -0,0 +1,80 @@
+(define (problem BLOCKS-4-0) (:domain blocks)
+(:objects
+	a - block
+	c - block
+	b - block
+	e - block
+	d - block
+	g - block
+	f - block
+	i - block
+	h - block
+	k - block
+	j - block
+	m - block
+	l - block
+	o - block
+	n - block
+	p - block
+
+	(:private a1
+		a1 - agent
+	)
+
+	(:private a2
+		a2 - agent
+	)
+
+	(:private a3
+		a3 - agent
+	)
+
+	(:private a4
+		a4 - agent
+	)
+)
+(:init
+	(handempty a1)
+	(handempty a2)
+	(handempty a3)
+	(handempty a4)
+	(clear f)
+	(clear h)
+	(clear o)
+	(ontable a)
+	(ontable e)
+	(ontable g)
+	(on f l)
+	(on l m)
+	(on m j)
+	(on j p)
+	(on p n)
+	(on n i)
+	(on i b)
+	(on b d)
+	(on d c)
+	(on c k)
+	(on k a)
+	(on h e)
+	(on o g)
+)
+(:goal
+	(and
+		(on d b)
+		(on b p)
+		(on p f)
+		(on f g)
+		(on g k)
+		(on k i)
+		(on i l)
+		(on l j)
+		(on j h)
+		(on h a)
+		(on a n)
+		(on n e)
+		(on e m)
+		(on m c)
+		(on c o)
+	)
+)
+)

pddl/multi-agent-examples/blocksworld/probBLOCKS-4-0.pddl

@@ -0,0 +1,45 @@
+(define (problem BLOCKS-4-0) (:domain blocks)
+(:objects
+	a - block
+	c - block
+	b - block
+	d - block
+
+	(:private a1
+		a1 - agent
+	)
+
+	(:private a2
+		a2 - agent
+	)
+
+	(:private a3
+		a3 - agent
+	)
+
+	(:private a4
+		a4 - agent
+	)
+)
+(:init
+	(handempty a1)
+	(handempty a2)
+	(handempty a3)
+	(handempty a4)
+	(clear c)
+	(clear a)
+	(clear b)
+	(clear d)
+	(ontable c)
+	(ontable a)
+	(ontable b)
+	(ontable d)
+)
+(:goal
+	(and
+		(on d c)
+		(on c b)
+		(on b a)
+	)
+)
+)

pddl/multi-agent-examples/depot/domain.pddl

@@ -0,0 +1,111 @@
+(define (domain depot)
+	(:requirements :typing :multi-agent :unfactored-privacy)
+(:types
+	place locatable driver - object
+	depot distributor - place
+	truck hoist surface - locatable
+	pallet crate - surface
+)
+(:predicates
+	(at ?x - locatable ?y - place)
+	(on ?x - crate ?y - surface)
+	(in ?x - crate ?y - truck)
+	(clear ?x - surface)
+
+	(:private ?agent - place
+		(lifting ?agent - place ?x - hoist ?y - crate)
+		(available ?agent - place ?x - hoist)
+	)
+
+	(:private ?agent - driver
+		(driving ?agent - driver ?t - truck)
+	)
+
+)
+
+(:action drive
+	:agent ?a - driver
+	:parameters (?x - truck ?y - place ?z - place)
+	:precondition 
+		(and (at ?x ?y) (driving ?a ?x))
+	:effect (and
+		(at ?x ?z)
+		(not (at ?x ?y))
+	)
+)
+
+
+(:action lift
+	:agent ?p - place
+	:parameters (?x - hoist ?y - crate ?z - surface)
+	:precondition (and
+		(at ?x ?p)
+		(available ?p ?x)
+		(at ?y ?p)
+		(on ?y ?z)
+		(clear ?y)
+	)
+	:effect (and
+		(lifting ?p ?x ?y)
+		(clear ?z)
+		(not (at ?y ?p))
+		(not (clear ?y))
+		(not (available ?p ?x))
+		(not (on ?y ?z))
+	)
+)
+
+
+(:action drop
+	:agent ?p - place
+	:parameters (?x - hoist ?y - crate ?z - surface)
+	:precondition (and
+		(at ?x ?p)
+		(at ?z ?p)
+		(clear ?z)
+		(lifting ?p ?x ?y)
+	)
+	:effect (and
+		(available ?p ?x)
+		(at ?y ?p)
+		(clear ?y)
+		(on ?y ?z)
+		(not (lifting ?p ?x ?y))
+		(not (clear ?z))
+	)
+)
+
+
+(:action load
+	:agent ?p - place
+	:parameters (?x - hoist ?y - crate ?z - truck)
+	:precondition (and
+		(at ?x ?p)
+		(at ?z ?p)
+		(lifting ?p ?x ?y)
+	)
+	:effect (and
+		(in ?y ?z)
+		(available ?p ?x)
+		(not (lifting ?p ?x ?y))
+	)
+)
+
+
+(:action unload
+	:agent ?p - place
+	:parameters (?x - hoist ?y - crate ?z - truck)
+	:precondition (and
+		(at ?x ?p)
+		(at ?z ?p)
+		(available ?p ?x)
+		(in ?y ?z)
+	)
+	:effect (and
+		(lifting ?p ?x ?y)
+		(not (in ?y ?z))
+		(not (available ?p ?x))
+	)
+)
+
+)

pddl/multi-agent-examples/depot/pfile1.pddl

@@ -0,0 +1,62 @@
+(define (problem depotprob1818) (:domain depot)
+(:objects
+	truck1 - truck
+	truck0 - truck
+	depot0 - depot
+	crate1 - crate
+	crate0 - crate
+	pallet1 - pallet
+	pallet0 - pallet
+	pallet2 - pallet
+	distributor1 - distributor
+	distributor0 - distributor
+
+	(:private depot0
+		hoist0 - hoist
+	)
+
+	(:private distributor0
+		hoist1 - hoist
+	)
+
+	(:private distributor1
+		hoist2 - hoist
+	)
+
+	(:private driver1
+		driver1 - driver
+	)
+
+	(:private driver0
+		driver0 - driver
+	)
+)
+(:init
+	(driving driver0 truck0)
+	(driving driver1 truck1)
+	(at pallet0 depot0)
+	(clear crate1)
+	(at pallet1 distributor0)
+	(clear crate0)
+	(at pallet2 distributor1)
+	(clear pallet2)
+	(at truck0 distributor1)
+	(at truck1 depot0)
+	(at hoist0 depot0)
+	(available depot0 hoist0)
+	(at hoist1 distributor0)
+	(available distributor0 hoist1)
+	(at hoist2 distributor1)
+	(available distributor1 hoist2)
+	(at crate0 distributor0)
+	(on crate0 pallet1)
+	(at crate1 depot0)
+	(on crate1 pallet0)
+)
+(:goal
+	(and
+		(on crate0 pallet2)
+		(on crate1 pallet1)
+	)
+)
+)