question-page.take

def: poster
    $ .user-details a
        | text ;                            : user_login
        | [href] ;                          : user_url
    $ .user-action-time span | [title] ;    : date

def: comments
    $ .comments .comment-body
        save each                               : comments
            $ .comment-user
                | text ;                            : user_login
                | [href] ;                          : user_url
            $ .comment-date span | [title] ;        : date



# get poster and comments for the question
$ .question ; +                                 : question
    $ .postcell .post-signature.owner
        poster ;                                    : asked_by
    comments ;                                   >> : comments

# get poster and comments for each answer
$ #answers .answer ; save each                  : answers
    $ .answercell .user-info | -1
        poster ;                                    : answered_by
    comments ;                                   >> : comments