build.gradle

plugins {
    id 'org.springframework.boot' version '1.5.1.RELEASE'
}

bootRepackage {
    enabled = false
}

subprojects {
    apply plugin: 'groovy'
    apply plugin: 'org.springframework.boot'

    bootRepackage {
        enabled = false
    }

    findMainClass {
        enabled = false
    }

    group 'com.insanedev'
    version '0.1-SNAPSHOT'

    repositories {
        jcenter()
    }

    sourceSets {
        integration {
            compileClasspath += sourceSets.test.runtimeClasspath
            runtimeClasspath += sourceSets.test.runtimeClasspath
        }
    }

    dependencies {
        compile 'org.codehaus.groovy:groovy-all'
        compile 'org.springframework.boot:spring-boot-starter-web'
        compile 'org.springframework.boot:spring-boot-starter-actuator'
        testCompile 'org.spockframework:spock-core:1.1-groovy-2.4-rc-3'
        testCompile 'org.springframework.boot:spring-boot-starter-test'
        testCompile 'org.spockframework:spock-spring:1.1-groovy-2.4-rc-2'
    }

    task integrationTest(type: Test) {
        testClassesDir = sourceSets.integration.output.classesDir
        classpath = sourceSets.integration.runtimeClasspath
    }

    task createGeneratedSrcDir() {
        def generatedSrcDir = file("$buildDir/generatedSrc")
        outputs.dir(generatedSrcDir)
        doLast {
            generatedSrcDir.mkdirs()
        }
    }
}

task wrapper(type: Wrapper) {
	gradleVersion = '3.3'
}