build.gradle

buildscript {
	repositories {
		mavenLocal()
		mavenCentral()
	}
	dependencies {
	}
}



apply plugin: 'java-library'
apply plugin: 'groovy'
apply plugin: 'maven-publish'
apply plugin: 'idea'

group = 'com.bertramlabs.plugins'
sourceCompatibility = '1.17'
targetCompatibility = '1.17'

ext.isReleaseVersion = !version.endsWith('SNAPSHOT')


repositories {
	mavenCentral()
}

configurations {
	provided
	doc.extendsFrom(runtime)
}

sourceSets {
	main {
		compileClasspath += configurations.provided
		groovy.srcDirs   += ['src/main/java']
		java.srcDirs      = []
	}
}

java {
    withSourcesJar()
    withJavadocJar()
}

groovydoc {
	docTitle "Asset Pipeline Core"
	windowTitle "Asset Pipeline For the JVM API Doc"
	groovyClasspath = configurations.doc
	classpath = configurations.runtime
	// Links to external Javadoc, currently only the J2SE links are working properly
  	link('http://download.oracle.com/javase/8/docs/api/', 'java.', 'org.xml', 'javax.', 'org.xml.')
  	link('http://groovy.codehaus.org/api/',  'groovy.', 'org.apache.groovy.')
}

dependencies {
	compileOnly    'org.codehaus.groovy:groovy:3.0.20'
	compileOnly    'org.codehaus.groovy:groovy-json:3.0.20'
	compileOnly    'org.codehaus.groovy:groovy-templates:3.0.20'
	doc         'org.apache.groovy:groovy-all:4.0.22'
	doc         'org.fusesource.jansi:jansi:1.11'
	compileOnly     'org.mozilla:rhino:1.7R4'
	api("org.graalvm.sdk:graal-sdk:22.0.0.2")
    api("org.graalvm.js:js:22.0.0.2")
    api("org.graalvm.js:js-scriptengine:22.0.0.2")
	compileOnly     'com.google.javascript:closure-compiler-unshaded:v20240317'
	api 'org.slf4j:slf4j-api:1.7.28'
	//api   'log4j:log4j:1.2.16'
	testImplementation project(':asset-pipeline-classpath-test')
	testImplementation 'org.apache.groovy:groovy-all:4.0.22'
	testImplementation 'org.spockframework:spock-core:2.3-groovy-4.0'
	testRuntimeOnly 'org.slf4j:slf4j-simple:1.7.28'
	compileOnly 'org.slf4j:slf4j-simple:1.7.28'
}

publishing {
	publications {
		maven(MavenPublication) {
			artifactId 'asset-pipeline-core'
			pom.withXml {
				asNode().children().last() + {
					resolveStrategy = Closure.DELEGATE_FIRST
					name 'asset-pipeline-core'
					description 'JVM Asset Pipeline library for serving static web assets, bundling, minifying, and extensibility for transpiling.'
					url 'https://github.com/bertramdev/asset-pipeline-core'
					scm {
						url 'https://github.com/bertramdev/asset-pipeline-core'
						connection 'scm:https://bertramdev@github.com/bertramdev/asset-pipeline-core.git'
						developerConnection 'scm:git://github.com/bertramdev/asset-pipeline-core.git'
					}
					licenses {
						license {
							name 'The Apache Software License, Version 2.0'
							url 'http://www.apache.org/license/LICENSE-2.0.txt'
							distribution 'repo'
						}
					}
					developers {
						developer {
							id 'davydotcom'
							name 'David Estes'
							email 'davydotcom@gmail.com'
						}
					}
				}
			}
			from components.java
		}
	}

    repositories {
        maven {
            if( !isReleaseVersion ) {
                url = "http://nexus.bertramlabs.com/content/repositories/snapshots"
                if(project.hasProperty('labsNexusUser')) {
                    credentials {
                        username = labsNexusUser
                        password = labsNexusPassword
                    }
                }
            }
        }
    }
}


task(console, dependsOn: 'classes', type: JavaExec) {
  main = 'groovy.ui.Console'
  classpath = sourceSets.main.runtimeClasspath
}

tasks.register("depsize") {
    description = 'Prints dependencies for "default" configuration'
    doLast() {
        listConfigurationDependencies(configurations.runtimeClasspath)
    }
}

tasks.register("depsize-all-configurations") {
    description = 'Prints dependencies for all available configurations'
    doLast() {
        configurations
                .findAll { it.isCanBeResolved() }
                .each { listConfigurationDependencies(it) }
    }
}



def listConfigurationDependencies(Configuration configuration) {
    def formatStr = "%,10.2f"

    def size = configuration.collect { it.length() / (1024 * 1024) }.sum()

    def out = new StringBuffer()
    out << "\nConfiguration name: \"${configuration.name}\"\n"
    if (size) {
        out << 'Total dependencies size:'.padRight(65)
        out << "${String.format(formatStr, size)} Mb\n\n"

        configuration.sort { -it.length() }
                .each {
                    out << "${it.name}".padRight(65)
                    out << "${String.format(formatStr, (it.length() / 1024))} kb\n"
                }
    } else {
        out << 'No dependencies found'
    }
    println(out)
}

test {
	testLogging {
		exceptionFormat = 'full'
		showStandardStreams = true
	}
}