[Bug]: Cannot set visible_range of bar_chart_visual in a quicksight analysis

[jshort-insights]

Terraform Core Version

1.5.2

AWS Provider Version

5.5.0

Affected Resource(s)

aws_quicksight_analysis

Expected Behavior

Setting the scrollbar options of a bar chart visual to a percentage range of 0-100 to be honoured in the analysis

Actual Behavior

An exception is thrown when creating the analysis

Relevant Error/Panic Output Snippet

╷
│ Error: setting definition: Invalid address to set: []string{"definition", "0", "sheets", "0", "visuals", "0", "bar_chart_visual", "0", "chart_configuration", "0", "category_axis", "0", "scrollbar_options", "0", "visibile_range"}
│

Terraform Configuration Files

resource "aws_quicksight_analysis" "example_download_analysis" {
  analysis_id    = "example-distribution-analysis"
  name           = "Example Analysis"
  aws_account_id = var.account_id

  definition {
    data_set_identifiers_declarations {
      data_set_arn = var.dataset_arn
      identifier   = var.dataset_id
    }

    sheets {
      sheet_id = "example-sheet"
      name     = "Example"

      visuals {
        bar_chart_visual {
          visual_id = "failed-download-bar-chart"
          title {
            visibility = "VISIBLE"
            format_text {
              rich_text = "<visual-title>Failed Download HTTP Statuses</visual-title>"
            }
          }
          subtitle {
            visibility = "VISIBLE"
          }
          chart_configuration {
            field_wells {
              bar_chart_aggregated_field_wells {
                category {
                  date_dimension_field {
                    field_id = "failed-download-time-field"
                    column {
                      data_set_identifier = var.dataset_id
                      column_name         = "time"
                    }
                    hierarchy_id = "failed-download-time-field"
                  }
                }
                colors {
                  categorical_dimension_field {
                    field_id = "failed-download-status-field"
                    column {
                      data_set_identifier = var.dataset_id
                      column_name         = "http_status"
                    }
                  }
                }
              }
            }
            sort_configuration {
              category_sort {
                field_sort {
                  field_id  = "failed-download-time-field"
                  direction = "ASC"
                }
              }
              category_items_limit {
                items_limit      = 5
                other_categories = "INCLUDE"
              }
              color_items_limit {
                items_limit      = 5
                other_categories = "INCLUDE"
              }
              small_multiples_limit_configuration {
                other_categories = "INCLUDE"
                items_limit      = 1
              }
            }
            orientation      = "VERTICAL"
            bars_arrangement = "CLUSTERED"
            category_axis {
              scrollbar_options {
                visible_range {
                  percent_range {
                    from = 0
                    to = 100
                  }
                }
              }
            }
            color_label_options {
              sort_icon_visibility = "VISIBLE"
            }
            legend {
              width = "108px"
            }
            data_labels {
              visibility = "HIDDEN"
              overlap    = "DISABLE_OVERLAP"
            }
            tooltip {
              tooltip_visibility    = "VISIBLE"
              selected_tooltip_type = "BASIC"
              field_base_tooltip {
                aggregation_visibility = "HIDDEN"
                tooltip_title_type     = "PRIMARY_VALUE"
                tooltip_fields {
                  field_tooltip_item {
                    field_id   = "failed-download-time-field"
                    visibility = "VISIBLE"
                  }
                }
                tooltip_fields {
                  field_tooltip_item {
                    field_id   = "failed-download-status-field"
                    visibility = "VISIBLE"
                  }
                }
              }
            }
          }
          column_hierarchies {
            date_time_hierarchy {
              hierarchy_id = "failed-download-time-field"
            }
          }
        }
      }

      layouts {
        configuration {
          grid_layout {
            elements {
              element_id   = "failed-download-bar-chart"
              element_type = "VISUAL"
              column_index = 0
              column_span  = 13
              row_index    = 0
              row_span     = 12
            }
            canvas_size_options {
              screen_canvas_size_options {
                resize_option             = "FIXED"
                optimized_view_port_width = "1600px"
              }
            }
          }
        }
      }

      content_type = "INTERACTIVE"
    }

    analysis_defaults {
      default_new_sheet_configuration {
        interactive_layout_configuration {
          grid {
            canvas_size_options {
              screen_canvas_size_options {
                resize_option             = "FIXED"
                optimized_view_port_width = "1600px"
              }
            }
          }
        }
        sheet_content_type = "INTERACTIVE"
      }
    }
  }

  permissions {
    principal = var.quicksight_data_group
    actions = [
      "quicksight:DeleteAnalysis",
      "quicksight:DescribeAnalysis",
      "quicksight:DescribeAnalysisPermissions",
      "quicksight:QueryAnalysis",
      "quicksight:RestoreAnalysis",
      "quicksight:UpdateAnalysis",
      "quicksight:UpdateAnalysisPermissions",
    ]
  }
}

Steps to Reproduce

Create a bar chart visual in a quicksight analysis and apply changes to AWS

Debug Output

No response

Panic Output

No response

Important Factoids

No response

References

No response

Would you like to implement a fix?

None

[github-actions]

Community Note

Voting for Prioritization

• Please vote on this issue by adding a 👍 reaction to the original post to help the community and maintainers prioritize this request.
• Please see our prioritization guide for information on how we prioritize.
• Please do not leave "+1" or other comments that do not add relevant new information or questions, they generate extra noise for issue followers and do not help prioritize the request.

Volunteering to Work on This Issue

• If you are interested in working on this issue, please leave a comment.
• If this would be your first contribution, please review the contribution guide.

[justinretzolk]

Hey @jshort-insights 👋 Thank you for taking the time to raise this! I noticed in the error that you pasted, that visible_range was misspelled as visibile_range, though that does not appear to be the case in the sample Terraform configuration that you provided. Did correcting this typo have any effect on the behavior?

If possible, it may be beneficial for us to review debug logging. Are you able to provide that (redacted as needed)?

[jshort-insights]

@justinretzolk I believe this the exact cause of the issue a typo in the mapping

terraform-provider-aws/internal/service/quicksight/schema/visual_chart_configuration.go

Line 1371 in 42bfa9c

tfMap["visibile_range"] = flattenVisibleRangeOptions(apiObject.VisibleRange)

[justinretzolk]

Hey @jshort-insights 👋 Thank you for taking the time to take a look into that; that definitely seems like a likely culprit.

Relates #31923

[github-actions]

This functionality has been released in v5.8.0 of the Terraform AWS Provider. Please see the Terraform documentation on provider versioning or reach out if you need any assistance upgrading.

For further feature requests or bug reports with this functionality, please create a new GitHub issue following the template. Thank you!

[github-actions]

I'm going to lock this issue because it has been closed for 30 days ⏳. This helps our maintainers find and focus on the active issues.
If you have found a problem that seems similar to this, please open a new issue and complete the issue template so we can capture all the details necessary to investigate further.