Validate keys in a dictionary against other values elsewhere

[jamieforrest]

I would like to have a definition for a dictionary where all of the keys in the dictionary must be string values from another definition in the cue file.

Let's say I have a cue file like the one below (I know this is invalid, but it expresses what I want to do):

#Box: {
    label!: string,
    description?: string,
}

boxes: [...#Box]

#Route: {
    location!: string,
}

#Routes: {
    #Box.label: #Route,
}

What I am trying to do here is specify that any key in the #Routes definition must be one of the #Box labels in the list of boxes above it. Is it possible to do this in cue?

[perelo]

Hello,
There is a solution using a pattern constraint with the or() built-in function and a comprehension.

#Routes: {
    [or([for b in boxes {b.label}])]: #Route
}

The list comprehension extracts the label field from items in boxes and the or() converts this list into a disjunction, as in boxes[0].label | boxes[1].label | .... Putting this into square brackets before colon will apply the RHS to fields whose key matches either label.

boxes: [
    { label: "foo" },
    { label: "bar" },
]
routes: #Routes & {
    foo: _  // `location!: string`
    baz: _  // Field not allowed
}

Note also that trailing commas are not required.