Street intersections

[1ec5]

One of the more popular Overpass queries (based on people asking for it) is for street intersections in a given area. Overpass is able to do this in part because it can easily recurse from a way to its members and also has a way_link: evaluator for counting the number of way segments (edges in a routing graph) that intersect at a given point.

Since there aren’t any triples explicitly tying ways to their constituent nodes (ad-freiburg/osm2rdf#72), we’d have to ignore connectedness, which may mishandle some double-decker roads and such. This is the closest I’ve come for street intersections in Chicago:

PREFIX osmkey: <https://www.openstreetmap.org/wiki/Key:>
PREFIX osmrel: <https://www.openstreetmap.org/relation/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX osm: <https://www.openstreetmap.org/>
PREFIX ogc: <http://www.opengis.net/rdf#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
SELECT ?intersection (COUNT(DISTINCT ?street) as ?count_street) (GROUP_CONCAT(DISTINCT ?name; SEPARATOR=" at ") as ?names) (SAMPLE(?geometry) as ?intersection_geometry) WHERE {
  ?street osmkey:highway ?classification .
  ?street rdf:type osm:way .
  ?street osmkey:name ?name .
  osmrel:122604 ogc:sfIntersects ?intersection .
  ?street ogc:sfIntersects ?intersection .
  ?intersection rdf:type osm:node .
  ?intersection geo:hasGeometry/geo:asWKT ?geometry .
}
GROUP BY ?intersection
HAVING(COUNT(DISTINCT ?name) >= 2)

Unfortunately, this still only returns nodes that have tags on them, which happen to be at the major intersections but not the minor intersections:

I’ve also tried the max-distance-in-meters predicate, but it seems to only support point-to-point searches, rather than linestring-to-point.

[hannahbast]

@1ec5 Thanks for the great query! osm2rdf has an option --add-way-node-order, which adds the information which nodes (untagged or not) are contained in which ways. Here is a SPARQL query on an endpoint for the OSM data of Germany, where you can see it in action. The query shows all intersections in Berlin (osmrel:62422). You can, of course, pick any region and even omit that triple and get all street intersections in Germany.

SELECT ?intersection ?street_names ?geometry WHERE {
  {
    SELECT ?intersection (GROUP_CONCAT(DISTINCT ?name; SEPARATOR=", ") AS ?street_names) WHERE {
      osmrel:62422 ogc:sfContains ?street .
      ?street osmkey:highway [] .
      ?street osmkey:name ?name .
      ?street osmway:node/osmway:node ?intersection .
    }
    GROUP BY ?intersection
    HAVING (COUNT(DISTINCT ?name) >= 2)
  }
  ?intersection geo:hasGeometry/geo:asWKT ?geometry .
}

https://qlever.cs.uni-freiburg.de/osm-test/ODVKGh

[hannahbast]

@1ec5 I will build the next index for the whole planet (planet-241223.osm.pbf) with the --add-way-node-order option, then this should also work on https://qlever.cs.uni-freiburg.de/osm-planet .

We are also working on integrating our spatial join library into QLever. We currently use this library only in the pre-processing, to compute the ogc:sf... triples. When integrated into QLever, it can be used for arbitrary spatial joins at query time.

[1ec5]

Wow, that would be wonderful! Thank you, and happy new year!

[hannahbast]

@1ec5 It now also works for the whole planet. For example, here are all intersections of (named) streets in Chicago: https://qlever.cs.uni-freiburg.de/osm-planet/bZHGhm . It even works for the whole US (takes a while though): https://qlever.cs.uni-freiburg.de/osm-planet/1DHcyB .

[1ec5]

Thanks so much for your help! I added this example to the OSM Wiki so people can find it more easily. This functionality will come in handy for a variety of purposes.Thanks so much for your help! I added this example to the OSM Wiki so people can find it more easily. This functionality will come in handy for a variety of purposes.