New greeting, new clothes and hair, and hair sprite adjustments

Monika After Story/game/event-rules.rpy

@@ -15,6 +15,7 @@ init -1 python:
     EV_RULE_AFF_RANGE = "affection_range"
     EV_RULE_PRIORITY = "rule_priority"
     EV_RULE_PROBABILITY = "rule_probability"
+    EV_RULE_RP_TIMEDELTA = "rp_timedelta"
 
 
     # special constants for numerical repeat rules
@@ -795,6 +796,72 @@ init -1 python:
             """
             return ev.rules.get(EV_RULE_PROBABILITY, MASProbabilityRule.DEF_PROBABILITY)
 
+    class MASTimedeltaRepeatRule(object):
+        """
+        Static class used to create repeat rules.
+        Timedelta repeat rules allow events to be repeated only every 'timedelta' since their last seen.
+        """
+        @staticmethod
+        def create_rule(timedelta, ev=None):
+            """
+            IN:
+                timedelta - the timedelta to set
+
+                ev - the event to add this rule to
+                    (Default: None)
+
+            OUT:
+                dict containing the rule
+            """
+            if not isinstance(timedelta, datetime.timedelta):
+                raise TypeError(
+                    "Expected a datetime.timedelta object, got: '{0}'.".format(timedelta)
+                )
+
+            elif not timedelta:
+                raise ValueError(
+                    "Expected a datetime.timedelta object with a non-null value."
+                )
+
+            rule = {EV_RULE_RP_TIMEDELTA: timedelta}
+
+            if ev:
+                ev.rules.update(rule)
+
+            return rule
+
+        @staticmethod
+        def evaluate_rule(event=None, rule=None, now=None):
+            """
+            Evaluates a MASTimedeltaRepeatRule rule
+
+            IN:
+                event - the event to evaluate
+                rule - the timedelta of the MASTimedeltaRepeatRule to check against,
+                    if None, we get it from the event
+                    (Default: None)
+                now - time to check against, if None, datetime.datetime.now() is used
+                    (Default: None)
+
+            OUT:
+                boolean whether or not the event's passed
+            """
+            # No event, no deal
+            if event is None:
+                return False
+
+            if rule is None:
+                rule = event.rules.get(EV_RULE_RP_TIMEDELTA, None)
+
+            # Empty timedelta? You passed
+            if not rule:
+                return True
+
+            if now is None:
+                now = datetime.datetime.now()
+
+            return event.timePassedSinceLastSeen_dt(rule, now)
+
 init python:
     # these rules are NOT actually event rules since they don't create rule
     # data in Event.

Monika After Story/game/script-ch30.rpy

@@ -2086,6 +2086,22 @@ label ch30_reset:
     # build background filter data and update the current filter progression
     $ store.mas_background.buildupdate()
 
+    # Handle cleanup for the bath greeting
+    $ bath_cleanup_ev = mas_getEV("mas_after_bath_cleanup")
+    if (
+        bath_cleanup_ev is not None
+        and bath_cleanup_ev.start_date is not None
+    ):
+        # Moni was alone for at least 10 minutes
+        # And it is the time to run the cleanup event
+        if (
+            mas_dockstat.retmoni_status is None
+            and mas_getAbsenceLength() >= datetime.timedelta(minutes=10)
+            and bath_cleanup_ev.start_date > datetime.datetime.now()
+        ):
+            call mas_after_bath_cleanup_change_outfit
+            $ mas_stripEVL("mas_after_bath_cleanup", list_pop=True, remove_dates=True)
+
     #set MAS window global
     $ mas_windowutils._setMASWindow()
 

Monika After Story/game/script-farewells.rpy

@@ -107,6 +107,7 @@ init -1 python in mas_farewells:
             store.MASSelectiveRepeatRule.evaluate_rule(check_time, ev, defval=True)
             and store.MASNumericalRepeatRule.evaluate_rule(check_time, ev, defval=True)
             and store.MASGreetingRule.evaluate_rule(ev, defval=True)
+            and store.MASTimedeltaRepeatRule.evaluate_rule(ev)
         ):
             return False
 

Monika After Story/game/script-greetings.rpy

@@ -181,12 +181,13 @@ init -1 python in mas_greetings:
 
         # rule checks
         if not (
-                store.MASSelectiveRepeatRule.evaluate_rule(
-                    check_time, ev, defval=True)
-                and store.MASNumericalRepeatRule.evaluate_rule(
-                    check_time, ev, defval=True)
-                and store.MASGreetingRule.evaluate_rule(ev, defval=True)
-            ):
+            store.MASSelectiveRepeatRule.evaluate_rule(
+                check_time, ev, defval=True)
+            and store.MASNumericalRepeatRule.evaluate_rule(
+                check_time, ev, defval=True)
+            and store.MASGreetingRule.evaluate_rule(ev, defval=True)
+            and store.MASTimedeltaRepeatRule.evaluate_rule(ev)
+        ):
             return False
 
         # conditional check
@@ -1626,6 +1627,39 @@ label monikaroom_greeting_ear_renpy_docs:
 
     jump monikaroom_greeting_choice
 
+init 5 python:
+    gmr.eardoor.append("monikaroom_greeting_ear_recursionerror")
+
+label monikaroom_greeting_ear_recursionerror:
+    m "Hmm, now that looks good. Let's-{w=0.5}{nw}"
+    m "Wait, no. Gosh, how did I forget..."
+    m "This has to be called right here."
+
+    python:
+        for loop_count in range(random.randint(2, 3)):
+            renpy.say(m, "Great! Alright, let's see...")
+
+    show noise
+    play sound "sfx/s_kill_glitch1.ogg"
+    pause 0.1
+    stop sound
+    hide noise
+
+    m "{cps=*2}What?!{/cps} {w=0.25}A RecursionError?!"
+    m "'Maximum recursion depth exceeded...'{w=0.7} How is this even happening?"
+    m "..."
+
+    if mas_isMoniUpset():
+        m "...Keep going, Monika, you'll figure this out."
+        call monikaroom_greeting_ear_prog_upset
+    elif mas_isMoniDis():
+        m "...Keep{w=0.1} it{w=0.1} going{w=0.1}, Monika. You {i}have{/i} to do this."
+        call monikaroom_greeting_ear_prog_dis
+    else:
+        m "Phew, at least everything else is fine."
+
+    jump monikaroom_greeting_choice
+
 ## ear door processing
 init 10 python:
 
@@ -4297,7 +4331,7 @@ label greeting_back_from_hangout:
     return
 
 init 5 python:
-    ev_rules = {}
+    ev_rules = dict()
     ev_rules.update(
         MASGreetingRule.create_rule(
             random_chance=3,
@@ -4368,38 +4402,185 @@ label greeting_spacing_out:
     m 1hubsb "Ahaha~"
     m 1eua "I'm very happy to see you again. {w=0.2}{nw}"
     extend 3eua "What should we do today, [player]?"
-
     return
 
 init 5 python:
-    gmr.eardoor.append("monikaroom_greeting_ear_recursionerror")
+    ev_rules = dict()
+    ev_rules.update(
+        MASGreetingRule.create_rule(
+            skip_visual=True,
+            random_chance=20,
+            override_type=True
+        )
+    )
+    ev_rules.update(
+        MASTimedeltaRepeatRule.create_rule(
+            datetime.timedelta(days=3)
+        )
+    )
 
-label monikaroom_greeting_ear_recursionerror:
-    m "Hmm, now that looks good. Let's-{w=0.5}{nw}"
-    m "Wait, no. Gosh, how did I forget..."
-    m "This has to be called right here."
+    addEvent(
+        Event(
+            persistent.greeting_database,
+            eventlabel="greeting_after_bath",
+            conditional=(
+                "mas_getAbsenceLength() >= datetime.timedelta(hours=6) "
+                "and not mas_isSpecialDay()"
+            ),
+            unlocked=True,
+            rules=ev_rules,
+            aff_range=(mas_aff.LOVE, None)
+        ),
+        code="GRE"
+    )
+
+    del ev_rules
+
+init 1:
+    # NOTE this should be defined AFTER init 0
+    # NOTE: default may be not completely reliable, always save the snapshot yourself
+    default persistent._mas_previous_moni_state = monika_chr.save_state(True, True, True, True)
+
+label greeting_after_bath:
+    python hide:
+        # Some preperations
+        mas_RaiseShield_core()
+        mas_startupWeather()
+        # Save current outfit
+        persistent._mas_previous_moni_state = monika_chr.save_state(True, True, True, True)
+        # Now let Moni get a towel
+        monika_chr.change_clothes(
+            random.choice(MASClothes.by_exprop(mas_sprites.EXP_C_WET, None)),
+            by_user=False,
+            outfit_mode=True
+        )
+        # In case the towel already set an appropriate hair, we don't change it
+        if not monika_chr.is_wearing_hair_with_exprop(mas_sprites.EXP_H_WET):
+            monika_chr.change_hair(mas_hair_wet, by_user=False)
+        # We leave this acs to the clothes PPs in case the towel we chose doesn't support it
+        # if not monika_chr.is_wearing_acs(mas_acs_water_drops):
+        #     monika_chr.wear_acs(mas_acs_water_drops)
+        # Setup the cleaup event
+        mas_setEVLPropValues(
+            "mas_after_bath_cleanup",
+            start_date=datetime.datetime.now() + datetime.timedelta(minutes=random.randint(30, 90)),
+            action=EV_ACT_QUEUE
+        )
+        mas_startup_song()
+
+    # Now show everything
+    call spaceroom(hide_monika=True, dissolve_all=True, scene_change=True, show_emptydesk=True)
+
+    $ renpy.pause(random.randint(5, 15), hard=True)
+    call mas_transition_from_emptydesk("monika 1huu")
+    $ renpy.pause(2.0)
+    $ quick_menu = True
+
+    m 1wuo "Oh! {w=0.2}{nw}"
+    extend 2wuo "[player]! {w=0.2}{nw}"
+    extend 2lubsa "I was thinking about you."
+
+    $ bathing_showering = random.choice(("bathing", "showering"))
+
+    if mas_getEVL_shown_count("greeting_after_bath") < 5:
+        m 7lubsb "I just finished [bathing_showering]...{w=0.3}{nw}"
+        extend 1ekbfa "you don't mind me being in my towel, do you?~"
+        m 1hubfb "Ahaha~"
+        m 3hubsa "I'll get ready soon, let me wait for my hair to dry off a little more first."
+
+    # Gets used to it
+    else:
+        m 7eubsb "I just finished [bathing_showering]."
+
+        if mas_canShowRisque() and random.randint(0, 3) == 0:
+            m 1msbfb "I bet you wish you could've joined me there..."
+            m 1tsbfu "Well, maybe one day~"
+            m 1hubfb "Ahaha~"
+
+        else:
+            m 1eua "I'll get dressed soon~"
 
     python:
-        for loop_count in range(random.randint(2, 3)):
-            renpy.say(m, "Great! Alright, let's see...")
+        # enable music menu and music hotkeys
+        mas_MUINDropShield()
+        # keymaps should be set
+        set_keymaps()
+        # show the overlays
+        mas_OVLShow()
 
-    show noise
-    play sound "sfx/s_kill_glitch1.ogg"
-    pause 0.1
-    stop sound
-    hide noise
+        del bathing_showering
 
-    m "{cps=*2}What?!{/cps} {w=0.25}A RecursionError?!"
-    m "'Maximum recursion depth exceeded...'{w=0.7} How is this even happening?"
-    m "..."
+    return
+
+# NOTE: This is not a greeting, but a followup for the greeting above, so I decided to keep them together
+init 5 python:
+    addEvent(Event(persistent.event_database, eventlabel="mas_after_bath_cleanup", show_in_idle=True, rules={"skip alert": None}))
+
+label mas_after_bath_cleanup:
+    # Sanity check (checking for towel should be enough)
+    if (
+        not monika_chr.is_wearing_clothes_with_exprop(mas_sprites.EXP_C_WET)
+        and not monika_chr.is_wearing_hair_with_exprop(mas_sprites.EXP_H_WET)
+    ):
+        return
+
+    if mas_globals.in_idle_mode or (mas_canCheckActiveWindow() and not mas_isFocused()):
+        m 1eua "I'm going to get dressed.{w=0.3}.{w=0.3}.{w=0.3}{nw}"
 
-    if mas_isMoniUpset():
-        m "...Keep going, Monika, you'll figure this out."
-        call monikaroom_greeting_ear_prog_upset
-    elif mas_isMoniDis():
-        m "...Keep{w=0.1} it{w=0.1} going{w=0.1}, Monika. You {i}have{/i} to do this."
-        call monikaroom_greeting_ear_prog_dis
     else:
-        m "Phew, at least everything else is fine."
+        m 1eua "Give me a moment [mas_get_player_nickname()], {w=0.2}{nw}"
+        extend 3eua "I'm going to get dressed."
 
-    jump monikaroom_greeting_choice
+    window hide
+    call mas_transition_to_emptydesk
+
+    $ renpy.pause(1.0, hard=True)
+    call mas_after_bath_cleanup_change_outfit
+    $ renpy.pause(random.randint(10, 15), hard=True)
+
+    call mas_transition_from_emptydesk("monika 3hub")
+    window auto
+
+    if mas_globals.in_idle_mode or (mas_canCheckActiveWindow() and not mas_isFocused()):
+        m 3hub "All done!{w=1}{nw}"
+
+    else:
+        m 3hub "Alright, I'm back!~"
+        m 1eua "So what would you like to do today, [player]?"
+
+    return
+
+label mas_after_bath_cleanup_change_outfit:
+    # TODO: Rng outfit selection wen
+    python hide:
+        if monika_chr.is_wearing_clothes_with_exprop(mas_sprites.EXP_C_WET):
+            prev_clothes = mas_sprites.get_sprite(mas_sprites.SP_CLOTHES, persistent._mas_previous_moni_state[0])
+            # Fallback just in case
+            if prev_clothes is None or prev_clothes.hasprop(mas_sprites.EXP_C_WET):
+                if mas_isMoniHappy(higher=True):
+                    prev_clothes = mas_clothes_blazerless
+
+                else:
+                    prev_clothes = mas_clothes_def
+
+            monika_chr.change_clothes(
+                prev_clothes,
+                by_user=False,
+                outfit_mode=True
+            )
+
+        if monika_chr.is_wearing_hair_with_exprop(mas_sprites.EXP_H_WET):
+            # I think it's better to always select new random hair, even after using outfit mode
+            prev_hair = random.choice(
+                [
+                    hair_obj
+                    for hair_obj in mas_sprites.HAIR_MAP.itervalues()
+                    if not hair_obj.hasprop(mas_sprites.EXP_H_WET) and mas_sprites.is_clotheshair_compatible(monika_chr.clothes, hair_obj)
+                ]
+            )
+            monika_chr.change_hair(
+                prev_hair,
+                by_user=False
+            )
+
+    return