From 883230b18f2632e472e4655eeb14d9155a9abe3a Mon Sep 17 00:00:00 2001
From: Artur Ayukhanov <aartbear@gmail.com>
Date: Wed, 18 Oct 2017 22:11:16 +0300
Subject: [PATCH] =?UTF-8?q?=D0=9F=D0=BE=D0=B4=D1=81=D1=87=D0=B5=D1=82=20?=
 =?UTF-8?q?=D0=BF=D0=BE=D0=BA=D1=80=D1=8B=D1=82=D0=B8=D1=8F=20=D0=BA=D0=BE?=
 =?UTF-8?q?=D0=B4=D0=B0=20#27?=
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

---
 tasks/coverage.os | 73 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 tasks/coverage.os

diff --git a/tasks/coverage.os b/tasks/coverage.os
new file mode 100644
index 0000000..ca026d3
--- /dev/null
+++ b/tasks/coverage.os
@@ -0,0 +1,73 @@
+#Использовать 1commands
+#Использовать asserts
+#Использовать fs
+#Использовать json
+
+СистемнаяИнформация = Новый СистемнаяИнформация;
+ЭтоWindows = Найти(НРег(СистемнаяИнформация.ВерсияОС), "windows") > 0;
+
+ФС.ОбеспечитьПустойКаталог("coverage");
+ПутьКСтат = "coverage/stat.json";
+
+Команда = Новый Команда;
+Команда.УстановитьКоманду("oscript");
+Если НЕ ЭтоWindows Тогда
+	Команда.ДобавитьПараметр("-encoding=utf-8");
+КонецЕсли;
+Команда.ДобавитьПараметр(СтрШаблон("-codestat=%1", ПутьКСтат));    
+Команда.ДобавитьПараметр("tasks/test.os");
+Команда.ПоказыватьВыводНемедленно(Истина);    
+
+КодВозврата = Команда.Исполнить();
+Сообщить(Команда.ПолучитьВывод());
+Ожидаем.Что(КодВозврата).Равно(0);
+
+Файл_Стат = Новый Файл(ПутьКСтат);
+Ожидаем.Что(Файл_Стат.Существует(), СтрШаблон("Файл <%1> с результатами покрытия не существует!", Файл_Стат.ПолноеИмя)).ЭтоИстина();
+
+ЧтениеТекста = Новый ЧтениеТекста(ПутьКСтат, КодировкаТекста.UTF8);
+
+СтрокаJSON = ЧтениеТекста.Прочитать();
+ЧтениеТекста.Закрыть();
+
+Парсер = Новый ПарсерJSON();
+ДанныеПокрытия = Парсер.ПрочитатьJSON(СтрокаJSON);
+
+ЗаписьXML = Новый ЗаписьXML;
+ЗаписьXML.ОткрытьФайл("coverage/genericCoverage.xml");
+ЗаписьXML.ЗаписатьОбъявлениеXML();
+ЗаписьXML.ЗаписатьНачалоЭлемента("coverage");
+ЗаписьXML.ЗаписатьАтрибут("version", "1");
+
+Для Каждого Файл Из ДанныеПокрытия Цикл
+	
+	ДанныеФайла = Файл.Значение;
+	
+	ЗаписьXML.ЗаписатьНачалоЭлемента("file");
+	ЗаписьXML.ЗаписатьАтрибут("path", ДанныеФайла.Получить("#path"));
+	
+	Для Каждого КлючИЗначение Из ДанныеФайла Цикл
+		
+		Если КлючИЗначение.Ключ = "#path" Тогда
+			Продолжить;
+		КонецЕсли;
+		
+		ДанныеПроцедуры = КлючИЗначение.Значение;
+		Для Каждого ДанныеСтроки Из ДанныеПроцедуры Цикл
+			
+			ЗаписьXML.ЗаписатьНачалоЭлемента("lineToCover");
+			
+			ЗаписьXML.ЗаписатьАтрибут("lineNumber", ДанныеСтроки.Ключ);
+			Покрыто = Число(ДанныеСтроки.Значение.Получить("count")) > 0;
+			ЗаписьXML.ЗаписатьАтрибут("covered", Формат(Покрыто, "БИ=true; БЛ=false"));
+			
+			ЗаписьXML.ЗаписатьКонецЭлемента(); // lineToCover
+		КонецЦикла
+	КонецЦикла;
+	
+	ЗаписьXML.ЗаписатьКонецЭлемента(); // file
+	
+КонецЦикла;
+
+ЗаписьXML.ЗаписатьКонецЭлемента(); // coverage
+ЗаписьXML.Закрыть();