Crossfading with delay when switching to live

[cdkey22]

Hello,

Here is the point :

I've got a queue with crossfade transition.
I've got something call live with will trigger sometimes openning a connection with an rtmp server.
When I switch to the rtmp server, I wan't to skip to the next song in order to make a fresh start after live.
I have tried multiple maneers to do that (custom annotations, dynamic value for cross parameters, ...) but no way.
When my rtmp stop i still hear to fadeout of the previous song and the fadein of the new song (for a duration defined in the crossfade).
When i remove the crossfading everything works fine.

{...}
crossfade_fade_in = ref(5.)
crossfade_fade_out = ref(5.)
crossfade_duration = ref(10.)

#Here is the queue

pl = request.queue()
with_cue_cut = cue_cut(mksafe(pl))
ambiance = mksafe(crossfade(fade_in=!crossfade_fade_in, fade_out=!crossfade_fade_out, duration=!crossfade_duration, with_cue_cut))

{...}

#Here is the live part

{...}

rtmp_url = ref("")
rtmp = input.ffmpeg(start=false, {!rtmp_url})
rtmp_1 = blank.strip(threshold=-500.0, max_blank=3.0, rtmp)
rtmp_2 = blank.strip(threshold=-40.0, max_blank=90.0, rtmp_1)
live = normalize(rtmp_2)

# Play Rtmp stream
def play_rtmp(uri) =
    log(level=2, "Playing rtmp uri #{uri}")
    rtmp.stop()
    rtmp_url := uri
    rtmp.start()
    pl.skip()
end

# Stop Rtmp stream
def stop_rtmp() =
    log(level=2, "Stopping rtmp stream")
    rtmp.stop()
end

{...}

From the slack I received the following from Romain Beauxis :

The problem here is that the crossfade has no way of knowing that it needs to apply a different transition when you issue that skip call. You will need to find a way to direct the crossfade to apply a different transition when skipping.
Generally speaking, this can be done by defining your own custom crossfade transition. To avoid rewritting the default transition, you can extend cross.simple or cross.smart depending on what you are using.
I'd suggest to:
Use a bool reference.
Set that bool reference to true when skipping.
Define a special transition that, when that bool is true, plays a sequence([old, new]) instead of a crossfade and sets the boolean back to false.

---

In order to implement what is suggested I did that
I've tried to make a new version of crossfade using a boolean to drive the crossfade effect.
It actually manage the crossfade but there is still few seconds playing old song before switching to new song (with no transition)
What am I doing wrong ?

def conditional_crossfade(~id=null(),
              ~duration=5.,
              ~override_duration="liq_cross_duration",
              ~fade_in=3.,
              ~fade_out=3.,
              ~default=(fun (a,b) -> (sequence([a, b]):source)),
              ~deduplicate=true,
              ~minimum=(-1.),
              ~width=2.,
              ~conservative=true,
              trigger_crossfade,
              s)
  id = string.id.default(default="crossfade", id)
  def log(~level=3,x) = log(label=id,level=level,x) end

  def conditional_transition(a,b)
    list.iter(fun(x)-> log(level=4,"Before: #{x}"), metadata.cover.remove(a.metadata))
    list.iter(fun(x)-> log(level=4,"After : #{x}"), metadata.cover.remove(b.metadata))

    if !trigger_crossfade then
        log("Simple transition: crossed, fade-in, fade-out.")
        cross.simple(fade_in=fade_in, fade_out=fade_out, a.source, b.source)
    else
        trigger_crossfade := true
        default(a.source, b.source)
    end
  end

  let (cross_id, deduplicate_id) = deduplicate ? (null(), null(id)) : (null(id), null())

  s = cross(id=cross_id, width=width, duration=duration, override_duration=override_duration,
            conservative=conservative, minimum=minimum, conditional_transition, s)

  if deduplicate then
    metadata.deduplicate(id=deduplicate_id, s)
  else
    s
  end
end

[cdkey22]

It seems to work if we remove conservative and minimum.

Constraint is that the next item in my queue has to be provided before the start of the crossfade (seems logic)

The code will change from

  s = cross(id=cross_id, width=width, duration=duration, override_duration=override_duration,
            conservative=conservative, minimum=minimum, conditional_transition, s)

to

  s = cross(id=cross_id, width=width, duration=duration, override_duration=override_duration,
            conservative=false minimum=0., conditional_transition, s)

Is this a good way to do it ?

[toots]

This could be good. I think that, to be able to give a better advice, I'd need to see more details around where the skip is applied and in relation to the new crossfade.

New crossfade looks great however, nice work!

[cdkey22]

I can give you the full liquidsoap script if you wan't but there is a lot of things inside.
For now it seems to work.
Thank you very much for all your advice.