本文由 简悦 SimpRead 转码， 原文地址 support.sas.com
PROC LOGISTIC automatically computes a test of the proportional odds assumption when the response is ......
PROC LOGISTIC automatically computes a test of the proportional odds assumption when the response is ordinal and the default logit link is used. For such a response, several cumulative logits are simultaneously modeled while only a single logit is modeled for a binary response. Conceptually, you could fit a model that has a complete set of parameter estimates for each of the cumulative logits. The simpler model that PROC LOGISTIC fits constrains each predictor's parameter estimates to be the same across all of the logits. This means that the fitted surfaces for the logits are all parallel and they are only allowed to differ by a constant shift that necessitates the separate intercepts that you get when you fit an ordinal model. When the logit link is used, this parallelism assumption also implies that the effect of a given predictor is the same regardless of where you"cut" the ordinal response to dichotomize it. The proportional odds test in PROC LOGISTIC simply tests whether the parameters are the same across logits, simultaneously for all predictors. PROC GENMOD fits the same proportional odds model, but it does not provide a proportional odds test.
Peterson and Harrell (1990) note that this proportional odds/parallelism test is known to be liberal when the sample size is small, which means that the p-value for the test could be artificially too small in small samples, possibly leading to inappropriate rejection of the proportional odds assumption. Because of this, graphical assessment of the parallelism assumption is useful and is discussed and illustrated in this note. However, nonsignificant test results (large p-values) are not affected and reliably indicate adequacy of the proportional odds/parallel assumption. Stokes, et. al. (2012) suggests doing cross-tabulations of the response with each predictor involved in the model. If all cell counts are about five or larger, then the sample size should be adequate.
If the sample size is adequate and the test or the graphs convince you to reject the assumption of proportional odds, then there are two alternative models that are often used. The first is the generalized logit model which can be fit by simply specifying the LINK=GLOGIT option in the MODEL statement of PROC LOGISTIC. This model treats the response as nominal (unordered) rather than ordinal and has a full set of parameters for each generalized logit.
The second alternative is the partial proportional odds model. This model continues to treat the response as ordinal, but allows you to assume proportional odds for some predictors while not for others. To do this, the model contains separate parameters across the logits for model effects exhibiting a lack of proportionality. A single parameter is used for effects where proportionality holds. At the extreme, the fully nonproportional odds model can be fit in which separate parameters are used for every effect in the model. Beginning in SAS® 9.3 TS1M2, you can fit this model using the UNEQUALSLOPES option in the MODEL statement of PROC LOGISTIC. In earlier releases, the model can also be fit using PROC NLMIXED as shown in the addendum at the end of this note.
In the following sections, proportional, fully nonproportional, and partial proportional odds models are fit to data from a study of a new analgesic for dental pain relief. Increasing relief from pain was recorded on a 5-point scale (0-4). Initially, PROC LOGISTIC is used to fit a proportional odds model involving three categorical predictors: the research center (CENTER=1 or 2), the treatment dosage (TRT=ACL, TL, ACH, TH, or P), and baseline pain (BASELINE=0 or 1). The proportional odds test is significant and tables produced with PROC FREQ (not shown) of each predictor against the response show generally adequate sample size. The alternative models are then fit.
Derr (2013) also discusses the testing and assessment of the proportional odds assumption. When the proportional odds assumption is rejected, he illustrates fitting the partial proportional odds model.
The following statements fit the proportional odds model to the dental data using PROC LOGISTIC. In PROC LOGISTIC, the CLASS statement creates reference-coded dummy variables for each of the three categorical predictors. The ORDER=DATA option causes predictor levels to be ordered as they first appear in the data set. The DESCENDING response variable option allows you to model the probability of the higher response levelsNOTE. The OUTPUT statement saves the cumulative predicted probabilities and the individual predicted probabilities to data set LOG.
proc logistic data=dent;
class center baseline trt / param=ref order=data;
model resp(descending)=center baseline trt;
output out=log predprobs=(c i);
run;
The test of the proportional odds assumption in PROC LOGISTIC is significant (p=0.0089) indicating that proportional odds does not hold and suggesting that separate parameters are needed across the logits for at least one predictor. A visual assessment of the assumption is provided by plotting the empirical logits.
| Score Test for the Proportional Odds Assumption | ||
|---|---|---|
| Chi-Square | DF | Pr > ChiSq |
| 35.2185 | 18 | 0.0089 |
| Analysis of Maximum Likelihood Estimates | ||||||
|---|---|---|---|---|---|---|
| Parameter | DF | Estimate | Standard Error | Wald Chi-Square | Pr > ChiSq | |
| Intercept | 4 | 1 | -2.8017 | 0.4814 | 33.8722 | <.0001 |
| Intercept | 3 | 1 | -1.0732 | 0.4472 | 5.7600 | 0.0164 |
| Intercept | 2 | 1 | -0.0434 | 0.4436 | 0.0096 | 0.9221 |
| Intercept | 1 | 1 | 0.9330 | 0.4476 | 4.3440 | 0.0371 |
| CENTER | 1 | 1 | -1.9388 | 0.2555 | 57.5778 | <.0001 |
| BASELINE | 0 | 1 | -0.6137 | 0.3361 | 3.3342 | 0.0679 |
| TRT | ACL | 1 | 1.5309 | 0.3978 | 14.8129 | 0.0001 |
| TRT | TL | 1 | 1.5045 | 0.3993 | 14.1940 | 0.0002 |
| TRT | ACH | 1 | 1.8204 | 0.4002 | 20.6867 | <.0001 |
| TRT | TH | 1 | 2.0204 | 0.4010 | 25.3863 | <.0001 |
The addition of the UNEQUALSLOPES option causes PROC LOGISTIC to fit the fully nonproportional odds model which includes separate slope parameters for each effect on each of the logits. If you also include the EQUALSLOPES option (available beginning in SAS 9.4 TS1M2), the model includes both a common, reference slope (slope on last logit) for each effect as well as parameters representing the differences between the reference slope and the separate slopes. The results include joint tests of these sets of difference parameters in the "Type 3 Analysis of Effects" table. Each set is labeled U__effect_ which is a test of the proportional odds assumption for effect. These statements fit the fully nonproportional odds model, parametrized to test the proportional odds assumption in each model effect.
proc logistic data=dent;
class center baseline trt / param=ref order=data;
model resp(descending) = center baseline trt / unequalslopes equalslopes;
run;
The nonsignificant tests for the CENTER and BASELINE effects (p=0.1782 and p=0.1727, respectively) suggest that the proportional odds assumption is reasonable for those effects. The test of proportional odds for the TRT effect (p=0.0688) is marginally significant. This seems consistent with the plots of the empirical logits.
| Type 3 Analysis of Effects | |||
|---|---|---|---|
| Effect | DF | Wald Chi-Square | Pr > ChiSq |
| CENTER | 1 | 42.7602 | <.0001 |
| U_CENTER | 3 | 4.9138 | 0.1782 |
| BASELINE | 1 | 2.6708 | 0.1022 |
| U_BASELINE | 3 | 4.9871 | 0.1727 |
| TRT | 4 | 32.1236 | <.0001 |
| U_TRT | 12 | 19.9122 | 0.0688 |
In the Parameter Estimates table, notice that the parameter estimates for each effect include a common, reference slope parameter (slope on RESP=1 logit) followed by three difference parameters for a total of four degrees of freedom. The three difference parameters for CENTER and BASELINE are all nonsignificant, as expected, but the difference parameters for TRT="ACH" show some significance which explains the marginally significant proportional odds test for the TRT effect.
| Analysis of Maximum Likelihood Estimates | |||||||
|---|---|---|---|---|---|---|---|
| Parameter | RESP | DF | Estimate | Standard Error | Wald Chi-Square | Pr > ChiSq | |
| Intercept | 4 | 1 | -1.9143 | 0.7984 | 5.7487 | 0.0165 | |
| Intercept | 3 | 1 | -0.8706 | 0.5798 | 2.2549 | 0.1332 | |
| Intercept | 2 | 1 | -0.6624 | 0.5321 | 1.5495 | 0.2132 | |
| Intercept | 1 | 1 | 1.1911 | 0.5724 | 4.3307 | 0.0374 | |
| CENTER | 1 | 1 | -2.2391 | 0.3424 | 42.7602 | <.0001 | |
| U_CENTER | 1 | 4 | 1 | 0.7502 | 0.6000 | 1.5632 | 0.2112 |
| U_CENTER | 1 | 3 | 1 | 0.1533 | 0.3906 | 0.1542 | 0.6946 |
| U_CENTER | 1 | 2 | 1 | 0.4673 | 0.2899 | 2.5984 | 0.1070 |
| U_CENTER | 1 | 1 | 0 | 0 | . | . | . |
| BASELINE | 0 | 1 | -0.7744 | 0.4739 | 2.6708 | 0.1022 | |
| U_BASELINE | 0 | 4 | 1 | -0.3549 | 0.7036 | 0.2544 | 0.6140 |
| U_BASELINE | 0 | 3 | 1 | 0.2538 | 0.5107 | 0.2471 | 0.6191 |
| U_BASELINE | 0 | 2 | 1 | 0.6892 | 0.4248 | 2.6313 | 0.1048 |
| U_BASELINE | 0 | 1 | 0 | 0 | . | . | . |
| TRT | ACL | 1 | 1.4190 | 0.4639 | 9.3557 | 0.0022 | |
| TRT | TL | 1 | 1.2923 | 0.4723 | 7.4848 | 0.0062 | |
| TRT | ACH | 1 | 2.6977 | 0.5334 | 25.5815 | <.0001 | |
| TRT | TH | 1 | 2.2822 | 0.5102 | 20.0106 | <.0001 | |
| U_TRT | ACL | 4 | 1 | -0.2071 | 0.9075 | 0.0521 | 0.8195 |
| U_TRT | ACL | 3 | 1 | 0.0644 | 0.5647 | 0.0130 | 0.9093 |
| U_TRT | ACL | 2 | 1 | 0.1693 | 0.4180 | 0.1640 | 0.6855 |
| U_TRT | ACL | 1 | 0 | 0 | . | . | . |
| U_TRT | TL | 4 | 1 | -0.6549 | 1.0232 | 0.4097 | 0.5221 |
| U_TRT | TL | 3 | 1 | 0.3176 | 0.5639 | 0.3171 | 0.5733 |
| U_TRT | TL | 2 | 1 | 0.5526 | 0.3919 | 1.9879 | 0.1586 |
| U_TRT | TL | 1 | 0 | 0 | . | . | . |
| U_TRT | ACH | 4 | 1 | -1.7339 | 1.0334 | 2.8149 | 0.0934 |
| U_TRT | ACH | 3 | 1 | -1.4494 | 0.6550 | 4.8959 | 0.0269 |
| U_TRT | ACH | 2 | 1 | -1.0150 | 0.5355 | 3.5931 | 0.0580 |
| U_TRT | ACH | 1 | 0 | 0 | . | . | . |
| U_TRT | TH | 4 | 1 | -0.8238 | 1.0052 | 0.6717 | 0.4125 |
| U_TRT | TH | 3 | 1 | -0.6984 | 0.6156 | 1.2872 | 0.2566 |
| U_TRT | TH | 2 | 1 | 0.0129 | 0.4655 | 0.0008 | 0.9779 |
| U_TRT | TH | 1 | 0 | 0 | . | . | . |
Note that you can also test for proportionality in each of the model effects and overall by omitting the EQUALSLOPES option and including appropriate TEST statements. When the UNEQUALSLOPES option appears without the EQUALSLOPES option, the parameters for each effect are the separate slopes on the logits rather than differences from the reference slope. The following four labeled TEST statements following the MODEL statement provide tests of proportionality. The first three TEST statements test for proportional odds in each of the three predictors. In the CENTER proportionality test (labeled CENTER_PO), the equality of the CENTER parameters across the four logits is tested. Similarly for the BASELINE proportionality test. For the TRT test, equality across the logits is tested simultaneously within each level of TRT. Parameter names used in the TEST statement are specified as described in "Parameter Names in the OUTEST= Data Set" in the Details section of the LOGISTIC documentation. The final TEST statement provides an overall test of proportional odds, similar to the test provided when the UNEQUALSLOPES option is not used. It combines the previous three tests into a single, joint test.
proc logistic data=dent;
class center baseline trt / param=ref order=data;
model resp(descending) = center baseline trt / unequalslopes;
CENTER_PO:test center1_4=center1_3=center1_2=center1_1;
BASELINE_PO:test baseline0_4=baseline0_3=baseline0_2=baseline0_1;
TRT_PO:test trtacl_4=trtacl_3=trtacl_2=trtacl_1,
trttl_4=trttl_3=trttl_2=trttl_1,
trtach_4=trtach_3=trtach_2=trtach_1,
trtth_4=trtth_3=trtth_2=trtth_1;
OVERALL_PO:test center1_4=center1_3=center1_2=center1_1,
baseline0_4=baseline0_3=baseline0_2=baseline0_1,
trtacl_4=trtacl_3=trtacl_2=trtacl_1,
trttl_4=trttl_3=trttl_2=trttl_1,
trtach_4=trtach_3=trtach_2=trtach_1,
trtth_4=trtth_3=trtth_2=trtth_1;
run;
In this parameterization of the fully nonproportional odds model, the separate slopes of each effect on each logit are given. The logit to which each parameter estimate applies is given in the RESP column. The value in the RESP column is the level after which the ordered response levels are cut to dichotomize the response. For instance, the value 4 indicates the logit comparing level 4 with levels 3, 2, and 1. The value 3 indicates the logit comparing levels 4 and 3 with levels 2 and 1, and so on.
| Analysis of Maximum Likelihood Estimates | |||||||
|---|---|---|---|---|---|---|---|
| Parameter | RESP | DF | Estimate | Standard Error | Wald Chi-Square | Pr > ChiSq | |
| Intercept | 4 | 1 | -1.9143 | 0.7984 | 5.7487 | 0.0165 | |
| Intercept | 3 | 1 | -0.8706 | 0.5798 | 2.2549 | 0.1332 | |
| Intercept | 2 | 1 | -0.6624 | 0.5321 | 1.5495 | 0.2132 | |
| Intercept | 1 | 1 | 1.1911 | 0.5724 | 4.3307 | 0.0374 | |
| CENTER | 1 | 4 | 1 | -1.4890 | 0.5466 | 7.4205 | 0.0064 |
| CENTER | 1 | 3 | 1 | -2.0858 | 0.3372 | 38.2664 | <.0001 |
| CENTER | 1 | 2 | 1 | -1.7719 | 0.2903 | 37.2503 | <.0001 |
| CENTER | 1 | 1 | 1 | -2.2391 | 0.3424 | 42.7602 | <.0001 |
| BASELINE | 0 | 4 | 1 | -1.1293 | 0.6061 | 3.4723 | 0.0624 |
| BASELINE | 0 | 3 | 1 | -0.5206 | 0.4211 | 1.5280 | 0.2164 |
| BASELINE | 0 | 2 | 1 | -0.0853 | 0.4104 | 0.0432 | 0.8354 |
| BASELINE | 0 | 1 | 1 | -0.7744 | 0.4739 | 2.6708 | 0.1022 |
| TRT | ACL | 4 | 1 | 1.2119 | 0.8738 | 1.9233 | 0.1655 |
| TRT | ACL | 3 | 1 | 1.4833 | 0.5592 | 7.0359 | 0.0080 |
| TRT | ACL | 2 | 1 | 1.5883 | 0.4874 | 10.6201 | 0.0011 |
| TRT | ACL | 1 | 1 | 1.4190 | 0.4639 | 9.3557 | 0.0022 |
| TRT | TL | 4 | 1 | 0.6374 | 0.9853 | 0.4184 | 0.5177 |
| TRT | TL | 3 | 1 | 1.6098 | 0.5564 | 8.3716 | 0.0038 |
| TRT | TL | 2 | 1 | 1.8448 | 0.5008 | 13.5678 | 0.0002 |
| TRT | TL | 1 | 1 | 1.2923 | 0.4723 | 7.4848 | 0.0062 |
| TRT | ACH | 4 | 1 | 0.9638 | 0.9555 | 1.0175 | 0.3131 |
| TRT | ACH | 3 | 1 | 1.2483 | 0.5610 | 4.9512 | 0.0261 |
| TRT | ACH | 2 | 1 | 1.6827 | 0.4900 | 11.7902 | 0.0006 |
| TRT | ACH | 1 | 1 | 2.6977 | 0.5334 | 25.5815 | <.0001 |
| TRT | TH | 4 | 1 | 1.4583 | 0.9401 | 2.4062 | 0.1209 |
| TRT | TH | 3 | 1 | 1.5837 | 0.5475 | 8.3683 | 0.0038 |
| TRT | TH | 2 | 1 | 2.2951 | 0.4969 | 21.3320 | <.0001 |
| TRT | TH | 1 | 1 | 2.2822 | 0.5102 | 20.0106 | <.0001 |
The overall test of proportional odds from the fourth TEST statement (OVERALL_PO) is a Wald test and gives results (p=0.0038) similar to the score test provided with the proportional odds model above. As before, only the test of the TRT effect (TRT_PO) suggests the possibility of nonproportionality.
| Linear Hypotheses Testing Results | |||
|---|---|---|---|
| Label | Wald Chi-Square | DF | Pr > ChiSq |
| CENTER_PO | 4.9138 | 3 | 0.1782 |
| BASELINE_PO | 4.9871 | 3 | 0.1727 |
| TRT_PO | 19.9122 | 12 | 0.0688 |
| OVERALL_PO | 38.0570 | 18 | 0.0038 |
If you are willing to assume that proportional odds holds for the BASELINE and CENTER predictors, then a partial proportional odds model can be fit which allows for nonproportionality only in the TRT predictor by specifying the UNEQUALSLOPES=TRT option. A common parameter is used across the logits for BASELINE and CENTER while separate parameters are used for the TRT levels. The following statements fit this partial proportional odds model.
Additionally, suppose you want to test whether the TRT levels differ. Normally, this can be done using the DIFF option in an LSMEANS statement. However, this statement is not available when the UNEQUALSLOPES or EQUALSLOPES option is specified. Instead, TEST statements are used. The first four labeled TEST statements test for treatment differences in each of the four logits. The final TEST statement (TRT_PO) tests for proportional odds for TRT in this simplified model.
proc logistic data=dent;
class center baseline trt / param=ref order=data;
model resp(descending)=center baseline trt / unequalslopes=trt;
TRT_RESP4:test trtacl_4,trttl_4,trtach_4,trtth_4;
TRT_RESP3:test trtacl_3,trttl_3,trtach_3,trtth_3;
TRT_RESP2:test trtacl_2,trttl_2,trtach_2,trtth_2;
TRT_RESP1:test trtacl_1,trttl_1,trtach_1,trtth_1;
TRT_PO:test trtacl_4=trtacl_3=trtacl_2=trtacl_1,
trttl_4=trttl_3=trttl_2=trttl_1,
trtach_4=trtach_3=trtach_2=trtach_1,
trtth_4=trtth_3=trtth_2=trtth_1;
run;
The table of parameter estimates shows the separate intercepts and separate TRT parameters for each logit, and the single parameter for each of BASELINE and CENTER in this partial proportional odds model.
| Analysis of Maximum Likelihood Estimates | |||||||
|---|---|---|---|---|---|---|---|
| Parameter | RESP | DF | Estimate | Standard Error | Wald Chi-Square | Pr > ChiSq | |
| Intercept | 4 | 1 | -2.1728 | 0.7859 | 7.6441 | 0.0057 | |
| Intercept | 3 | 1 | -0.8979 | 0.5469 | 2.6959 | 0.1006 | |
| Intercept | 2 | 1 | -0.2045 | 0.4968 | 0.1694 | 0.6807 | |
| Intercept | 1 | 1 | 0.8796 | 0.4723 | 3.4687 | 0.0625 | |
| CENTER | 1 | 1 | -1.9788 | 0.2595 | 58.1542 | <.0001 | |
| BASELINE | 0 | 1 | -0.5606 | 0.3537 | 2.5120 | 0.1130 | |
| TRT | ACL | 4 | 1 | 1.2763 | 0.8569 | 2.2185 | 0.1364 |
| TRT | ACL | 3 | 1 | 1.4614 | 0.5565 | 6.8963 | 0.0086 |
| TRT | ACL | 2 | 1 | 1.6651 | 0.4839 | 11.8382 | 0.0006 |
| TRT | ACL | 1 | 1 | 1.3353 | 0.4501 | 8.8001 | 0.0030 |
| TRT | TL | 4 | 1 | 0.4960 | 0.9463 | 0.2747 | 0.6002 |
| TRT | TL | 3 | 1 | 1.6643 | 0.5524 | 9.0763 | 0.0026 |
| TRT | TL | 2 | 1 | 1.8728 | 0.4887 | 14.6887 | 0.0001 |
| TRT | TL | 1 | 1 | 1.1711 | 0.4519 | 6.7144 | 0.0096 |
| TRT | ACH | 4 | 1 | 0.8320 | 0.9026 | 0.8497 | 0.3566 |
| TRT | ACH | 3 | 1 | 1.3112 | 0.5594 | 5.4943 | 0.0191 |
| TRT | ACH | 2 | 1 | 1.7105 | 0.4868 | 12.3490 | 0.0004 |
| TRT | ACH | 1 | 1 | 2.5727 | 0.5195 | 24.5251 | <.0001 |
| TRT | TH | 4 | 1 | 1.2844 | 0.8549 | 2.2571 | 0.1330 |
| TRT | TH | 3 | 1 | 1.6081 | 0.5453 | 8.6972 | 0.0032 |
| TRT | TH | 2 | 1 | 2.3383 | 0.4918 | 22.6063 | <.0001 |
| TRT | TH | 1 | 1 | 2.2175 | 0.4942 | 20.1352 | <.0001 |
The tests for treatment differences suggest that the treatments differ on logits 1, 2, and 3, but not on logit 4 (p=0.4925). The test for proportional odds in the treatment effect (TEST_PO) continues to indicate possible lack of proportionality (p=0.0729).
| Linear Hypotheses Testing Results | |||
|---|---|---|---|
| Label | Wald Chi-Square | DF | Pr > ChiSq |
| TRT_RESP4 | 3.4046 | 4 | 0.4925 |
| TRT_RESP3 | 10.7834 | 4 | 0.0291 |
| TRT_RESP2 | 24.3858 | 4 | <.0001 |
| TRT_RESP1 | 31.9492 | 4 | <.0001 |
| TRT_PO | 19.7037 | 12 | 0.0729 |
You can use the SELECTION= option to have PROC LOGISTIC determine which effects exhibit nonproportional odds and choose a final model. The following statements use stepwise effect selection to select a final model from a set of candidate effects that includes all equal and unequal slope parameters. Beginning in SAS 9.4 TS1M2, the EQUALSLOPES option makes the equal slope parameters available. Used with the UNEQUALSLOPES option, all equal and unequal slope parameters are available for effect selection. The INCLUDE=EQUALSLOPES option restricts the selection by requiring every model in the selection process to include the equal slope parameters. The selection process tests the unequal slope parameters for an effect and includes and retains them if significant at the 0.1 level. The DETAILS option shows the tests of the candidate effects at each step.
proc logistic data=dent;
class center baseline trt / param=ref order=data;
model resp(descending)=center baseline trt / selection=stepwise slentry=0.1 slstay=0.1
equalslopes unequalslopes include=equalslopes details;
run;
The model in the first step includes the intercepts and equal slope parameters. This is the same proportional odds model as shown above. The analysis at this step includes tests of the remaining candidate effects, which are the unequal slope parameters for each of the three predictors. The U_ prefix indicates that these are the unequal slope parameters for each predictor. The score tests give similar results to the Wald tests for proportional odds shown above.
| Analysis of Effects Eligible for Entry | |||
|---|---|---|---|
| Effect | DF | Score Chi-Square | Pr > ChiSq |
| U_CENTER | 3 | 6.1038 | 0.1067 |
| U_BASELINE | 3 | 5.6195 | 0.1317 |
| U_TRT | 12 | 21.8632 | 0.0391 |
Since the unequal slopes effect for TRT is significant at the 0.1 level, it is included in the next step of the model selection process. This results in the same partial proportional odds model shown above but is parameterized slightly differently with a set of equal slope parameters followed by sets of unequal slope parameters. For each TRT level, the equal slope parameter is used as the slope for the last logit (RESP=1), and the unequal slope parameters (U_TRT) are deviations from the equal slope parameter.
| Analysis of Maximum Likelihood Estimates | |||||||
|---|---|---|---|---|---|---|---|
| Parameter | RESP | DF | Estimate | Standard Error | Wald Chi-Square | Pr > ChiSq | |
| Intercept | 4 | 1 | -2.1728 | 0.7859 | 7.6441 | 0.0057 | |
| Intercept | 3 | 1 | -0.8979 | 0.5469 | 2.6959 | 0.1006 | |
| Intercept | 2 | 1 | -0.2045 | 0.4968 | 0.1694 | 0.6807 | |
| Intercept | 1 | 1 | 0.8796 | 0.4723 | 3.4687 | 0.0625 | |
| CENTER | 1 | 1 | -1.9788 | 0.2595 | 58.1542 | <.0001 | |
| BASELINE | 0 | 1 | -0.5606 | 0.3537 | 2.5120 | 0.1130 | |
| TRT | ACL | 1 | 1.3353 | 0.4501 | 8.8001 | 0.0030 | |
| TRT | TL | 1 | 1.1711 | 0.4519 | 6.7144 | 0.0096 | |
| TRT | ACH | 1 | 2.5727 | 0.5195 | 24.5251 | <.0001 | |
| TRT | TH | 1 | 2.2175 | 0.4942 | 20.1352 | <.0001 | |
| U_TRT | ACL | 4 | 1 | -0.0590 | 0.8864 | 0.0044 | 0.9469 |
| U_TRT | ACL | 3 | 1 | 0.1261 | 0.5553 | 0.0516 | 0.8204 |
| U_TRT | ACL | 2 | 1 | 0.3298 | 0.4085 | 0.6519 | 0.4194 |
| U_TRT | ACL | 1 | 0 | 0 | . | . | . |
| U_TRT | TL | 4 | 1 | -0.6751 | 0.9757 | 0.4787 | 0.4890 |
| U_TRT | TL | 3 | 1 | 0.4932 | 0.5380 | 0.8403 | 0.3593 |
| U_TRT | TL | 2 | 1 | 0.7018 | 0.3744 | 3.5136 | 0.0609 |
| U_TRT | TL | 1 | 0 | 0 | . | . | . |
| U_TRT | ACH | 4 | 1 | -1.7407 | 0.9761 | 3.1801 | 0.0745 |
| U_TRT | ACH | 3 | 1 | -1.2615 | 0.6411 | 3.8725 | 0.0491 |
| U_TRT | ACH | 2 | 1 | -0.8622 | 0.5248 | 2.6986 | 0.1004 |
| U_TRT | ACH | 1 | 0 | 0 | . | . | . |
| U_TRT | TH | 4 | 1 | -0.9331 | 0.9171 | 1.0352 | 0.3089 |
| U_TRT | TH | 3 | 1 | -0.6094 | 0.6031 | 1.0210 | 0.3123 |
| U_TRT | TH | 2 | 1 | 0.1208 | 0.4509 | 0.0717 | 0.7888 |
| U_TRT | TH | 1 | 0 | 0 | . | . | . |
Since tests of the remaining nonproportional odds effects are not significant, the selection process ends.
| Analysis of Effects Eligible for Entry | |||
|---|---|---|---|
| Effect | DF | Score Chi-Square | Pr > ChiSq |
| U_CENTER | 3 | 5.6487 | 0.1300 |
| U_BASELINE | 3 | 5.9237 | 0.1154 |
An additional example of fitting nonproportional odds models and using model selection can be found in the example titled "Partial Proportional Odds Model" in the LOGISTIC documentation.
References
Peterson, B. and F. Harrell (1990), "Partial Proportional Odds Models for Ordinal Response Variables," Applied Statistics , 39:205-217.
Stokes, M.E., Davis, C.S., and Koch, G.G.
Addendum: Using NLMIXED to fit ordinal logistic models
The following section fits the same models as above using PROC NLMIXED.
In PROC NLMIXED, reference-coded dummies (T1-T4, B, and C) are created 
proc nlmixed data=dent;
parms Int4 = -1, Int3 = 0, Int2 = 1, Int1 = 2;
t1=(trt='ACL'); t2=(trt='TL'); t3=(trt='ACH'); t4=(trt='TH');
b=(baseline=0); c=(center=1);
cp4= logistic(Int4 + bc1*c + bb0*b + bACL*t1 + bTL*t2 + bACH*t3 + bTH*t4);
cp3= logistic(Int3 + bc1*c + bb0*b + bACL*t1 + bTL*t2 + bACH*t3 + bTH*t4);
cp2= logistic(Int2 + bc1*c + bb0*b + bACL*t1 + bTL*t2 + bACH*t3 + bTH*t4);
cp1= logistic(Int1 + bc1*c + bb0*b + bACL*t1 + bTL*t2 + bACH*t3 + bTH*t4);
if resp=4 then ip = cp4; /* CP4 is Pr(resp=4) */
else if resp=3 then ip = cp3-cp4; /* CP3 is Pr(resp=4 or 3) */
else if resp=2 then ip = cp2-cp3; /* CP2 is Pr(resp=4 or 3 or 2) */
else if resp=1 then ip = cp1-cp2; /* CP1 is Pr(resp=4 or 3 or 2 or 1) */
else ip = 1-cp1; /* IP is Pr(resp=observed level) */
p = (ip>0 and ip<=1)*ip + (ip<=0)*1e-8 + (ip>1);
loglik = log(p);
model resp ~ general(loglik);
id cp1-cp4;
predict ip out=nlm;
run;
The parameter estimates from PROC NLMIXED agree closely with those from PROC LOGISTIC. The standard errors differ slightly since LOGISTIC constructs Wald tests while NLMIXED uses t-tests based on the available degrees of freedom. The predicted probabilities produced by the two procedures (in data sets LOG and NLM) are also very similar.
Note that unique names are used across the cumulative probabilities
The parameter estimates of the fully nonproportional odds model has four complete sets of parameter estimates compared to the single set in the proportional odds model. The logit to which the parameter estimate applies is given in the last character of its name. For instance, the estimates Int4, bc14, bb04, bACL4, bTL4, bACH4, and bTH4 are the parameter estimates associated with the fourth logit which contrasts the highest level of relief against all other levels.
proc nlmixed data=dent;
parms Int4 = -1, Int3 = 0, Int2 = 1, Int1 = 2;
t1=(trt='ACL'); t2=(trt='TL'); t3=(trt='ACH'); t4=(trt='TH');
b=(baseline=0); c=(center=1);
cp4= logistic(Int4 + bc14*c + bb04*b + bACL4*t1 + bTL4*t2 + bACH4*t3 + bTH4*t4);
cp3= logistic(Int3 + bc13*c + bb03*b + bACL3*t1 + bTL3*t2 + bACH3*t3 + bTH3*t4);
cp2= logistic(Int2 + bc12*c + bb02*b + bACL2*t1 + bTL2*t2 + bACH2*t3 + bTH2*t4);
cp1= logistic(Int1 + bc11*c + bb01*b + bACL1*t1 + bTL1*t2 + bACH1*t3 + bTH1*t4);
if resp=4 then ip = cp4;
else if resp=3 then ip = cp3-cp4;
else if resp=2 then ip = cp2-cp3;
else if resp=1 then ip = cp1-cp2;
else ip = 1-cp1;
p = (ip>0 and ip<=1)*ip + (ip<=0)*1e-8 + (ip>1);
loglik = log(p);
model resp ~ general(loglik);
id cp1-cp4;
predict ip out=nlm;
contrast 'center on logit1 (4321 vs 0)' bc11;
contrast 'baseline on logit1 (4321 vs 0)' bb01;
contrast 'trt on logit1 (4321 vs 0)'
bACL1, bTL1, bACH1, bTH1;
contrast 'center PO'
bc11-bc14, bc12-bc14, bc13-bc14;
contrast 'baseline PO'
bb01-bb04, bb02-bb04, bb03-bb04;
contrast 'trt PO'
bACL1-bACL4, bACL2-bACL4, bACL3-bACL4,
bTL1-bTL4, bTL2-bTL4, bTL3-bTL4,
bACH1-bACH4, bACH2-bACH4, bACH3-bACH4,
bTH1-bTH4, bTH2-bTH4, bTH3-bTH4;
contrast 'overall PO'
bc11-bc14, bc12-bc14, bc13-bc14,
bb01-bb04, bb02-bb04, bb03-bb04,
bACL1-bACL4, bACL2-bACL4, bACL3-bACL4,
bTL1-bTL4, bTL2-bTL4, bTL3-bTL4,
bACH1-bACH4, bACH2-bACH4, bACH3-bACH4,
bTH1-bTH4, bTH2-bTH4, bTH3-bTH4;
run;
A partial proportional odds model is fit with a common parameter across the logits for BASELINE (BB0) and CENTER (BC1) and separate parameters for the TRT levels. The following statements fit this partial proportional odds model in PROC NLMIXED.
proc nlmixed data=dent;
parms Int4 = -1, Int3 = 0, Int2 = 1, Int1 = 2;
t1=(trt='ACL'); t2=(trt='TL'); t3=(trt='ACH'); t4=(trt='TH');
b=(baseline=0); c=(center=1);
cp4= logistic(Int4 + bc1*c + bb0*b + bACL4*t1 + bTL4*t2 + bACH4*t3 + bTH4*t4);
cp3= logistic(Int3 + bc1*c + bb0*b + bACL3*t1 + bTL3*t2 + bACH3*t3 + bTH3*t4);
cp2= logistic(Int2 + bc1*c + bb0*b + bACL2*t1 + bTL2*t2 + bACH2*t3 + bTH2*t4);
cp1= logistic(Int1 + bc1*c + bb0*b + bACL1*t1 + bTL1*t2 + bACH1*t3 + bTH1*t4);
if resp=4 then ip = cp4;
else if resp=3 then ip = cp3-cp4;
else if resp=2 then ip = cp2-cp3;
else if resp=1 then ip = cp1-cp2;
else ip = 1-cp1;
p = (ip>0 and ip<=1)*ip + (ip<=0)*1e-8 + (ip>1);
loglik = log(p);
model resp ~ general(loglik);
id cp1-cp4;
predict ip out=nlm;
run;
NOTE: If you want to model the probability of lower, rather than higher, response levels omit the DESCENDING response variable option in the MODEL statement of PROC LOGISTIC. In PROC NLMIXED, you could simply use increasing values of RESP in the statements defining the individual probability. For instance:
if resp=0 then ip = cp4;
else if resp=1 then ip = cp3-cp4;
else if resp=2 then ip = cp2-cp3;
else if resp=3 then ip = cp1-cp2;
else ip = 1-cp1;
But the results will be more meaningfully labeled if you also change the names of the parameters and cumulative probabilities as below for the proportional odds model:
proc nlmixed data=dent;
parms Int0 = -1, Int1 = 0, Int2 = 1, Int3 = 2;
t1=(trt='ACL'); t2=(trt='TL'); t3=(trt='ACH'); t4=(trt='TH');
b=(baseline=0); c=(center=1);
cp0= logistic(Int0 + bc1*c + bb0*b + bACL*t1 + bTL*t2 + bACH*t3 + bTH*t4);
cp1= logistic(Int1 + bc1*c + bb0*b + bACL*t1 + bTL*t2 + bACH*t3 + bTH*t4);
cp2= logistic(Int2 + bc1*c + bb0*b + bACL*t1 + bTL*t2 + bACH*t3 + bTH*t4);
cp3= logistic(Int3 + bc1*c + bb0*b + bACL*t1 + bTL*t2 + bACH*t3 + bTH*t4);
if resp=0 then ip = cp0; /* CP0 is Pr(resp=0) */
else if resp=1 then ip = cp1-cp0; /* CP1 is Pr(resp=0 or 1) */
else if resp=2 then ip = cp2-cp1; /* CP2 is Pr(resp=0 or 1 or 2) */
else if resp=3 then ip = cp3-cp2; /* CP3 is Pr(resp=0 or 1 or 2 or 3) */
else ip = 1-cp3; /* IP is Pr(resp=observed level) */
p = (ip>0 and ip<=1)*ip + (ip<=0)*1e-8 + (ip>1);
loglik = log(p);
model resp ~ general(loglik);
id cp1-cp4;
predict ip out=nlm;
run;
data dent; input patient center trt $ baseline ldose resp @@; datalines; 2 1 ACL 0 5.29832 0 131 1 TL 0 3.91202 2 1 1 ACH 1 5.99146 1 3 1 TH 0 4.60517 1 130 1 P 0 0.00000 0 132 1 P 0 0.00000 0 4 1 P 0 0.00000 0 133 1 P 0 0.00000 0 5 1 P 0 0.00000 0 134 2 ACH 0 5.99146 4 6 1 TL 1 3.91202 2 135 2 ACL 0 5.29832 4 7 1 ACH 0 5.99146 1 136 2 TH 0 4.60517 3 8 1 ACL 0 5.29832 0 137 2 ACL 0 5.29832 4 9 1 TL 1 3.91202 0 138 2 TL 0 3.91202 3 10 1 TL 1 3.91202 4 139 2 P 0 0.00000 4 11 1 ACL 0 5.29832 2 140 2 TL 0 3.91202 3 12 1 ACH 0 5.99146 0 141 2 TL 0 3.91202 3 13 1 P 0 0.00000 0 142 2 ACL 1 5.29832 3 14 1 TL 0 3.91202 0 143 2 ACH 0 5.99146 1 15 1 P 0 0.00000 0 144 2 ACH 0 5.99146 3 16 1 TH 1 4.60517 4 145 2 P 0 0.00000 1 17 1 TH 0 4.60517 2 146 2 P 0 0.00000 0 18 1 ACH 0 5.99146 1 147 2 ACH 0 5.99146 4 19 1 ACL 0 5.29832 0 148 2 TL 0 3.91202 2 20 1 TH 0 4.60517 3 149 2 TH 0 4.60517 3 21 1 P 1 0.00000 1 150 2 P 0 0.00000 0 22 1 TH 1 4.60517 0 151 2 TH 0 4.60517 2 23 1 TL 0 3.91202 2 152 2 ACL 1 5.29832 3 24 1 ACL 1 5.29832 0 153 2 TH 0 4.60517 2 25 1 P 0 0.00000 0 154 2 ACH 0 5.99146 3 26 1 ACH 0 5.99146 0 155 2 ACL 0 5.29832 1 27 1 ACL 0 5.29832 0 156 2 ACL 0 5.29832 0 28 1 P 0 0.00000 0 157 2 ACL 0 5.29832 3 29 1 ACH 0 5.99146 2 158 2 TH 0 4.60517 3 30 1 TL 0 3.91202 0 159 2 ACL 0 5.29832 1 31 1 P 0 0.00000 0 160 2 TL 0 3.91202 3 32 1 ACH 0 5.99146 1 161 2 P 0 0.00000 2 33 1 TL 0 3.91202 0 162 2 TH 0 4.60517 3 34 1 TH 1 4.60517 4 163 2 TH 0 4.60517 4 35 1 TL 0 3.91202 2 164 2 ACH 0 5.99146 3 36 1 ACH 0 5.99146 0 165 2 TH 0 4.60517 2 37 1 ACL 1 5.29832 1 166 2 P 0 0.00000 3 38 1 ACL 0 5.29832 3 167 2 ACH 0 5.99146 1 39 1 TH 0 4.60517 2 168 2 P 0 0.00000 2 40 1 TH 0 4.60517 0 169 2 TL 1 3.91202 2 41 1 ACL 0 5.29832 2 170 2 P 0 0.00000 0 42 1 TL 0 3.91202 3 171 2 TL 0 3.91202 0 43 1 ACL 0 5.29832 2 172 2 TL 0 3.91202 3 44 1 ACL 0 5.29832 0 173 2 ACH 1 5.99146 2 45 1 TH 0 4.60517 2 174 2 ACL 0 5.29832 3 46 1 ACH 0 5.99146 0 175 2 P 0 0.00000 4 47 1 P 0 0.00000 0 176 2 TL 1 3.91202 0 48 1 ACL 0 5.29832 0 177 2 ACH 0 5.99146 1 49 1 TL 0 3.91202 0 178 2 ACH 1 5.99146 2 50 1 TL 0 3.91202 2 179 2 ACL 0 5.29832 2 51 1 TL 0 3.91202 0 180 2 ACL 0 5.29832 2 52 1 ACH 0 5.99146 4 181 2 TH 0 4.60517 2 53 1 TH 0 4.60517 4 182 2 TL 0 3.91202 3 54 1 TH 0 4.60517 0 183 2 TH 0 4.60517 3 55 1 P 0 0.00000 0 184 2 ACH 0 5.99146 1 56 1 ACH 0 5.99146 3 185 2 P 0 0.00000 1 57 1 ACH 0 5.99146 2 186 2 ACL 0 5.29832 1 58 1 P 0 0.00000 0 187 2 TH 0 4.60517 2 59 1 TH 0 4.60517 0 188 2 ACH 1 5.99146 3 60 1 P 0 0.00000 0 189 2 TH 0 4.60517 2 61 1 TL 0 3.91202 1 190 2 TL 0 3.91202 3 62 1 P 0 0.00000 0 191 2 P 0 0.00000 1 63 1 TH 1 4.60517 1 192 2 TL 0 3.91202 3 64 1 TL 0 3.91202 0 193 2 P 0 0.00000 0 65 1 ACH 0 5.99146 2 194 2 TH 0 4.60517 2 66 1 ACL 0 5.29832 2 195 2 ACH 0 5.99146 4 67 1 P 0 0.00000 2 196 2 ACH 0 5.99146 2 68 1 TH 0 4.60517 1 197 2 ACL 0 5.29832 3 69 1 ACH 0 5.99146 0 198 2 P 0 0.00000 0 70 1 P 0 0.00000 0 199 2 P 0 0.00000 3 71 1 TL 0 3.91202 0 200 2 ACL 0 5.29832 0 72 1 ACH 0 5.99146 2 201 2 ACL 1 5.29832 4 73 1 P 0 0.00000 0 202 2 TH 0 4.60517 3 74 1 TL 0 3.91202 2 203 2 P 0 0.00000 1 75 1 TH 0 4.60517 2 204 2 TH 0 4.60517 1 76 1 ACL 1 5.29832 0 205 2 TH 0 4.60517 3 77 1 TH 1 4.60517 0 206 2 TL 0 3.91202 3 78 1 ACL 0 5.29832 0 207 2 TL 0 3.91202 3 79 1 ACL 1 5.29832 3 208 2 TL 0 3.91202 3 80 1 ACH 0 5.99146 2 209 2 ACL 0 5.29832 2 81 1 ACL 0 5.29832 0 210 2 ACH 0 5.99146 3 82 1 P 0 0.00000 0 211 2 TL 1 3.91202 1 83 1 TH 0 4.60517 0 212 2 ACH 0 5.99146 3 84 1 ACH 0 5.99146 1 213 2 P 0 0.00000 2 85 1 TL 0 3.91202 0 214 2 P 0 0.00000 0 86 1 TH 0 4.60517 3 215 2 TL 0 3.91202 0 87 1 ACH 0 5.99146 0 216 2 TH 0 4.60517 4 88 1 P 0 0.00000 0 217 2 ACH 0 5.99146 2 89 1 ACH 0 5.99146 1 218 2 P 0 0.00000 0 90 1 TL 0 3.91202 0 219 2 TH 0 4.60517 2 91 1 ACL 0 5.29832 1 220 2 TL 0 3.91202 1 92 1 TH 0 4.60517 0 221 2 ACH 0 5.99146 2 93 1 ACL 0 5.29832 1 222 2 TL 0 3.91202 4 94 1 TL 1 3.91202 1 223 2 TH 0 4.60517 2 95 1 TL 1 3.91202 3 224 2 TH 1 4.60517 1 96 1 P 0 0.00000 0 225 2 ACH 0 5.99146 1 97 1 TH 0 4.60517 0 226 2 ACL 0 5.29832 4 98 1 ACL 0 5.29832 0 227 2 P 1 0.00000 3 99 1 P 1 0.00000 0 228 2 ACL 0 5.29832 2 100 1 ACH 0 5.99146 2 229 2 TL 0 3.91202 0 101 1 TH 0 4.60517 0 230 2 ACL 0 5.29832 1 102 1 TL 0 3.91202 0 231 2 ACH 0 5.99146 3 103 1 ACL 0 5.29832 1 232 2 ACL 0 5.29832 3 104 1 TL 0 3.91202 0 233 2 P 0 0.00000 1 105 1 P 0 0.00000 1 234 2 ACL 0 5.29832 4 106 1 ACL 0 5.29832 0 235 2 ACH 0 5.99146 1 107 1 TH 1 4.60517 2 236 2 TH 0 4.60517 1 108 1 P 0 0.00000 0 237 2 ACL 0 5.29832 0 109 1 ACH 0 5.99146 1 238 2 ACL 1 5.29832 4 110 1 TH 1 4.60517 1 239 2 ACL 0 5.29832 3 111 1 TL 0 3.91202 0 240 2 P 0 0.00000 0 112 1 ACH 0 5.99146 0 241 2 P 1 0.00000 3 113 1 TL 0 3.91202 0 242 2 TL 0 3.91202 2 114 1 ACH 0 5.99146 1 243 2 P 0 0.00000 0 115 1 P 0 0.00000 0 244 2 TH 0 4.60517 3 116 1 ACL 0 5.29832 0 245 2 TL 1 3.91202 4 117 1 P 0 0.00000 0 246 2 ACH 1 5.99146 1 118 1 ACH 0 5.99146 3 247 2 P 0 0.00000 1 119 1 TH 0 4.60517 3 248 2 TH 0 4.60517 4 120 1 ACL 0 5.29832 2 249 2 TL 0 3.91202 0 121 1 TH 0 4.60517 2 250 2 TL 0 3.91202 3 122 1 TH 0 4.60517 1 251 2 ACH 0 5.99146 3 123 1 TL 0 3.91202 0 252 2 TH 0 4.60517 3 124 1 ACH 0 5.99146 0 253 2 ACH 0 5.99146 1 125 1 ACL 0 5.29832 0 254 2 TH 0 4.60517 3 126 1 TH 1 4.60517 0 255 2 ACL 0 5.29832 0 127 1 ACL 0 5.29832 0 256 2 TL 0 3.91202 3 128 1 ACH 0 5.99146 1 257 2 P 0 0.00000 1 129 1 ACL 0 5.29832 3 258 2 ACH 0 5.99146 3 ;
| Product Family | Product | System | SAS Release | |
| Reported | Fixed* | |||
| SAS System | SAS/STAT | All | n/a | |
***** For software releases that are not yet generally available, the Fixed Release is the software release in which the problem is planned to be fixed.