build.gradle

plugins {
    id 'maven'
    id "org.jetbrains.kotlin.jvm" version "1.3.50"
}

ext{
    moduleName = 'com.github.kotlin_graphics.kotlin_unsigned'
    kotlin = 'org.jetbrains.kotlin:kotlin'
    kotlintest_version = '3.4.0'
}

dependencies {

    implementation "$kotlin-stdlib"

    testImplementation "io.kotlintest:kotlintest-runner-junit5:$kotlintest_version".toString()
}

repositories {
    mavenCentral()
    maven { url "https://jitpack.io" }
}

task sourcesJar(type: Jar, dependsOn: classes) {
    archiveClassifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    archiveClassifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives sourcesJar
//    archives javadocJar
}

compileKotlin {
    // Enable Kotlin compilation to Java 8 class files with method parameter name metadata
    kotlinOptions{
        jvmTarget = "11"
//        javaParameters = true
    }
    // As per https://stackoverflow.com/a/47669720
    // See also https://discuss.kotlinlang.org/t/kotlin-support-for-java-9-module-system/2499/9
    destinationDir = compileJava.destinationDir
}

compileTestKotlin {
    kotlinOptions{
        jvmTarget = "11"
//        javaParameters = true
    }
}

compileJava {
    dependsOn(':compileKotlin')
    doFirst {
        options.compilerArgs = ['--module-path', classpath.asPath,]
        classpath = files()
    }
}

jar {
    inputs.property("moduleName", moduleName)
//    manifest.attributes('Automatic-Module-Name': moduleName)
//    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
}

test.useJUnitPlatform()