repos.gradle

apply plugin: 'maven'

repositories {
  mavenCentral()
  maven { url ossSnapshotRepositoryUrl }
}

if (!project.version.endsWith('-SNAPSHOT')) {
  apply plugin: 'signing'
  signing {
    sign configurations.archives
  }
}

uploadArchives {
  repositories.mavenDeployer {
    if (project.version.endsWith('-SNAPSHOT')) { 
      repository(url: ossSnapshotRepositoryUrl) {
        authentication(userName: ossSnapshotRepositoryUserName, password: ossSnapshotRepositoryPassword)
      }
    } else {
      repository(url: ossReleaseRepositoryUrl) {
        authentication(userName: ossReleaseRepositoryUserName, password: ossReleaseRepositoryPassword)
      }
      beforeDeployment { deployment -> signing.signPom(deployment) }
    }
    pom.project {
      name pomProjectTitle
      packaging 'jar'
      description pomProjectDescription
      url "https://github.com/aestasit/${githubProjectName}"
      scm {
        url "scm:git@github.com:aestasit/${githubProjectName}.git"
        connection "scm:git@github.com:aestasit/${githubProjectName}.git"
        developerConnection "scm:git@github.com:aestasit/${githubProjectName}.git"
      }
      licenses {
        license {
          name 'The Apache Software License, Version 2.0'
          url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
          distribution 'repo'
        }
      }
      developers {
        developer {
          id 'aadamovich'
          name 'Andrey Adamovich'
        }
      }
    }
  }
}