build.gradle

buildscript {
  group = 'io.michaelrocks'
  version = '8.13.48'

  ext.projectCompileSdkVersion = 35
  ext.projectBuildToolsVersion = '35.0.0'
  ext.projectMinSdkVersion = 14
  ext.projectTargetSdkVersion = 35

  ext.androidToolsVersion = '8.7.0'

  ext.junitVersion = '4.13.2'
  ext.mockitoVersion = '5.14.1'

  ext.androidxEspressoVersion = '3.6.1'
  ext.androidxTestRulesVersion = '1.6.1'
  ext.androidxTestRunnerVersion = '1.6.2'
  ext.androidxTestExtJunitVersion = '1.2.1'

  repositories {
    google()
    mavenCentral()
  }

  dependencies {
    classpath "com.android.tools.build:gradle:$androidToolsVersion"
  }
}

allprojects {
  repositories {
    google()
    mavenCentral()
  }
}

task clean(type: Delete) {
  delete rootProject.layout.buildDirectory
}

allprojects { project ->
  def publishPropertiesFile = rootProject.file('publish.properties')
  if (publishPropertiesFile.exists()) {
    def localProperties = new Properties()
    publishPropertiesFile.withInputStream { stream -> localProperties.load(stream) }
    localProperties.each { property ->
      if (property.key == "signing.secretKeyRingFile") {
        // If this is the key ring, treat it as a relative path
        project.ext.set(property.key, rootProject.file(property.value).absolutePath)
      } else {
        project.ext.set(property.key, property.value)
      }
    }
  }
}