build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
apply plugin: 'jacoco'

buildscript {
    repositories {
        google()
        jcenter()
    }
    project.ext {
        kotlinVersion = '1.2.0'
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.0.1'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
        classpath "org.jetbrains.dokka:dokka-gradle-plugin:0.9.15"

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    apply plugin: 'jacoco'
    repositories {
        google()
        jcenter()
    }

    task codeCoverageReport(type: JacocoReport) {
        classDirectories = files('build/classes/kotlin/main')
        classDirectories = files(classDirectories.files.collect {
            fileTree(dir: it,
                //ReflectionStrategy and AnnotationStrategy are using complex type classes
                //that are hard to test
                excludes: ['**/ReflectionStrategy**', '**/AnnotationStrategy**']
            )
        })
        sourceDirectories = files('src/main/java')

        executionData fileTree(project.rootDir.absolutePath).include("**/build/jacoco/*.exec")

        reports {
            xml.enabled true
            xml.destination "${buildDir}/reports/jacoco/report.xml"
            html.enabled true
            csv.enabled true
        }
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

codeCoverageReport.dependsOn {
    subprojects*.test
}