Merge pull request #9627 from Booplicate/unomas_outfit

NOU outfit

Monika After Story/game/script-greetings.rpy

@@ -4663,3 +4663,129 @@ label mas_after_bath_cleanup:
 label mas_after_bath_cleanup_change_outfit:
     $ mas_after_bath_cleanup_change_outfit()
     return
+
+
+init 5 python:
+    ev_rules = dict()
+    ev_rules.update(
+        MASGreetingRule.create_rule(
+            skip_visual=True,
+            random_chance=10,
+            override_type=True
+        )
+    )
+
+    addEvent(
+        Event(
+            persistent.greeting_database,
+            eventlabel="greeting_found_nou_shirt",
+            conditional=(
+                "mas_getAbsenceLength() >= datetime.timedelta(hours=3) "
+                "and mas_nou.get_wins_for('Player') > {0} "
+                "and mas_nou.get_total_games() > {1} "
+                "and not mas_isSpecialDay() "
+                "and not mas_SELisUnlocked(mas_clothes_nou_shirt)"
+            ).format(random.randint(45, 65), random.randint(95, 115)),
+            unlocked=True,
+            rules=ev_rules,
+            aff_range=(mas_aff.AFFECTIONATE, None)
+        ),
+        code="GRE"
+    )
+
+    del ev_rules
+
+default persistent._mas_pm_snitched_on_chibika = None
+
+label greeting_found_nou_shirt:
+    python:
+        mas_RaiseShield_core()
+        mas_startupWeather()
+        monika_chr.change_clothes(mas_clothes_nou_shirt, by_user=False, outfit_mode=True)
+        glitch_option_text = glitchtext(7)
+
+    call spaceroom(hide_monika=True, dissolve_all=True, scene_change=True, show_emptydesk=True)
+    pause 2.5
+
+    m "There you are! {w=0.2}I was waiting for you~"
+    m "I have to admit, {w=0.1}I don't know how you were able to put this in my wardrobe without me noticing, [player]...{nw}"
+    $ _history_list.pop()
+    show screen mas_background_timed_jump(5, "greeting_found_nou_shirt.menu_skip")
+    menu:
+        m "I have to admit, I don't know how you were able to put this in my wardrobe without me noticing, [player]...{fast}"
+
+        "It's a secret.":
+            hide screen mas_background_timed_jump
+            jump greeting_found_nou_shirt.menu_choice_secret
+
+        "It was [glitch_option_text]!":
+            hide screen mas_background_timed_jump
+            $ persistent._mas_pm_snitched_on_chibika = True
+            $ renpy.invoke_in_thread(
+                mas_utils.trywrite,
+                os.path.join(renpy.config.basedir, "characters/for snitch.txt"),
+                ">:("
+            )
+            jump greeting_found_nou_shirt.menu_choice_other
+
+        "I have no idea...":
+            hide screen mas_background_timed_jump
+            jump greeting_found_nou_shirt.menu_choice_other
+
+    label .post_menu:
+        pass
+
+    m 1ekbla "Thanks, [player]."
+    m 1tfu "Don't think I'll go any easier on you, though~"
+
+    if mas_nou.get_wins_for('Player') >= mas_nou.get_wins_for('Monika'):
+        m 1rtsdlb "In fact, {w=0.1}maybe I should try harder, ahaha..."
+
+    m 3ttb "Are you up for a game, [mas_get_player_nickname()]?"
+
+    python:
+        mas_selspr.unlock_clothes(mas_clothes_nou_shirt)
+        mas_selspr.save_selectables()
+        mas_lockEVL("greeting_found_nou_shirt", "GRE")
+        renpy.save_persistent()
+
+        del glitch_option_text
+
+        mas_MUINDropShield()
+        set_keymaps()
+        HKBShowButtons()
+        mas_startup_song()
+        enable_esc()
+    return
+
+label greeting_found_nou_shirt.menu_skip:
+    hide screen mas_background_timed_jump
+    call mas_transition_from_emptydesk("monika 4sub")
+    m "But I love it~"
+
+    jump greeting_found_nou_shirt.post_menu
+
+label greeting_found_nou_shirt.menu_choice_secret:
+    if mas_isMoniEnamored(higher=True):
+        call mas_transition_from_emptydesk("monika 2tublu")
+        m "{cps=*1.5}You don't peek there {i}often{/i}, do you?~{/cps}{w=0.1}{nw}"
+        $ _history_list.pop()
+        m 2lusdla "Anyway... {w=0.3}{nw}"
+
+    else:
+        call mas_transition_from_emptydesk("monika 2rtblsdlu")
+        m "Hmm, anyway... {w=0.3}{nw}"
+
+    extend 4sub "I really love this new outfit!"
+
+    jump greeting_found_nou_shirt.post_menu
+
+label greeting_found_nou_shirt.menu_choice_other:
+    show noise zorder 500 onlayer overlay:
+        alpha 0.0
+        easein_elastic 0.5 alpha 0.1
+    play sound "sfx/s_kill_glitch1.ogg"
+    pause 0.5
+    hide noise onlayer overlay
+
+    jump greeting_found_nou_shirt.menu_skip

Monika After Story/game/script-story-events.rpy

@@ -1633,7 +1633,7 @@ label mas_corrupted_persistent:
         call mas_showpoem(mas_note_backups_all_good)
 
     window auto
-    $ _gtext = glitchtext(15)
+    $ _gtext = glitchtext(7)
 
     m 1ekc "Do you know what this is about?{nw}"
     $ _history_list.pop()
@@ -1643,6 +1643,7 @@ label mas_corrupted_persistent:
             jump mas_corrupted_persistent_post_menu
 
         "It's about [_gtext].":
+            $ persistent._mas_pm_snitched_on_chibika = True
             $ disable_esc()
             $ mas_MUMURaiseShield()
             window hide

Monika After Story/game/zz_history.rpy

@@ -1119,6 +1119,7 @@ init -810 python:
 
             # actions / mas
             "_mas_pm_has_went_back_in_time": "pm.actions.mas.went_back_in_time",
+            "_mas_pm_snitched_on_chibika": "pm.actions.mas.snitched_on_chibika",
 
             # actions / mas / music
             "_mas_pm_added_custom_bgm": "pm.actions.mas.music.added_custom_bgm",

Monika After Story/game/zz_spriteobjects.rpy

@@ -2871,6 +2871,49 @@ init -1 python:
     )
     store.mas_sprites.init_clothes(mas_clothes_bath_towel_white)
 
+    ### NOU SHIRT
+    ## nou_shirt
+    # NOU-themed shirt
+    # Thanks Eroneko (Finikyu's commission)
+    mas_clothes_nou_shirt = MASClothes(
+        "nou_shirt",
+        "nou_shirt",
+        MASPoseMap(
+            default=True,
+            use_reg_for_l=True
+        ),
+        stay_on_start=True,
+        ex_props={
+            store.mas_sprites.EXP_C_C_DTS: True
+        },
+        pose_arms=MASPoseArms(
+            {
+                9: MASArmRight(
+                    "def",
+                    {
+                        MASArm.LAYER_MID: True,
+                    }
+                ),
+            }
+        )
+    )
+    store.mas_sprites.init_clothes(mas_clothes_nou_shirt)
+    store.mas_selspr.init_selectable_clothes(
+        mas_clothes_nou_shirt,
+        "Shirt (NOU)",
+        "nou_shirt",
+        "clothes",
+        visible_when_locked=False,
+        hover_dlg=None,
+        select_dlg=[
+            "No U! Ehehe~",
+            "Ready to draw some more cards?~",
+            "Colorful!",
+            "Plus 10 to luck~",
+            "Up for a game, [player]?"
+        ]
+    )
+
 
 #### ACCCESSORY VARIABLES (SPR230)
 # variables that accessories may need for enabling / disabling / whatever