Buffer organization

[kflak]

Hi,

I started porting over some of my sc-lang tools, and I am quite happy about this way of organizing buffers. It takes a directory filled with subdirectories, each containing a bunch of sound files, fills a hash-table with keys named after the subdirectories and populates a list with buffers for the files:

(defparameter *buffers* (make-hash-table))

(defun free-buffers (buffer-hash-table)
  "Frees all the buffers stored in a hash-table and clears all keys"
  (trivial-do:dohash (dir bufferlist buffer-hash-table)
    (dolist (buffer bufferlist)
      (sc:buffer-free buffer))
    (remhash dir buffer-hash-table))
  (format t "Freed all buffers from hash-table~%"))

(defun load-buffers (audio-dir buffer-hash-table)
  "Read audio files from a directory containing directories of files into 
buffers, using a hash-table to organize them.

Example usage:
(defparameter *buf* (make-hash-table))
(load-buffers \"audio\" *buf*)

(defparameter *synth* (sc:synth playbuf (buf (gethash 'cello *buf*)))
This example assumes that you have a directory in your current working directory
called \"audio\", which, in turn, contains a directory called \"cello\" with 
some audio files.
"
  (let ((dir-count 0) (buf-count 0))
    (dolist (dir (uiop:subdirectories audio-dir))
      (setf (gethash (read-from-string
                      (first (last (pathname-directory dir)))) buffer-hash-table)
            (let ((buflist (make-list 0)))
              (loop for file in (uiop:directory-files dir)
                    do (when
                           ;; Check if the file is audio file
                           (member (pathname-type file)
                                   '("wav" "aiff" "aif")
                                   :test #'equal)
                         (push (sc:buffer-read file) buflist)
                         (incf buf-count)))
              buflist))
      (format t "Loaded ~S~%" dir)
      (incf dir-count))
    (format t "Loaded ~A buffers in ~A directories~%" buf-count dir-count)))

;; access the buffers. Either return the buffer list at the key, or, with two args, return the buffer object itself
;; I suspect there is a better, more idiomatic way to do this, though...
(defun buf (key &optional index)
  (let ((buflist (gethash key *buffers*)))
    (if index
        (nth index buflist)
        buflist)))

;; test it, assuming the existence of a defsynth named playbuf-mono-asr-2 and a folder named brpiano with some audio samples
(defparameter *synth* (sc:synth 'playbuf-mono-asr-2
                                :buf (buf 'brpiano 0)
                                :loop 1
                                :pan 0))

Any feedback much appreciated :-)