build.gradle

plugins {
    id 'java'
    id 'maven-publish'
    id "org.sonarqube" version "4.4.1.3373"
}

group = 'fr.efreicraft'
version = '1.1.2'

compileJava.options.encoding = 'UTF-8'

repositories {
    mavenCentral()
    maven {
        name = 'papermc-repo'
        url = 'https://repo.papermc.io/repository/maven-public/'
    }
    maven {
        name = 'sonatype'
        url = 'https://oss.sonatype.org/content/groups/public/'
    }
    if (System.getenv("NEXUS_REPOSITORY")) {
        println "Using Nexus repository"
        maven {
            name = 'nexus'
            url = uri(System.getenv("NEXUS_REPOSITORY"))
            credentials {
                username = System.getenv("NEXUS_USERNAME")
                password = System.getenv("NEXUS_PASSWORD")
            }
        }
    }
}

dependencies {
    compileOnly 'io.papermc.paper:paper-api:1.19.2-R0.1-SNAPSHOT'

    compileOnly "fr.efreicraft:AnimusClient:latest.integration"
    compileOnly "fr.efreicraft:ECATUP:latest.integration"
}

def targetJavaVersion = 17
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release = targetJavaVersion
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}

configurations {
    jar.archiveName = rootProject.name + ".jar"
}

publishing {
    publications {
        maven(MavenPublication) {
            groupId = rootProject.group
            artifactId = rootProject.name
            version = rootProject.version

            from components.java

            pom.packaging = 'jar'

            artifact("${buildDir}/libs/${rootProject.name}.jar") {
                classifier = 'jar'
            }
        }
    }
    repositories {
        if (System.getenv("NEXUS_REPOSITORY")) {
            maven {
                url = uri(System.getenv("NEXUS_REPOSITORY"))
                credentials {
                    username = System.getenv("NEXUS_USERNAME")
                    password = System.getenv("NEXUS_PASSWORD")
                }
            }
        } else {
            mavenLocal()
        }
    }
}

task devBuildDockerImage(type: Exec) {
    dependsOn build

    workingDir '../'
    commandLine 'docker', 'build', '-t', 'dev.efrei-craft/acp/templates/lobby', '-f', 'eclobby/dev/Dockerfile', '.'
}

sonar {
    properties {
        property "sonar.projectKey", "efrei-craft_eclobby_AYxT1h4W0r1VQ1KDYPLh"
        property "sonar.projectName", "eclobby"
    }
}