genconfig.pl

#!/usr/bin/perl

use strict;
use warnings;

use DBCredentials;

use POSIX qw(getuid getgid);
use WebService::Dropbox;

sub setup_dropbox_credentials
{
	my $settings_file = $_[0];

	my $dropbox = WebService::Dropbox->new(DBCredentials::get_credentials());
	my $access_url = $dropbox->login or die($dropbox->error);
	print("Open this URL in browser and press ENTER:\n$access_url\n");
	<>;

	$dropbox->auth or die $dropbox->error;

	print $settings_file "\n# DropBox configuration\n";
	print $settings_file "access_token=".$dropbox->access_token."\n";
	print $settings_file "access_secret=".$dropbox->access_secret."\n";
	print $settings_file "access_type=sandbox\n";
}

sub setup_basic_configuration
{
	my ($settings_file, $mountpoint, $mode) = @_;

	print $settings_file "\n# FUSE settings configuration\n";
	print $settings_file "mountpoint=$mountpoint\n";
	print $settings_file "uid=".getuid()."\n";
	print $settings_file "gid=".getgid()."\n";
	printf $settings_file "mode=%#o\n", $mode;
}

sub create_config_file
{
	my ($path, $mountpoint, $mode) = @_;

	open my $settings_file, '>', $path;

	print $settings_file "# This file was automaticaly generated by genconfig.pl\n";
	print $settings_file "# ".localtime()."\n";

	setup_basic_configuration($settings_file, $mountpoint, $mode);
	setup_dropbox_credentials($settings_file);

	close $settings_file;
}

my $settings_file_path = shift || $ENV{HOME}."/.perldrops";
my $mountpoint = shift || "/mnt";
my $mode = shift || 0644;

create_config_file($settings_file_path, $mountpoint, $mode);