Lesson 9: My fullfillRandomWords() function does not get called automatically after deploying on testnet

[AyodejiKomolafe]

Following along with Patrick. we literally have the same code. all tests passed both on locahost and sepolia testnet.

I have deployed and verified successfully. consumer was added successfully and i was able to create upkeep and add the contract address.

My problem now is when i enter raffle, no winner is picked. Raffle stays open and i have tried this 4 times each time deploying the contract after trying to switch a couple things around but same thing. No winner is picked.

I have attached a picture of my upkeeps that stays pending for over an hour.

Also a screenshot of the transaction hash that shows the logs: winner picked is not being logged. i dont think my fulfillRandomWords() gets called as its the function that emits the winner.

Please Help

here is my latest upkeep transaction hash
[]https://sepolia.etherscan.io/tx/0xf47b47f418a3d87aea437db440729d60684ac2c8a3b69dc33321c63f48e88d3b#eventlog

my Raffle.sol contract

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.18;

/**
 * @title A sample Raffle Contract
 * @author Ayodeji Komolafe
 * @notice This contract is creating a raffle/lottery
 * @dev Implememts Chainlink VRFv2
 */
import {VRFCoordinatorV2Interface} from "@chainlink/contracts/src/v0.8/interfaces/VRFCoordinatorV2Interface.sol";
import {VRFConsumerBaseV2} from "@chainlink/contracts/src/v0.8/VRFConsumerBasev2.sol";
import {AutomationCompatibleInterface} from "@chainlink/contracts/src/v0.8/interfaces/AutomationCompatibleInterface.sol";

contract Raffle is VRFConsumerBaseV2, AutomationCompatibleInterface {
    error Raffle__NotEnoughEthSent();
    error Raffle_EnoughTimeNotPassed();
    error Raffle__TransferFailed();
    error Raffle__RaffleNotOpen();
    error Raffle__UpkeepNotNeeded();

    enum RaffleState {
        OPEN,
        CALCULATING
    }

    uint16 private constant REQUEST_CONFIRMATIONS = 3;
    uint32 private constant NUM_WORDS = 1;

    uint256 private immutable i_entranceFee;
    uint256 private immutable i_interval;
    VRFCoordinatorV2Interface private immutable i_vrfCoordinator;
    bytes32 private immutable i_gasLane;
    uint64 private immutable i_subscriptionId;
    uint32 private immutable i_callbackGasLimit;

    address payable[] private s_players;
    uint256 private s_lastTimestamp;
    address private s_recentWinner;
    RaffleState private s_raffleState;

    /**Events */
    event RaffleEntered(address indexed player);
    event WinnerPicked(address indexed winner);
    event RequestedRaffleWinner(uint256 indexed requestId);

    constructor(
        uint256 entranceFee,
        uint256 interval,
        address vrfCoordinator,
        bytes32 gasLane,
        uint64 subscriptionId,
        uint32 callbackGasLimit
    ) VRFConsumerBaseV2(vrfCoordinator) {
        i_entranceFee = entranceFee;
        i_interval = interval;
        s_lastTimestamp = block.timestamp;
        i_vrfCoordinator = VRFCoordinatorV2Interface(vrfCoordinator);
        i_gasLane = gasLane;
        i_subscriptionId = subscriptionId;
        i_callbackGasLimit = callbackGasLimit;
        s_raffleState = RaffleState.OPEN;
    }

    function enterRaffle() external payable {
        if (msg.value < i_entranceFee) {
            revert Raffle__NotEnoughEthSent();
        }
        if (s_raffleState != RaffleState.OPEN) {
            revert Raffle__RaffleNotOpen();
        }
        s_players.push(payable(msg.sender));
        emit RaffleEntered(msg.sender);
    }

    /**
     * @dev This is the function that the ChainLink Automation nodes call
     * to see if its time to perform upkeep.
     * the following should be true for this to return true:
     * 1. The time interval has passed between raffle runs.
     * 2. The raffle is in the OPEN state.
     * 3. The contract has ETH(meaning players have entered the raffle).
     * 4(Implicit) The subscription is funded with LINK
     * @return upkeepNeeded
     */

    function checkUpkeep(
        bytes memory /* checkData */
    ) public view returns (bool upkeepNeeded, bytes memory /* performData */) {
        bool isOpen = RaffleState.OPEN == s_raffleState;
        bool timePassed = (block.timestamp - s_lastTimestamp) > i_interval;
        bool hasBalance = address(this).balance > 0;
        bool hasPlayers = s_players.length > 0;
        upkeepNeeded = (timePassed && isOpen && hasBalance && hasPlayers);
        return (upkeepNeeded, "0x0");
    }

    function performUpkeep(bytes calldata /* performData */) external {
        (bool upKeepNeeded, ) = checkUpkeep("");
        if (!upKeepNeeded) {
            revert Raffle__UpkeepNotNeeded();
        }
        s_raffleState = RaffleState.CALCULATING;
        uint256 requestId = i_vrfCoordinator.requestRandomWords(
            i_gasLane,
            i_subscriptionId,
            REQUEST_CONFIRMATIONS,
            i_callbackGasLimit,
            NUM_WORDS
        );
        emit RequestedRaffleWinner(requestId);
    }

    function fulfillRandomWords(
        uint256 /*requestId*/,
        uint256[] memory randomWords
    ) internal override {
        uint256 indexOfWinner = randomWords[0] % s_players.length;
        address payable winner = s_players[indexOfWinner];
        s_recentWinner = winner;
        s_players = new address payable[](0);
        s_raffleState = RaffleState.OPEN;
        s_lastTimestamp = block.timestamp;
        emit WinnerPicked(winner);
        (bool success, ) = winner.call{value: address(this).balance}("");
        if (!success) {
            revert Raffle__TransferFailed();
        }
    }

    /**Getter Functions */

    function getEntranceFee() public view returns (uint256) {
        return i_entranceFee;
    }

    function getRaffleState() public view returns (RaffleState) {
        return s_raffleState;
    }

    function getPlayer(uint256 indexOfPlayer) public view returns (address) {
        return s_players[indexOfPlayer];
    }

    function getRecentWinner() external view returns (address) {
        return s_recentWinner;
    }

    function getLengthOfPlayers() external view returns (uint256) {
        return s_players.length;
    }

    function getLastTimestamp() external view returns (uint256) {
        return s_lastTimestamp;
    }
}

[EngrPips]

Why does the link share show a successful transaction and that the transaction was 52 days ago?

[AyodejiKomolafe]

@EngrPips i must have copied the wrong link.

here is the right one
[]https://sepolia.etherscan.io/tx/0x7b71ab85cca647916515c84a0fb58dc74cc200a3e29c7f0b54738d8bcf59c3d7#eventlog

[EngrPips]

Hello @AyodejiKomolafe, I think the problem arose because you created a VRFV2.5 subscription, but you inherited VRFConsumerBaseV2 instead of VRFConsumerBaseV2Plus so when the VRF coordinator wants to call back into your contract to deliver the random number which will be done by calling your fulfillRandomWords function it found out your contract is not of type VRFConsumerBaseV2Plus and the call fail. If you have created subId on the chainlink user interface, you should inherit VRFConsumerBaseV2Plus instead of ``VRFConsumerBaseV2`.

[EngrPips]

@AyodejiKomolafe, You are welcome.

[AyodejiKomolafe]

@EngrPips did you find anything that could cause my raffle not to pick a winner?

[EngrPips]

Hello @AyodejiKomolafe, I think they stopped returning random numbers to a contract that implemented the v2 of VRFComsumerBase, but I am unsure. I am writing the version that would implement the latest version of VRF and see if everything works fine. I will let you know once I finish implementing it.

[AyodejiKomolafe]

@EngrPips I finally got it to work. turns out you need to have more than enough LINK for the performUpkeep to go ahead and call fulfillRandomwords(). I was able to see this after completing the code using the the VRFCoordinator version 2.5. the user interface on their website hints at needing to add more link so i did and the contract picked a winner successfully.

Even though it didn't spend a lot but i guess i needed to have the max link fee of about 36LINK.

After this ran successfully, I went back to the original raffle where the VRFV2 was used and i added more link to the subscription. I had two performUpkeep that was pending for over 18hours. both were successful immediately i added the excess LINK.

Just to be sure and safe, i redeployed a new contract and created a new upkeep, entered the raffle and sure enough in less than a minute, A winner was picked.

I am so delighted at my outcome. Thank you so much for your time and patience and thanks to Raman for his time too. He is a MVP !!!

[EngrPips]

Interesting, that is what programmers do: Figure out things. Keep crushing it.