build.gradle

plugins {
    id 'com.autonomousapps.dependency-analysis' version '0.46.0'
    id 'io.codearte.nexus-staging' version "0.21.1"
}

allprojects {
    apply plugin: 'base'
    apply plugin: 'eclipse'

    // Always download sources, to allow debugging
    eclipse {
        classpath {
            downloadSources = true
        }
    }

    repositories {
        mavenCentral()
    }
}

subprojects {
    apply plugin: 'java-library'
    apply plugin: 'checkstyle'
    
    checkstyle {
        configFile = rootProject.file('config/checkstyle/checkstyle.xml')
        configProperties = [ 'checkstyle.config.dir' : rootProject.file('config/checkstyle') ]
        toolVersion = '8.33'
    }
     
    task checkstyleAll{}
     
    tasks.withType(Checkstyle).all { checkstyleTask -> checkstyleAll.dependsOn checkstyleTask }
     
    check.dependsOn checkstyleAll
    
    // Setup default test behavior, including failure logging
    test {
        useTestNG() {
            useDefaultListeners = true
        }
    }
    
    // Set Java 9 automatic module name to prevent future collisions
    jar {
        manifest {
            attributes("Automatic-Module-Name": "${project.group}.${project.name}".replaceAll("-", "."))
        }
    }

    task sourcesJar(type: Jar, dependsOn: classes) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }
    
    task javadocJar(type: Jar, dependsOn: javadoc) {
    	classifier = 'javadoc'
    	from javadoc
	}
	
	assemble.dependsOn sourcesJar
	assemble.dependsOn javadocJar
    
    tasks.withType(Jar).all {
        from("${rootDir}"){
            include 'LICENSE'
        }
    }
    
}