build.gradle

allprojects {
    apply plugin: "java"

    base {
        java.toolchain.languageVersion = JavaLanguageVersion.of(17)
        compileJava.options.encoding = compileTestJava.options.encoding = javadoc.options.encoding = "UTF-8"

        group = project.maven_group ?: rootProject.maven_group
        archivesName = project.maven_name ?: rootProject.maven_name
        version = project.maven_version ?: rootProject.maven_version
    }

    repositories {
        mavenCentral()
    }

    configurations {
        include

        implementation.extendsFrom include
        api.extendsFrom include
    }

    jar {
        dependsOn configurations.include
        from {
            duplicatesStrategy = DuplicatesStrategy.EXCLUDE
            configurations.include.collect {
                zipTree(it)
            }
        } {
            exclude "META-INF/*.RSA", "META-INF/*.SF", "META-INF/*.DSA"
        }

        from("LICENSE") {
            rename { "${it}_${project.name ?: rootProject.name}" }
        }
    }
}

apply plugin: "idea"

repositories {
    maven {
        name = "ViaVersion"
        url = "https://repo.viaversion.com"
    }
}

dependencies {
    implementation "net.raphimc:ViaProxy:3.3.6"
}

processResources {
    inputs.property "version", project.version

    filesMatching("viaproxy.yml") {
        expand "version": project.version
    }
}

idea {
    module {
        ["run"].each {
            excludeDirs << file("$it")
        }
    }
}

tasks.register("runViaProxy", JavaExec) {
    dependsOn tasks.jar

    mainClass = "net.raphimc.viaproxy.ViaProxy"
    classpath = sourceSets.main.compileClasspath
    workingDir = file("run")
    jvmArgs = ["-DskipUpdateCheck"]

    doFirst {
        def pluginsDir = file("$workingDir/plugins")
        pluginsDir.mkdirs()
        file("$pluginsDir/${project.name}.jar").bytes = tasks.jar.archiveFile.get().asFile.bytes
    }

    doLast {
        file("$workingDir/plugins/${project.name}.jar").delete()
        file("$workingDir/logs").deleteDir()
    }
}