build.gradle

plugins {
  id 'application'
  id 'eclipse'
  id 'com.github.johnrengelman.shadow' version '7.0.0'
}

defaultTasks 'shadowJar'

repositories {
  jcenter()

  // maven { url "http://jacamo.sourceforge.net/maven2" }
  maven { url "https://raw.github.com/jacamo-lang/mvn-repo/master" }
}

group = "org.hyperagents"
version = '0.0-SNAPSHOT'
sourceCompatibility = '1.8'
mainClassName = 'io.vertx.core.Launcher'

def vertxVersion = '3.9.0'
def mainVerticleName = 'org.hyperagents.yggdrasil.MainVerticle'
def watchForChange = 'src/**/*'
def doOnChange = './gradlew classes'

dependencies {
  implementation "io.vertx:vertx-core:$vertxVersion"
  implementation "io.vertx:vertx-config:$vertxVersion"
  implementation "io.vertx:vertx-web:$vertxVersion"
  implementation "io.vertx:vertx-web-api-contract:$vertxVersion"
  implementation "io.vertx:vertx-web-client:$vertxVersion"
  implementation "io.github.classgraph:classgraph:4.4.12"

  implementation 'org.apache.httpcomponents.client5:httpclient5:5.0.1'
  implementation 'org.apache.httpcomponents.client5:httpclient5-fluent:5.0.1'

  implementation name: "cartago", version: "2.5-SNAPSHOT"
  implementation name: "wot-td-java", version: "0.0.1"

  // https://mvnrepository.com/artifact/org.eclipse.rdf4j/rdf4j-model
  implementation group: 'org.eclipse.rdf4j', name: 'rdf4j-model', version: '2.4.2'
  // https://mvnrepository.com/artifact/org.eclipse.rdf4j/rdf4j-repository-sail
  implementation group: 'org.eclipse.rdf4j', name: 'rdf4j-repository-sail', version: '2.4.2'
  // https://mvnrepository.com/artifact/org.eclipse.rdf4j/rdf4j-sail-memory
  implementation group: 'org.eclipse.rdf4j', name: 'rdf4j-sail-memory', version: '2.4.2'
  implementation group: 'org.eclipse.rdf4j', name: 'rdf4j-sail-nativerdf', version: '2.4.2'

  implementation 'org.apache.commons:commons-rdf-api:0.5.0'
  implementation 'org.apache.commons:commons-rdf-rdf4j:0.5.0'
  implementation 'com.google.code.gson:gson:2.8.6'

  testImplementation "junit:junit:4.12"
  testImplementation "io.vertx:vertx-unit:$vertxVersion"
}

shadowJar {
  classifier = 'fat'
  manifest {
      attributes "Main-Verticle": mainVerticleName
  }
  mergeServiceFiles {
    include 'META-INF/services/io.vertx.core.spi.VerticleFactory'
  }
}

run {
  args = ['run', mainVerticleName, "--redeploy=$watchForChange", "--launcher-class=$mainClassName", "--on-redeploy=$doOnChange"]
}

apply plugin: 'java'

compileJava {
  options.compilerArgs << '-parameters'
}

apply plugin: 'maven-publish'

publishing {
    publications {
        customLibrary(MavenPublication) {
            from components.java
        }
    }

    repositories {
        maven {
            name = 'yggdrasil_shared_auth'
            url = layout.buildDirectory.dir("repo")
        }
    }
}