Detached configuration dependency report

[TWiStErRob]

@UntrackedTask(because = "Console output only.")
abstract class DetachedConfigurationReportTask extends AbstractDependencyReportTask {

	@Input
	abstract ListProperty<Configuration> getDetachedConfigurations()

	@Override
	ConfigurationContainer getTaskConfigurations() {
		def configurations = new ExistingConfigurationContainer()
		configurations.addAll(detachedConfigurations.get())
		return configurations
	}
}

ExistingConfigurationContainer

@SuppressWarnings('GrUnnecessaryPublicModifier')
public class ExistingConfigurationContainer
		extends org.gradle.api.internal.AbstractNamedDomainObjectContainer<Configuration>
		implements ConfigurationContainer {

	public ExistingConfigurationContainer() {
		super(Configuration.class, null, { name }, null)
	}
	@Override
	public Configuration detachedConfiguration(Dependency... dependencies) {
		throw new UnsupportedOperationException("$this cannot create a detached configuration.")
	}
	@Override
	protected Configuration doCreate(String name) {
		throw new UnsupportedOperationException("$this cannot create a configuration named $name.")
	}
	@Override
	public Configuration getAt(String name) {
		return (Configuration)super.getAt(name)
	}
	@Override
	public Configuration findByName(String name) {
		return (Configuration)super.findByName(name)
	}
	@Override
	public Configuration getByName(String name) {
		return (Configuration)super.getByName(name)
	}
	@Override
	public Configuration getByName(String name, Closure configureClosure)
			throws UnknownDomainObjectException {
		return (Configuration)super.getByName(name, configureClosure)
	}
	@Override
	public Configuration getByName(String name, Action<? super Configuration> configureAction)
			throws UnknownDomainObjectException {
		return (Configuration)super.getByName(name, configureAction)
	}
}

Motivation: wanted to see what was called lintClassPath in old AGPs. In AGP 8 it's a detached configuration, hidden away:

afterEvaluate {
	tasks.register("detached", DetachedConfigurationReportTask) {
		detachedConfigurations.add(
			tasks.named("lintAnalyzeDebug")
			     .map { com.android.build.gradle.internal.lint.AndroidLintAnalysisTask task ->
				     // Hack com.android.build.gradle.internal.lint.LintFromMaven's detached config.
				     println(task.lintTool.classpath.class)
				     println(task.lintTool.classpath.sourceCollections)
				     def c = task.lintTool.classpath.sourceCollections.first()
				     println(c)
				     c
			     }
			     // If this is not done eagerly while configuring,
			     // and the lintTool.classpath gets resolved,
			     // The sourceCollections will return Files instead of the originating Configuration.
			     // See DefaultConfigurableFileCollection#calculateFinalizedValue for why this happens (value = ...).
			     .get()
		)
	}