-
Notifications
You must be signed in to change notification settings - Fork 830
/
Copy pathoverworld.asm
1812 lines (1545 loc) · 27.3 KB
/
overworld.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
FieldMoveJumptableReset:
xor a
ld hl, wFieldMoveData
ld bc, wFieldMoveDataEnd - wFieldMoveData
call ByteFill
ret
FieldMoveJumptable:
ld a, [wFieldMoveJumptableIndex]
rst JumpTable
ld [wFieldMoveJumptableIndex], a
bit JUMPTABLE_EXIT_F, a
jr nz, .okay
and a
ret
.okay
and JUMPTABLE_INDEX_MASK
scf
ret
GetPartyNickname:
; write wCurPartyMon nickname to wStringBuffer1-3
ld hl, wPartyMonNicknames
ld a, BOXMON
ld [wMonType], a
ld a, [wCurPartyMon]
call GetNickname
call CopyName1
; copy text from wStringBuffer2 to wStringBuffer3
ld de, wStringBuffer2
ld hl, wStringBuffer3
call CopyName2
ret
CheckEngineFlag:
; Check engine flag de
; Return carry if flag is not set
ld b, CHECK_FLAG
farcall EngineFlagAction
ld a, c
and a
jr nz, .isset
scf
ret
.isset
xor a
ret
CheckBadge:
; Check engine flag a (ENGINE_ZEPHYRBADGE thru ENGINE_EARTHBADGE)
; Display "Badge required" text and return carry if the badge is not owned
call CheckEngineFlag
ret nc
ld hl, .BadgeRequiredText
call MenuTextboxBackup ; push text to queue
scf
ret
.BadgeRequiredText:
text_far _BadgeRequiredText
text_end
CheckPartyMove:
; Check if a monster in your party has move d.
ld e, 0
xor a
ld [wCurPartyMon], a
.loop
ld c, e
ld b, 0
ld hl, wPartySpecies
add hl, bc
ld a, [hl]
and a
jr z, .no
cp -1
jr z, .no
cp EGG
jr z, .next
ld bc, PARTYMON_STRUCT_LENGTH
ld hl, wPartyMon1Moves
ld a, e
call AddNTimes
ld b, NUM_MOVES
.check
ld a, [hli]
cp d
jr z, .yes
dec b
jr nz, .check
.next
inc e
jr .loop
.yes
ld a, e
ld [wCurPartyMon], a ; which mon has the move
xor a
ret
.no
scf
ret
FieldMoveFailed:
ld hl, .CantUseItemText
call MenuTextboxBackup
ret
.CantUseItemText:
text_far _CantUseItemText
text_end
CutFunction:
call FieldMoveJumptableReset
.loop
ld hl, .Jumptable
call FieldMoveJumptable
jr nc, .loop
and JUMPTABLE_INDEX_MASK
ld [wFieldMoveSucceeded], a
ret
.Jumptable:
dw .CheckAble
dw .DoCut
dw .FailCut
.CheckAble:
ld de, ENGINE_HIVEBADGE
call CheckBadge
jr c, .nohivebadge
call CheckMapForSomethingToCut
jr c, .nothingtocut
ld a, $1
ret
.nohivebadge
ld a, JUMPTABLE_EXIT
ret
.nothingtocut
ld a, $2
ret
.DoCut:
ld hl, Script_CutFromMenu
call QueueScript
ld a, JUMPTABLE_EXIT | $1
ret
.FailCut:
ld hl, CutNothingText
call MenuTextboxBackup
ld a, JUMPTABLE_EXIT
ret
UseCutText:
text_far _UseCutText
text_end
CutNothingText:
text_far _CutNothingText
text_end
CheckMapForSomethingToCut:
; Does the collision data of the facing tile permit cutting?
call GetFacingTileCoord
ld c, a
push de
farcall CheckCutCollision
pop de
jr nc, .fail
; Get the location of the current block in wOverworldMapBlocks.
call GetBlockLocation
ld c, [hl]
; See if that block contains something that can be cut.
push hl
ld hl, CutTreeBlockPointers
call CheckOverworldTileArrays
pop hl
jr nc, .fail
; Save the Cut field move data
ld a, l
ld [wCutWhirlpoolOverworldBlockAddr], a
ld a, h
ld [wCutWhirlpoolOverworldBlockAddr + 1], a
ld a, b
ld [wCutWhirlpoolReplacementBlock], a
ld a, c
ld [wCutWhirlpoolAnimationType], a
xor a
ret
.fail
scf
ret
Script_CutFromMenu:
refreshmap
special UpdateTimePals
Script_Cut:
callasm GetPartyNickname
writetext UseCutText
refreshmap
callasm CutDownTreeOrGrass
closetext
end
CutDownTreeOrGrass:
ld hl, wCutWhirlpoolOverworldBlockAddr
ld a, [hli]
ld h, [hl]
ld l, a
ld a, [wCutWhirlpoolReplacementBlock]
ld [hl], a
xor a
ldh [hBGMapMode], a
call LoadOverworldTilemapAndAttrmapPals
call UpdateSprites
call DelayFrame
ld a, [wCutWhirlpoolAnimationType]
ld e, a
farcall OWCutAnimation
call BufferScreen
call GetMovementPermissions
call UpdateSprites
call DelayFrame
call LoadStandardFont
ret
CheckOverworldTileArrays:
; Input: c contains the tile you're facing
; Output: Replacement tile in b and effect on wild encounters in c, plus carry set.
; Carry is not set if the facing tile cannot be replaced, or if the tileset
; does not contain a tile you can replace.
; Dictionary lookup for pointer to tile replacement table
push bc
ld a, [wMapTileset]
ld de, 3
call IsInArray
pop bc
jr nc, .nope
; Load the pointer
inc hl
ld a, [hli]
ld h, [hl]
ld l, a
; Look up the tile you're facing
ld de, 3
ld a, c
call IsInArray
jr nc, .nope
; Load the replacement to b
inc hl
ld b, [hl]
; Load the animation type parameter to c
inc hl
ld c, [hl]
scf
ret
.nope
xor a
ret
INCLUDE "data/collision/field_move_blocks.asm"
FlashFunction:
call .CheckUseFlash
and JUMPTABLE_INDEX_MASK
ld [wFieldMoveSucceeded], a
ret
.CheckUseFlash:
ld de, ENGINE_ZEPHYRBADGE
farcall CheckBadge
jr c, .nozephyrbadge
push hl
farcall SpecialAerodactylChamber
pop hl
jr c, .useflash
ld a, [wTimeOfDayPalset]
cp DARKNESS_PALSET
jr nz, .notadarkcave
.useflash
call UseFlash
ld a, JUMPTABLE_EXIT | $1
ret
.notadarkcave
call FieldMoveFailed
ld a, JUMPTABLE_EXIT
ret
.nozephyrbadge
ld a, JUMPTABLE_EXIT
ret
UseFlash:
ld hl, Script_UseFlash
jp QueueScript
Script_UseFlash:
refreshmap
special UpdateTimePals
writetext UseFlashTextScript
callasm BlindingFlash
closetext
end
UseFlashTextScript:
text_far _BlindingFlashText
text_asm
call WaitSFX
ld de, SFX_FLASH
call PlaySFX
call WaitSFX
ld hl, .BlankText
ret
.BlankText:
text_end
SurfFunction:
call FieldMoveJumptableReset
.loop
ld hl, .Jumptable
call FieldMoveJumptable
jr nc, .loop
and JUMPTABLE_INDEX_MASK
ld [wFieldMoveSucceeded], a
ret
.Jumptable:
dw .TrySurf
dw .DoSurf
dw .FailSurf
dw .AlreadySurfing
.TrySurf:
ld de, ENGINE_FOGBADGE
call CheckBadge
jr c, .nofogbadge
ld hl, wBikeFlags
bit BIKEFLAGS_ALWAYS_ON_BIKE_F, [hl]
jr nz, .cannotsurf
ld a, [wPlayerState]
cp PLAYER_SURF
jr z, .alreadyfail
cp PLAYER_SURF_PIKA
jr z, .alreadyfail
call GetFacingTileCoord
call GetTilePermission
cp WATER_TILE
jr nz, .cannotsurf
call CheckDirection
jr c, .cannotsurf
farcall CheckFacingObject
jr c, .cannotsurf
ld a, $1
ret
.nofogbadge
ld a, JUMPTABLE_EXIT
ret
.alreadyfail
ld a, $3
ret
.cannotsurf
ld a, $2
ret
.DoSurf:
call GetSurfType
ld [wSurfingPlayerState], a
call GetPartyNickname
ld hl, SurfFromMenuScript
call QueueScript
ld a, JUMPTABLE_EXIT | $1
ret
.FailSurf:
ld hl, CantSurfText
call MenuTextboxBackup
ld a, JUMPTABLE_EXIT
ret
.AlreadySurfing:
ld hl, AlreadySurfingText
call MenuTextboxBackup
ld a, JUMPTABLE_EXIT
ret
SurfFromMenuScript:
special UpdateTimePals
UsedSurfScript:
; BUG: Surfing directly across a map connection does not load the new map (see docs/bugs_and_glitches.md)
writetext UsedSurfText ; "used SURF!"
waitbutton
closetext
callasm .stubbed_fn
readmem wSurfingPlayerState
writevar VAR_MOVEMENT
special UpdatePlayerSprite
special PlayMapMusic
; step into the water (slow_step DIR, step_end)
special SurfStartStep
applymovement PLAYER, wMovementBuffer
end
.stubbed_fn
farcall StubbedTrainerRankings_Surf
ret
UsedSurfText:
text_far _UsedSurfText
text_end
CantSurfText:
text_far _CantSurfText
text_end
AlreadySurfingText:
text_far _AlreadySurfingText
text_end
GetSurfType:
; Surfing on Pikachu uses an alternate sprite.
; This is done by using a separate movement type.
ld a, [wCurPartyMon]
ld e, a
ld d, 0
ld hl, wPartySpecies
add hl, de
ld a, [hl]
cp PIKACHU
ld a, PLAYER_SURF_PIKA
ret z
ld a, PLAYER_SURF
ret
CheckDirection:
; Return carry if a tile permission prevents you
; from moving in the direction you're facing.
; Get player direction
ld a, [wPlayerDirection]
and %00001100 ; bits 2 and 3 contain direction
rrca
rrca
ld e, a
ld d, 0
ld hl, .Directions
add hl, de
; Can you walk in this direction?
ld a, [wTilePermissions]
and [hl]
jr nz, .quit
xor a
ret
.quit
scf
ret
.Directions:
db FACE_DOWN
db FACE_UP
db FACE_LEFT
db FACE_RIGHT
TrySurfOW::
; Checking a tile in the overworld.
; Return carry if fail is allowed.
; Don't ask to surf if already fail.
ld a, [wPlayerState]
cp PLAYER_SURF_PIKA
jr z, .quit
cp PLAYER_SURF
jr z, .quit
; Must be facing water.
ld a, [wFacingTileID]
call GetTilePermission
cp WATER_TILE
jr nz, .quit
; Check tile permissions.
call CheckDirection
jr c, .quit
ld de, ENGINE_FOGBADGE
call CheckEngineFlag
jr c, .quit
ld d, SURF
call CheckPartyMove
jr c, .quit
ld hl, wBikeFlags
bit BIKEFLAGS_ALWAYS_ON_BIKE_F, [hl]
jr nz, .quit
call GetSurfType
ld [wSurfingPlayerState], a
call GetPartyNickname
ld a, BANK(AskSurfScript)
ld hl, AskSurfScript
call CallScript
scf
ret
.quit
xor a
ret
AskSurfScript:
opentext
writetext AskSurfText
yesorno
iftrue UsedSurfScript
closetext
end
AskSurfText:
text_far _AskSurfText
text_end
FlyFunction:
call FieldMoveJumptableReset
.loop
ld hl, .Jumptable
call FieldMoveJumptable
jr nc, .loop
and JUMPTABLE_INDEX_MASK
ld [wFieldMoveSucceeded], a
ret
.Jumptable:
dw .TryFly
dw .DoFly
dw .FailFly
.TryFly:
ld de, ENGINE_STORMBADGE
call CheckBadge
jr c, .nostormbadge
call GetMapEnvironment
call CheckOutdoorMap
jr z, .outdoors
jr .indoors
.outdoors
xor a
ldh [hMapAnims], a
call LoadStandardMenuHeader
call ClearSprites
farcall _FlyMap
ld a, e
cp -1
jr z, .illegal
cp NUM_SPAWNS
jr nc, .illegal
ld [wDefaultSpawnpoint], a
call CloseWindow
ld a, $1
ret
.nostormbadge
ld a, JUMPTABLE_EXIT | $2
ret
.indoors
ld a, $2
ret
.illegal
call CloseWindow
call WaitBGMap
ld a, JUMPTABLE_EXIT
ret
.DoFly:
ld hl, .FlyScript
call QueueScript
ld a, JUMPTABLE_EXIT | $1
ret
.FailFly:
call FieldMoveFailed
ld a, JUMPTABLE_EXIT | $2
ret
.FlyScript:
refreshmap
callasm HideSprites
special UpdateTimePals
callasm FlyFromAnim
farscall Script_AbortBugContest
special WarpToSpawnPoint
callasm SkipUpdateMapSprites
loadvar VAR_MOVEMENT, PLAYER_NORMAL
newloadmap MAPSETUP_FLY
callasm FlyToAnim
special WaitSFX
callasm .ReturnFromFly
end
.ReturnFromFly:
farcall RespawnPlayer
call DelayFrame
call UpdatePlayerSprite
farcall LoadOverworldFont
ret
WaterfallFunction:
call .TryWaterfall
and JUMPTABLE_INDEX_MASK
ld [wFieldMoveSucceeded], a
ret
.TryWaterfall:
ld de, ENGINE_RISINGBADGE
farcall CheckBadge
ld a, JUMPTABLE_EXIT
ret c
call CheckMapCanWaterfall
jr c, .failed
ld hl, Script_WaterfallFromMenu
call QueueScript
ld a, JUMPTABLE_EXIT | $1
ret
.failed
call FieldMoveFailed
ld a, JUMPTABLE_EXIT
ret
CheckMapCanWaterfall:
ld a, [wPlayerDirection]
and $c
cp FACE_UP
jr nz, .failed
ld a, [wTileUp]
call CheckWaterfallTile
jr nz, .failed
xor a
ret
.failed
scf
ret
Script_WaterfallFromMenu:
refreshmap
special UpdateTimePals
Script_UsedWaterfall:
callasm GetPartyNickname
writetext .UseWaterfallText
waitbutton
closetext
playsound SFX_BUBBLEBEAM
.loop
applymovement PLAYER, .WaterfallStep
callasm .CheckContinueWaterfall
iffalse .loop
end
.CheckContinueWaterfall:
xor a
ld [wScriptVar], a
ld a, [wPlayerTileCollision]
call CheckWaterfallTile
ret z
farcall StubbedTrainerRankings_Waterfall
ld a, $1
ld [wScriptVar], a
ret
.WaterfallStep:
turn_waterfall UP
step_end
.UseWaterfallText:
text_far _UseWaterfallText
text_end
TryWaterfallOW::
ld d, WATERFALL
call CheckPartyMove
jr c, .failed
ld de, ENGINE_RISINGBADGE
call CheckEngineFlag
jr c, .failed
call CheckMapCanWaterfall
jr c, .failed
ld a, BANK(Script_AskWaterfall)
ld hl, Script_AskWaterfall
call CallScript
scf
ret
.failed
ld a, BANK(Script_CantDoWaterfall)
ld hl, Script_CantDoWaterfall
call CallScript
scf
ret
Script_CantDoWaterfall:
jumptext .HugeWaterfallText
.HugeWaterfallText:
text_far _HugeWaterfallText
text_end
Script_AskWaterfall:
opentext
writetext .AskWaterfallText
yesorno
iftrue Script_UsedWaterfall
closetext
end
.AskWaterfallText:
text_far _AskWaterfallText
text_end
EscapeRopeFunction:
call FieldMoveJumptableReset
ld a, $1
jr EscapeRopeOrDig
DigFunction:
call FieldMoveJumptableReset
ld a, $2
EscapeRopeOrDig:
ld [wEscapeRopeOrDigType], a
.loop
ld hl, .DigTable
call FieldMoveJumptable
jr nc, .loop
and JUMPTABLE_INDEX_MASK
ld [wFieldMoveSucceeded], a
ret
.DigTable:
dw .CheckCanDig
dw .DoDig
dw .FailDig
.CheckCanDig:
call GetMapEnvironment
cp CAVE
jr z, .incave
cp DUNGEON
jr z, .incave
.fail
ld a, $2
ret
.incave
ld hl, wDigWarpNumber
ld a, [hli]
and a
jr z, .fail
ld a, [hli]
and a
jr z, .fail
ld a, [hl]
and a
jr z, .fail
ld a, $1
ret
.DoDig:
ld hl, wDigWarpNumber
ld de, wNextWarp
ld bc, 3
call CopyBytes
call GetPartyNickname
ld a, [wEscapeRopeOrDigType]
cp $2
jr nz, .escaperope
ld hl, .UsedDigScript
call QueueScript
ld a, JUMPTABLE_EXIT | $1
ret
.escaperope
farcall SpecialKabutoChamber
ld hl, .UsedEscapeRopeScript
call QueueScript
ld a, JUMPTABLE_EXIT | $1
ret
.FailDig:
ld a, [wEscapeRopeOrDigType]
cp $2
jr nz, .failescaperope
ld hl, .CantUseDigText
call MenuTextbox
call WaitPressAorB_BlinkCursor
call CloseWindow
.failescaperope
ld a, JUMPTABLE_EXIT
ret
.UseDigText:
text_far _UseDigText
text_end
.UseEscapeRopeText:
text_far _UseEscapeRopeText
text_end
.CantUseDigText:
text_far _CantUseDigText
text_end
.UsedEscapeRopeScript:
refreshmap
special UpdateTimePals
writetext .UseEscapeRopeText
sjump .UsedDigOrEscapeRopeScript
.UsedDigScript:
refreshmap
special UpdateTimePals
writetext .UseDigText
.UsedDigOrEscapeRopeScript:
waitbutton
closetext
playsound SFX_WARP_TO
applymovement PLAYER, .DigOut
farscall Script_AbortBugContest
special WarpToSpawnPoint
loadvar VAR_MOVEMENT, PLAYER_NORMAL
newloadmap MAPSETUP_DOOR
playsound SFX_WARP_FROM
applymovement PLAYER, .DigReturn
end
.DigOut:
step_dig 32
hide_object
step_end
.DigReturn:
show_object
return_dig 32
step_end
TeleportFunction:
call FieldMoveJumptableReset
.loop
ld hl, .Jumptable
call FieldMoveJumptable
jr nc, .loop
and JUMPTABLE_INDEX_MASK
ld [wFieldMoveSucceeded], a
ret
.Jumptable:
dw .TryTeleport
dw .DoTeleport
dw .FailTeleport
.TryTeleport:
call GetMapEnvironment
call CheckOutdoorMap
jr z, .CheckIfSpawnPoint
jr .nope
.CheckIfSpawnPoint:
ld a, [wLastSpawnMapGroup]
ld d, a
ld a, [wLastSpawnMapNumber]
ld e, a
farcall IsSpawnPoint
jr nc, .nope
ld a, c
ld [wDefaultSpawnpoint], a
ld a, $1
ret
.nope
ld a, $2
ret
.DoTeleport:
call GetPartyNickname
ld hl, .TeleportScript
call QueueScript
ld a, JUMPTABLE_EXIT | $1
ret
.FailTeleport:
ld hl, .CantUseTeleportText
call MenuTextboxBackup
ld a, JUMPTABLE_EXIT
ret
.TeleportReturnText:
text_far _TeleportReturnText
text_end
.CantUseTeleportText:
text_far _CantUseTeleportText
text_end
.TeleportScript:
refreshmap
special UpdateTimePals
writetext .TeleportReturnText
pause 60
refreshmap
closetext
playsound SFX_WARP_TO
applymovement PLAYER, .TeleportFrom
farscall Script_AbortBugContest
special WarpToSpawnPoint
loadvar VAR_MOVEMENT, PLAYER_NORMAL
newloadmap MAPSETUP_TELEPORT
playsound SFX_WARP_FROM
applymovement PLAYER, .TeleportTo
end
.TeleportFrom:
teleport_from
step_end
.TeleportTo:
teleport_to
step_end
StrengthFunction:
call .TryStrength
and JUMPTABLE_INDEX_MASK
ld [wFieldMoveSucceeded], a
ret
.TryStrength:
ld de, ENGINE_PLAINBADGE
call CheckBadge
jr c, .Failed
jr .UseStrength
.AlreadyUsingStrength: ; unreferenced
ld hl, .AlreadyUsingStrengthText
call MenuTextboxBackup
ld a, JUMPTABLE_EXIT
ret
.AlreadyUsingStrengthText:
text_far _AlreadyUsingStrengthText
text_end
.Failed:
ld a, JUMPTABLE_EXIT
ret
.UseStrength:
ld hl, Script_StrengthFromMenu
call QueueScript
ld a, JUMPTABLE_EXIT | $1
ret
SetStrengthFlag:
ld hl, wBikeFlags
set BIKEFLAGS_STRENGTH_ACTIVE_F, [hl]
ld a, [wCurPartyMon]
ld e, a
ld d, 0
ld hl, wPartySpecies
add hl, de
ld a, [hl]
ld [wStrengthSpecies], a
call GetPartyNickname
ret