A                                      DSPSIZ(27 132 *DS4)
     A                                      REF(*LIBL/INFLDREF INLMAPR)
     A                                      CHGINPDFT(HI CS FE)
     A                                      MSGLOC(27)
     A                                      PRINT
     A                                      INDARA
     A                                      ALTHELP(CA01)
     A**********************************************************************  �
     A* SCREEN 2 SUBFILE
     A**********************************************************************  �
     A          R S02
     A*%%TS  SD  20030829  111543  CGIGER      REL-V5R1M0  5722-WDS
     A                                      SFL
     A  25                                  SFLNXTCHG
     A            S2QUAD         5   O  9  2
     A            S2EQ#         15   O  9 12
     A            S2AEQ#        15   O  9 29
     A            S2STAT        25   O  9 46
     A            S2BEGD         6Y 0O  9 73EDTWRD('  /  / 0')
     A            S2BEGT          T  O  9 83TIMFMT(*HMS)
     A            S2ENDD         6Y 0O  9 93EDTWRD('  /  / 0')
     A            S2ENDT          T  O  9103TIMFMT(*HMS)
     A            S2STDY         6  0O  9113EDTCDE(Z)
     A            S2STTM         4  0O  9122EDTWRD('  : 0')
     A*%%GP SCREEN1    01
     A**********************************************************************  �
     A* SCREEN 2 CONTROL
     A**********************************************************************  �
     A          R C02
     A*%%TS  SD  20030829  111543  CGIGER      REL-V5R1M0  5722-WDS
     A                                      SFLCTL(S02)
     A                                      SFLSIZ(17)
     A                                      SFLPAG(16)
     A                                      HELP
     A                                      CA03
     A  27N29                               PAGEDOWN
     A                                      CHANGE(99)
     A                                      CF04
     A                                      CA12
     A                                      CA13
     A                                      RTNCSRLOC(&CSRREC &CSRFLD)
     A                                      RTNCSRLOC(*WINDOW &CSRROW &CSRCOL)
     A                                      CSRLOC(CSRPOSROW CSRPOSCOL)
     A                                      OVERLAY
     A                                      PROTECT
     A                                      SFLCSRRRN(&CSRRRN)
     A                                      SFLMODE(&C2MODE)
     A  27                                  SFLDSP
     A  28                                  SFLDSPCTL
     A N27                                  SFLCLR
     A  29                                  SFLEND
     A  11                                  SFLDROP(CF11)
     A N11                                  SFLFOLD(CF11)
     A            C2DSPR         4S 0H      SFLRCDNBR(CURSOR)
     A            C2MODE         1A  H
     A            CSRRRN         5S 0H
     A            CSRREC        10A  H
     A            CSRFLD        10A  H
     A            CSRROW         3S 0H
     A            CSRCOL         3S 0H
     A            CSRPOSROW      3S 0H
     A            CSRPOSCOL      3S 0H
     A            C2WHSE    R        O  3 29REFFLD(FLDREFR/WHS5)
     A                                      DSPATR(HI)
     A                                      EDTCDE(7)
     A                                  3 19'Location:'
     A                                  5 21'GPS ID:'
     A            C2AEQ#        15A  O  5 29DSPATR(HI)
     A                                  6 19'Quadrant:'
     A            C2QUAD         5A  O  6 29DSPATR(HI)
     A                                  4 17'Equipment#:'
     A            C2EQ#         15A  O  4 29DSPATR(HI)
     A                                  1 49'YARD INVENTORY TRANSACTION HISTORY-
     A                                       INQUIRY'
     A                                      DSPATR(HI)
     A                                  1124'IND2790'
     A            C2NAME        25   O  3 38DSPATR(HI)
     A                                  7 21'Status:'
     A            C2STAT        15   O  7 29DSPATR(HI)
     A                                  6 47'Start Date:'
     A            C2SDATE        6Y 0O  6 59EDTWRD('  /  / 0')
     A                                  6 71'End Date:'
     A            C2EDATE        6Y 0O  6 82EDTWRD('  /  / 0')
     A                                  8  2'Quadrant'
     A                                      DSPATR(HI)
     A                                  8 12'Equipment'
     A                                      DSPATR(HI)
     A                                  8 29'GPS ID'
     A                                      DSPATR(HI)
     A                                  8 46'Status'
     A                                      DSPATR(HI)
     A                                  7 76'Start'
     A                                      DSPATR(HI)
     A                                  8 77'Date'
     A                                      DSPATR(HI)
     A                                  7 86'Start'
     A                                      DSPATR(HI)
     A                                  8 87'Time'
     A                                      DSPATR(HI)
     A                                  7 98'End'
     A                                      DSPATR(HI)
     A                                  8 97'Date'
     A                                      DSPATR(HI)
     A                                  7108'End'
     A                                      DSPATR(HI)
     A                                  8107'Time'
     A                                      DSPATR(HI)
     A                                  7112'Time in'
     A                                      DSPATR(HI)
     A                                  7121'Status'
     A                                      DSPATR(HI)
     A                                  8115'Days'
     A                                      DSPATR(HI)
     A                                  8122'Hr:Mn'
     A                                      DSPATR(HI)