-
Notifications
You must be signed in to change notification settings - Fork 0
/
regex.ebnf
160 lines (126 loc) · 3.92 KB
/
regex.ebnf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
Regex ::= StartOfStringAnchor? Expression
Expression ::= Subexpression ("|" Expression)?
/* Anything that can be on one side of the alternation. */
Subexpression ::= SubexpressionItem+
SubexpressionItem
::= Match
| Group
| Anchor
| Backreference
/* Grouping Constructs
------------------------------------------------------------------*/
Group ::= "(" GroupNonCapturingModifier? Expression ")" Quantifier?
GroupNonCapturingModifier ::= "?:"
/* Match
------------------------------------------------------------------*/
Match ::= MatchItem Quantifier?
MatchItem
::= MatchAnyCharacter
| MatchCharacterClass
| MatchCharacter
MatchAnyCharacter ::= "."
MatchCharacterClass
::= CharacterGroup
| CharacterClass
| CharacterClassFromUnicodeCategory
MatchCharacter ::= Char
/* Character Classes
------------------------------------------------------------------*/
CharacterGroup ::= "[" CharacterGroupNegativeModifier? CharacterGroupItem+ "]"
CharacterGroupNegativeModifier ::= "^"
CharacterGroupItem
::= CharacterClass
| CharacterClassFromUnicodeCategory
| CharacterRange
| Char /* excluding ] */
CharacterClass
::= CharacterClassAnyWord
| CharacterClassAnyWordInverted
| CharacterClassAnyDecimalDigit
| CharacterClassAnyDecimalDigitInverted
CharacterClassAnyWord ::= "\w"
CharacterClassAnyWordInverted ::= "\W"
CharacterClassAnyDecimalDigit ::= "\d"
CharacterClassAnyDecimalDigitInverted ::= "\D"
CharacterClassFromUnicodeCategory ::= "\p{" UnicodeCategoryName "}"
UnicodeCategoryName
::= "L" | "Letter"
| "Ll" | "Lowercase_Letter"
| "Lu" | "Uppercase_Letter"
| "Lt" | "Titlecase_Letter"
| "L&" | "Cased_Letter"
| "Lm" | "Modified_Letter"
| "Lo" | "Other_Letter"
| "M" | "Mark"
| "Mn" | "Non_Spacing_Mark"
| "Mc" | "Spacing_Combining_Mark"
| "Me" | "Enclosing_Mark"
| "Z" | "Separator"
| "Zs" | "Space_Separator"
| "Zl" | "Line_Separator"
| "Zp" | "Paragraph_Separator"
| "S" | "Symbol"
| "Sm" | "Math_Symbol"
| "Sc" | "Currency_Symbol"
| "Sk" | "Modifier_Symbol"
| "So" | "Other_Symbol"
| "N" | "Number"
| "Nd" | "Decimal_Digit_Number"
| "Nl" | "Letter_Number"
| "No" | "Other_Number"
| "P" | "Punctuation"
| "Pd" | "Dash_Punctuation"
| "Ps" | "Open Punctuation"
| "Pe" | "Close_Punctuation"
| "Pi" | "Initial_Punctuation"
| "Pf" | "Final_Punctuation"
| "Pc" | "Connector_Punctuation"
| "Po" | "Other_Punctuation"
| "C" | "Other"
| "Cc" | "Control"
| "Cf" | "Format"
| "Co" | "Private_Use"
| "Cs" | "Surrogate"
| "Cn" | "Unassigned"
CharacterRange ::= Char "-" Char
/* Quantifiers
------------------------------------------------------------------*/
Quantifier ::= QuantifierType LazyModifier?
QuantifierType
::= ZeroOrMoreQuantifier
| OneOrMoreQuantifier
| ZeroOrOneQuantifier
| RangeQuantifier
LazyModifier ::= "?"
ZeroOrMoreQuantifier ::= "*"
OneOrMoreQuantifier ::= "+"
ZeroOrOneQuantifier ::= "?"
RangeQuantifier ::= "{" RangeQuantifierLowerBound ( "," RangeQuantifierUpperBound? )? "}"
RangeQuantifierLowerBound ::= Integer
RangeQuantifierUpperBound ::= Integer
/* Backreferences
------------------------------------------------------------------*/
Backreference ::= "\" Integer
/* Anchors
------------------------------------------------------------------*/
StartOfStringAnchor ::= "^"
Anchor
::= AnchorWordBoundary
| AnchorNonWordBoundary
| AnchorStartOfStringOnly
| AnchorEndOfStringOnlyNotNewline
| AnchorEndOfStringOnly
| AnchorPreviousMatchEnd
| AnchorEndOfString
AnchorWordBoundary ::= "\b"
AnchorNonWordBoundary ::= "\B"
AnchorStartOfStringOnly ::= "\A"
AnchorEndOfStringOnlyNotNewline ::= "\z"
AnchorEndOfStringOnly ::= "\Z"
AnchorPreviousMatchEnd ::= "\G"
AnchorEndOfString ::= "$"
/* Misc
------------------------------------------------------------------*/
Integer ::= [0-9]+
Letters ::= [a-zA-Z]+
Char ::= #x9 | #xA | #xD | [#x20-#xD7FF] | [#xE000-#xFFFD] | [#x10000-#x10FFFF]