3.12-subdivision.nlogo

; Copyright (c) 2011-24 David O'Sullivan and George Perry
; Licensed under the Creative Commons
; Attribution-NonCommercial-ShareAlike 3.0 License
; See Info tab for full copyright and license information
;;

;; a breed of turtles one of which is
;; associated with each subdivision
breed [nodes node]

nodes-own [
  domain ;; patches in the subdivision
  state      ;; integer 0 or 1
  width      ;; width and height of subdivision
  height     ;; in patches
  depth      ;; limits how far subdivision can go
]

globals [
  max-depth  ;; maximum number of times we can subdivide
  colours    ;; list of the two patch colours
  contrast-colors  ;; list of corresponding contrast colors for nodes
]

patches-own [
  my-node    ;; each patch has node (and is one of the domain of that node)
]

to setup
  clear-all

  let x max (list world-width world-height)
  set x 2 ^ ceiling (ln x / ln 2)
  resize-world 0 (x - 1) 0 (x - 1)
  set-patch-size ceiling (512 / world-width)

  ;; max depth is limited by world size power of two
  set max-depth floor (ln count patches / ln 2)

  ;; set up the colours
  set colours [grey green]
  set contrast-colors map [ ?1 -> contrast-color ?1 ] colours

  ;; make the starting node, which is associated with all patches
  create-nodes 1 [
    ;; put it in the center of the world
    setxy (min-pxcor + world-width / 2) - 0.5 (min-pycor + world-height / 2) - 0.5
    ;; and all the world is associated with it
    set domain patches
    set width world-width
    set height world-height
    ;; housekeeping
    set heading 0 ;; this is important for the positioning of new nodes heading 0 = North
    set shape "dot"
    set depth 0
    set state random 2
    set color item 0 contrast-colors
  ]
  ;; all patches are associated with node 0
  ask patches [
    set my-node node 0
    set pcolor item ([state] of my-node) colours
  ]
  reset-ticks
end


to go
  if count nodes > n-subdivisions [ stop ]
  ;; pick a node to subdivide
  ask node-to-divide [
    ;; make 'children' of this node
    let children subdivide
    ;; position them and allocate patches to them
    locate children
    allocate-patches-to children
    ;; and then parent node disappears
    die
  ]
  tick
end


;; reports a color contrasting with the supplied color
;; uses RGB colours to do this
to-report contrast-color [c]
  let rgb-color extract-rgb c
  ;; make the RGB components either 0 or 255 in
  ;; opposition to the RGB components of the supplied color
  report map [ cx -> 255 - round (cx / 255) * 255 ] rgb-color
end


;; pick a node to subdivide
to-report node-to-divide
  let to-divide nobody
  if select-for-subdivision-by = "area" [
    ;; area-based so pick a patch whose my-node is non-terminal
    ;; choosing based on patches is equivalent to area-weighting
    ;; the random selection
    ask one-of patches with [[depth] of my-node < max-depth] [
      set to-divide my-node
    ]
  ]
  if select-for-subdivision-by = "equal-probability" [
    ;; just pick a non-terminal node
    set to-divide one-of nodes with [depth < max-depth]
  ]
  report to-divide
end


;; hatch two 'children' and set their state
;; according to the rules specified
to-report subdivide
  ;; we will return a turtle-set
  let new-nodes turtle-set nobody
  hatch-nodes 2 [
    ;; empty domain set to start
    set domain (patch-set nobody)
    ;; one level 'deeper' in the subdivision
    set depth depth + 1
    ;; set state based on inheritance, or at random
    ifelse inherit-state? [
      ;; still a chance for non-inheritance
      if random-float 1 < p-state-change [
        set state 1 - ([state] of myself) ;; the opposite state
      ]
    ]
    ;; otherwise just pick a random state
    [ set state random 2 ]
    ;; now set color and add to the new-nodes
    set color item state contrast-colors
    set new-nodes (turtle-set self new-nodes)
  ]
  report new-nodes
end


;; procedure to 'deploy' the new-nodes supplied
;; in square domain, heading of the nodes is arbitrary
;; in a rectangular domain, they must turn 90 degrees
to locate [c]
  ifelse width = height [
    ;; parent domain is square, flip coin to turn 90
    let coin random 2
    ask c [ if coin = 0 [ rt 90 ] ]
  ]
  [ ;; rectangle, so must turn 90 degrees
    ask c [ rt 90 ]
  ]
  ;; now make one of them face the other way
  ask one-of c [ rt 180 ]
  ;; now they each move 1/4 of distance across
  ;; current domain away from its center
  let d max (list width height) / 4
  ask c [ jump d ]
end


;; procedure to split the parent domain between the
;; new nodes depending on closeness to the new nodes
to allocate-patches-to [c]
  ;; note that this awkward formulation is required because
  ;; 'ask domain' encounters the 'only observer can ask all patches'
  ;; error at depth 0
  ask domain with [my-node = myself] [
    set my-node min-one-of c [distance myself]
  ]
  let dom domain
  ask c [
    set domain dom with [my-node = myself]
    set width max [pxcor] of domain - min [pxcor] of domain + 1
    set height max [pycor] of domain - min [pycor] of domain + 1
    ask domain [
      set pcolor item ([state] of myself) colours
    ]
  ]
end


;; draw boundaries between domains
to draw-borders
  ;; boundary patches are those with any neighbors4 that have a different my-node
  let boundaries patches with [any? neighbors4 with [my-node != [my-node] of myself]]
  ask boundaries [
    ask neighbors4 [
      ;; only those with different my-node need to draw a line
      if my-node != [my-node] of myself [
        draw-line-between self myself
      ]
    ]
  ]
end


;; draw line between two patches
;; by sprouting a turtle and having it move
;; to halfway point and draw the edge
to draw-line-between [p1 p2]
  ;; set a visible colour
  let pen-color item 0 contrast-colors
  ask p1 [
    ;; make a turtle to do the drawing
    sprout 1 [
      set color pen-color
      ;; move to the boundary
      face p2
      jump 0.5
      ;; face the corner and move there
      rt 90
      jump 0.5
      ;; turn around and draw the edge
      rt 180
      pd
      jump 1
      ;; and die...
      die
    ]
  ]
end


;; colours the patches by the depth of their my-node
to color-by-depth
  ask nodes [
    let n depth
    ask domain [
      set pcolor scale-color red n max-depth 0
    ]
  ]
end


;; R plotting code
;;to r-plot-world
;;  r:put "s" map [position ([pcolor] of ?) colours] sort patches
;;  r:put "nr" world-height
;;  r:put "nc" world-width
;;  r:eval("map <- matrix(s, ncol=nc, nrow=nr)")
;;  r:eval("image(map, asp=1, col=c('white','black'), axes=F)")
;;end
@#$#@#$#@
GRAPHICS-WINDOW
210
10
730
531
-1
-1
2.0
1
10
1
1
1
0
0
0
1
0
255
0
255
0
0
1
ticks
100.0

BUTTON
134
12
201
45
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
138
48
201
81
step
go
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
138
84
201
117
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
26
378
198
411
n-subdivisions
n-subdivisions
100
count patches / 4
4041.0
1
1
NIL
HORIZONTAL

CHOOSER
19
417
198
462
select-for-subdivision-by
select-for-subdivision-by
"area" "equal-probability"
1

SLIDER
27
511
199
544
p-state-change
p-state-change
0
1
0.5
0.01
1
NIL
HORIZONTAL

SWITCH
53
473
199
506
inherit-state?
inherit-state?
1
1
-1000

BUTTON
122
123
201
156
go-100
repeat 100 [go]
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
83
175
199
208
toggle-nodes
ask nodes [\nset hidden? not hidden?\n]
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
82
213
200
246
NIL
draw-borders
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
83
250
201
283
clear-borders
clear-drawing
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
82
297
200
330
NIL
color-by-depth
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
82
334
200
367
restore-colors
ask patches [\nset pcolor item ([state] of my-node) colours\n]
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

@#$#@#$#@
## WHAT IS IT?

This model demonstrates an iterative process which sequentially subdivides a region into halves in either a vertical or horizontal direction.  The resulting subdivided landscape is coloured two different colours to help visualize the structure that emerges, although this colouring is entirely arbitrary and regions could in principle be assigned to many different classes. Options are provided to allow the boundaries between subdivisions to be drawn to assist in visualization

The concept underlying this model is a _binary space partition_ or _binary tree_ and is loosely based on ideas in

+   Morgan FJ 2011 _Residential Property Developers in Urban Agent-Based Models: Competition, Behaviour and the Resulting Spatial Landscape_ Unpublished Ph.D. thesis University of Auckland, New Zealand.

and also described in this paper

+   Etherington TR, FJ Morgan and D O’Sullivan. 2022. Binary space partitioning generates hierarchical and rectilinear neutral landscape models suitable for human-dominated landscapes. _Landscape Ecology_ **37**(7): 1761–1769.

This model is discussed in Chapter 3 of

+   O'Sullivan D and Perry GLW 2013 _Spatial Simulation: Exploring Pattern and Process_. Wiley, Chichester, England.

You should consult that book for more information and details of the model.

## THINGS TO NOTICE

This model uses NetLogo turtles as placeholders that store information about the subdivision structure, and also as a mechanism to operate the subdivision. Each `node` turtle has a `domain` attribute which is a `patch-set` of all its 'member' patches.  Patches correspondingly store a `my-node` attribute which is the node turtles whose domain they are in. A `node` can act on its domain by invoking

    ask domain [
      ;; do stuff
    ]

and a patch can act on the domain of which it is a part by doing

    ask [domain] of my-node [
      ;; do stuff
    ]

Initially `node 0` has as its domain the set of all `patches`. When the time to subdivide comes, the `subdivide` reporter creates two 'child' nodes of the selected node turtle, which are then moved orthogonally away from the current location halfway towards the edge of the domain in opposite directions.  The domain is then split between the two based on which patches are nearer to each.

The state of each node changes relative to its parent depending on how the `inherit-state?` flag is set.

## HOW TO CITE

If you mention this model in a publication, please include these citations for the model itself and for NetLogo

+   Morgan FJ 2011 _Residential Property Developers in Urban Agent-Based Models: Competition, Behaviour and the Resulting Spatial Landscape_ Unpublished Ph.D. thesis University of Auckland, New Zealand.
+   O'Sullivan D and Perry GLW 2013 _Spatial Simulation: Exploring Pattern and Process_. Wiley, Chichester, England.
+   Wilensky U 1999 NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

## COPYRIGHT AND LICENSE

The MIT License (MIT)

Copyright &copy; 2011-24 David O'Sullivan and George Perry

Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the "Software"), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to  permit persons to whom the Software is furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
0
Rectangle -7500403 true true 151 225 180 285
Rectangle -7500403 true true 47 225 75 285
Rectangle -7500403 true true 15 75 210 225
Circle -7500403 true true 135 75 150
Circle -16777216 true false 165 76 116

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270
@#$#@#$#@
NetLogo 6.4.0
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180
@#$#@#$#@
0
@#$#@#$#@